/* Процедура осуществляет перекидку сиквенса согласно значению поля таблицы.
     Если колонка не передана, то процедура пытается найти колонку через
     констрейнты. Если ключ - составной или ключ нечисловой или таблицы нет - исключение
  */
  procedure alter_sequence_nextval (p_table_name    varchar2
                                  , p_column_name   varchar2 := null
                                  , p_sequence_name varchar2 := null
                                   )
    as
    number_fmt               constant varchar2 (100) := 'fm99999999999999999999999';
    l_seq_currval                     number;
    l_seq_incrementby                 number;
    l_seq_nextval                     number;
    l_seq_cache                       number;
    l_tab_currval                     number;
    l_tab_nextval                     number;
    l_dml                             varchar2 (1000 char);
    l_column_name                     varchar2 (30 char);
    l_table_name                      varchar2 (30 char);
    l_sequence_name                   varchar2 (30 char);
  begin
    l_table_name := UPPER (DBMS_ASSERT.sql_object_name (p_table_name));
    l_sequence_name := UPPER (DBMS_ASSERT.sql_object_name (p_sequence_name));
    l_column_name := TRIM (p_column_name);

    if l_column_name is not null
    then
       l_column_name := DBMS_ASSERT.simple_sql_name (p_column_name);
    else
       begin
          select cc.column_name
            into l_column_name
            from user_constraints c
                 inner join user_cons_columns cc on cc.constraint_name = c.constraint_name and cc.owner = c.owner
                 inner join user_tab_columns tc on tc.table_name = cc.table_name and tc.column_name = cc.column_name
           where c.constraint_type in ('P', 'U') and tc.data_type in ('NUMBER', 'INTEGER') and UPPER (tc.table_name) = l_table_name;
       exception
          when NO_DATA_FOUND
          then
             raise DBMS_ASSERT.invalid_object_name;
          when TOO_MANY_ROWS
          then
             utl_ddl.error ('Таблица ' || l_table_name || ' имеет составной ключ! Укажите требуемую колонку');
             raise exc#invalid_identifier;
       end;
    end if;

    l_dml := 'select s.increment_by, s.cache_size from user_sequences s where sequence_name = upper(trim(:1))';

    execute immediate l_dml into l_seq_incrementby, l_seq_cache using l_sequence_name;

    l_dml := 'begin select max(' || l_column_name || ') into :1 from ' || l_table_name || '; :2 := ' || l_sequence_name || '.nextval; end;';

    execute immediate l_dml using out l_tab_currval, out l_seq_currval;

    if l_tab_currval > l_seq_currval -- В случае, если строго больше, тогда меняем инкремент
    then
       l_dml := 'alter sequence ' || l_sequence_name || ' increment by ' || TO_CHAR (l_tab_currval - l_seq_currval, number_fmt) || ' nocache';
       execute immediate l_dml;

       l_dml := 'begin :2 := ' || l_sequence_name || '.nextval; end;';
       execute immediate l_dml using out l_tab_nextval;

       execute immediate 'alter sequence ' || l_sequence_name || 
                         ' increment by ' || TO_CHAR (l_seq_incrementby, number_fmt) || 
                         case when l_seq_cache = 0 then ' nocache' 
                              else ' cache ' || to_char(l_seq_cache, number_fmt)
                         end;
    elsif l_tab_currval = l_seq_currval
    then -- В редких случаях, когда равны, просто еще раз дернем сиквенс, чтобы не делать alter

       l_dml := 'begin :2 := ' || l_sequence_name || '.nextval; end;';
       execute immediate l_dml using out l_tab_nextval;    

    end if;

    exception
       when DBMS_ASSERT.invalid_object_name
       then
          utl_ddl.error ('Таблицы ' || p_table_name || ' с числовым полем для сиквенса не существует');
          raise exc#invalid_identifier;
       when DBMS_ASSERT.invalid_sql_name
       then
          utl_ddl.error ('Колонка ' || p_table_name || '.' || p_column_name || ' не существует');
          raise exc#invalid_identifier;
    end;