PROCEDURE CLOB2FILE(CL CLOB, FLOCATION VARCHAR2, FNAME VARCHAR2,
                    CSID IN NUMBER := 0) IS
   FP UTL_FILE.FILE_TYPE;
   TEMPBUF RAW(32767);
   AMOUNT INTEGER;
   OFFSET INTEGER;
   CHARSET VARCHAR2(50);
   TEMPBLOB  BLOB;
   SRC     NUMBER := 1;
   DST     NUMBER := 1;
   LANG    NUMBER := 0;
   WARN    NUMBER;
BEGIN
   
   IF (CSID <> 0) THEN
     CHARSET := NLS_CHARSET_NAME(CSID);
     IF (CHARSET IS NULL) THEN
       RAISE_APPLICATION_ERROR (-20000, 'unsupported charset id ' || CSID); 
       RETURN;
     END IF;
   END IF;

   FP := UTL_FILE.FOPEN(FLOCATION, FNAME, 'wb', 32767);

   AMOUNT := DBMS_LOB.GETLENGTH(CL);

   DBMS_LOB.CREATETEMPORARY(TEMPBLOB,TRUE,DBMS_LOB.SESSION);

   
   DBMS_LOB.CONVERTTOBLOB(TEMPBLOB, CL, AMOUNT, DST, SRC, CSID, LANG, WARN); 

   OFFSET := 1;
   LOOP
      BEGIN
         AMOUNT := 32767;
         DBMS_LOB.READ(TEMPBLOB, AMOUNT, OFFSET, TEMPBUF); 
           
         UTL_FILE.PUT_RAW(FP, TEMPBUF);
         UTL_FILE.FFLUSH(FP);
         EXIT WHEN (AMOUNT < 32767);
         OFFSET := OFFSET + AMOUNT;
      EXCEPTION
         WHEN NO_DATA_FOUND THEN
           EXIT;
      END;
   END LOOP;
   UTL_FILE.FCLOSE(FP);
   DBMS_LOB.FREETEMPORARY(TEMPBLOB);			  
END CLOB2FILE;