CREATE OR REPLACE PROCEDURE decode_base64_NOCOPY ( 
                                                  p_clob_in IN OUT NOCOPY CLOB,  -- ЧТО ДЕКОДИРОВАТЬ 
                                                  p_blob_in IN OUT NOCOPY BLOB   -- КУДА ДЕКОДИРОВАТЬ  
                                                  ) -- (ВСЕ ОБЬЕКТЫ СОЗДАЮТСЯ ЗАРАНЕЕ !!!) 
IS 
   v_offset           INTEGER; 
   v_buffer_size      BINARY_INTEGER := 23808; 
   v_buffer_varchar   VARCHAR2 (32767); 
   v_buffer_raw       RAW (32767); 
   v_MaxIN NUMBER := NVL(DBMS_LOB.getlength (p_clob_in),0) ; 
   -- создаем из входного CLOB, соответствующего RFC2045 (с переносами строк) - внутренний CLOB, соответствующий RFC4648 (без переносов) 
   v_Clb_RFC4648 CLOB;   -- этот обьект и будем декодировать 
   v_ControlStr varchar2(100);   -- проверочная строка 
BEGIN 
   IF p_clob_in IS NULL or v_MaxIN=0  -- ничего нет, ничего не делаем 
   THEN 
      RETURN; 
   END IF; 
    
 -- проверим - нужно ли удалять CRLF из входящего CLOB: 
 /* 
 RFC 2045  
 Encoded lines must not be longer than 76 characters, not counting the trailing CRLF.  
 If longer lines are found in incoming, encoded data, a robust implementation might nevertheless decode the lines,  
 and might report the erroneous encoding to the user.  
 */ 
  
 -- берем тестовую строку для определения версии RFC входящего обьекта  
 v_ControlStr:=DBMS_LOB.SubStr(p_clob_in,(case when v_MaxIN<100 then v_MaxIN else 100 end),1); 
    if (instr(v_ControlStr,CHR(10))>0 or instr(v_ControlStr,CHR(13))>0)  
     then 
       DBMS_LOB.createtemporary (v_Clb_RFC4648, TRUE);   
       v_offset := 1;      
       LOOP EXIT WHEN v_offset >= v_MaxIN;  -- перезапишем входящие данные во внутренний обьект без переносов строк 
            v_buffer_varchar:=Replace(Replace(DBMS_LOB.SubStr(p_clob_in,v_buffer_size,v_offset), CHR(10),''), CHR(13),'');  
            DBMS_LOB.writeappend(v_Clb_RFC4648,DBMS_LOB.GetLength(v_buffer_varchar),v_buffer_varchar); 
            v_offset := v_offset + v_buffer_size; 
       END LOOP;      
   else 
      v_Clb_RFC4648:= p_clob_in;  -- ничего изменять не надо.   
   end if; 
    
   -- Теперь основной процесс декодирования по RFC4648 
       v_MaxIN :=DBMS_LOB.getlength (v_Clb_RFC4648); 
       v_offset := 1; 
       LOOP EXIT WHEN v_offset >= v_MaxIN; 
            -- возьмем кусок строки, размером, кратным 4  
            v_buffer_varchar:= DBMS_LOB.SubStr(v_Clb_RFC4648,v_buffer_size,v_offset); 
            -- теперь можно конвертировать 
            v_buffer_raw := UTL_RAW.cast_to_raw (v_buffer_varchar); 
            v_buffer_raw := UTL_ENCODE.base64_decode (v_buffer_raw); 
            DBMS_LOB.writeappend (p_blob_in, UTL_RAW.LENGTH (v_buffer_raw), v_buffer_raw); 
            v_offset := v_offset + v_buffer_size; 
       END LOOP; 
 
-- удалять обьекты не нужно! 
END decode_base64_NOCOPY; 

CREATE OR REPLACE PROCEDURE decode_base64_NOCOPY ( 
                                                  p_clob_in IN OUT NOCOPY CLOB,  -- ЧТО ДЕКОДИРОВАТЬ 
                                                  p_blob_in IN OUT NOCOPY BLOB   -- КУДА ДЕКОДИРОВАТЬ  
                                                  ) -- (ВСЕ ОБЬЕКТЫ СОЗДАЮТСЯ ЗАРАНЕЕ !!!) 
IS 
   v_offset           INTEGER  :=1; 
   v_buffer_size      BINARY_INTEGER; 
   v_buffer_varchar   VARCHAR2 (32767); 
   v_buffer_raw       RAW (32767); 
   v_MaxIN NUMBER := NVL(DBMS_LOB.getlength (p_clob_in),0) ; 

BEGIN 
   IF p_clob_in IS NULL or v_MaxIN=0  -- ничего нет, ничего не делаем 
   THEN 
      RETURN; 
   END IF; 
    
 v_buffer_size:=regexp_instr(DBMS_LOB.SubStr(p_clob_in,(case when v_MaxIN<100 then v_MaxIN else 100 end),1),'['||chr(10)||'|'||chr(13)||']')-1;
 v_buffer_size:= case when v_buffer_size<0 then 32760 else floor(32767/v_buffer_size)*v_buffer_size end;

if mod(v_buffer_size,4)>0
then
 Raise_application_error(-20064,'Base64 decoder must have buffer size divided by 4, instead of '||to_char(v_buffer_size));
end if;
    
   -- Теперь основной процесс декодирования
       LOOP EXIT WHEN v_offset >= v_MaxIN; 
            -- возьмем кусок строки, размером, кратным 4  
            v_buffer_varchar:= DBMS_LOB.SubStr(p_clob_in,v_buffer_size,v_offset); 
            -- теперь можно конвертировать 
            v_buffer_raw := UTL_RAW.cast_to_raw (v_buffer_varchar); 
            v_buffer_raw := UTL_ENCODE.base64_decode (v_buffer_raw); 
            DBMS_LOB.writeappend (p_blob_in, UTL_RAW.LENGTH (v_buffer_raw), v_buffer_raw); 
            v_offset := v_offset + v_buffer_size; 
       END LOOP; 
 
-- удалять обьекты не нужно! 
END decode_base64_NOCOPY;