declare
     c sys_refcursor;
     column_1_data dbms_sql.Number_Table;
     column_2_data dbms_sql.Varchar2_Table;
     column_3_data dbms_sql.Date_Table;
     column_1_position integer;
     column_2_position integer;
     column_3_position integer;
     n pls_integer := 1;
     desc_tab dbms_sql.desc_tab;
     cursor_number integer;
     col_cnt integer;
     status integer;
     fetched_count integer;
     fetch_size constant integer := 10;
begin
     open c for
          select level a,
                     level the_column_we_need_1,
                     to_char(level) the_column_we_need_2,
                     sysdate + level the_column_we_need_3,
                     level b
                from dual
                connect by level <= 100;
     cursor_number := dbms_sql.to_cursor_number(c);
     dbms_sql.describe_columns(cursor_number, col_cnt, desc_tab);
     for position in 1..col_cnt loop
          case desc_tab(position).col_name
                when 'THE_COLUMN_WE_NEED_1' then
                     column_1_position := position;
                when 'THE_COLUMN_WE_NEED_2' then
                     column_2_position := position;
                when 'THE_COLUMN_WE_NEED_3' then
                     column_3_position := position;
                else
                     continue;
          end case;
     end loop;
     dbms_sql.define_array(cursor_number, column_1_position, column_1_data, fetch_size, 1);
     dbms_sql.define_array(cursor_number, column_2_position, column_2_data, fetch_size, 1);
     dbms_sql.define_array(cursor_number, column_3_position, column_3_data, fetch_size, 1);
     loop
          fetched_count := dbms_sql.fetch_rows(cursor_number);
          dbms_sql.column_value(cursor_number, column_1_position, column_1_data);
          dbms_sql.column_value(cursor_number, column_2_position, column_2_data);
          dbms_sql.column_value(cursor_number, column_3_position, column_3_data);
          for i in 1..fetched_count loop
                dbms_output.put_line('THE_COLUMN_WE_NEED_1[' || n || '] = ' || column_1_data(i) || ', THE_COLUMN_WE_NEED_2[' || n || '] = ' || column_2_data(i) || ', THE_COLUMN_WE_NEED_3[' || n || '] = ' || column_3_data(i));
                n := n + 1;
          end loop;
          exit when fetched_count < fetch_size;
     end loop;
     dbms_sql.close_cursor(cursor_number);
end;