declare
 type arr_type is table of varchar2(300) index by varchar2(30);
 tab 		arr_type;
 F2_CUR 	sys_refcursor;
 C1 		number;
 fcolcnt 	INTEGER;
 fcols 		DBMS_SQL.DESC_TAB;
 fvalue 	varchar2(32000);
procedure print_tab(rec_tab arr_type) as
  col_ch varchar2(30);
begin 
  col_ch := rec_tab.first;
    LOOP
      dbms_output.put(col_ch||'='||rec_tab(col_ch)||' ');
      col_ch := rec_tab.next(col_ch);
      EXIT WHEN (col_ch IS NULL);
    END LOOP;
    dbms_output.put_line('');
end; 
begin
 null;
 open f2_cur for select * from dept; --my_table
 C1:= DBMS_SQL.TO_CURSOR_NUMBER(f2_cur);
 dbms_sql.describe_columns(c1,fcolcnt,fcols);
 for i in 1..fcolcnt loop
   dbms_sql.define_column(c1,i,fvalue,32000);
 end loop;
 LOOP 
  IF DBMS_SQL.FETCH_ROWS(C1)>0 THEN 
   for i in 1 .. fcolcnt loop
    dbms_sql.column_value(c1,i,fvalue);
    tab(fcols(i).col_name):=fvalue;     null;
   end loop;
    print_tab(tab);
   ELSE 
        EXIT; 
   END IF; 
END LOOP; 
 DBMS_SQL.CLOSE_CURSOR(C1);
end;
/
SQL> /
DEPTNO=10 DNAME=ACCOUNTING LOC=NEW YORK
DEPTNO=20 DNAME=RESEARCH LOC=DALLAS
DEPTNO=30 DNAME=SALES LOC=CHICAGO
DEPTNO=40 DNAME=OPERATIONS LOC=BOSTON

PL/SQL procedure successfully completed.