declare
  l_NumFilter1 number := 7;
  l_DateFilterStart date := date'2018-04-28';
  l_DateFilterStop date := date'2018-04-29';

  -- Просто определим структуру записи
  -- Этот курсор НЕ используется для получения данных
  cursor c_rec is  with t(id, dt_eventDate, num_Attr1, num_Attr2) as (select rownum, date'2018-04-25'+rownum, rownum+1, rownum*7  from dual connect by level < 10)
      select * from t where 1=0
    ;
  type t_cur is ref cursor return c_rec%rowtype; -- Strong ref cursor позволяет легко обращаться к полям записи из PL/SQL 

  -- Перегруженные геттеры (варианты курсора)
  -- Первый параметр геттера - фейк, просто для выбора варианта перегруженной функции 
  -- если таких функций будет много, использовать одни только сочетания параметров для формирования уникальной сигнатуры 
  -- может оказаться неудобно.
  -- 1. По дате
  function get_dataset(by_DtRange number, p_dt_from date, p_dt_to date) return t_cur is
    l_cur t_cur;
  begin
    open l_cur for with t(id, dt_eventDate, num_Attr1, num_Attr2) as (select rownum, date'2018-04-25'+rownum, rownum+1, rownum*7  from dual connect by level < 10)
        select * from t where dt_eventDate between p_dt_from and p_dt_to
    ;
    return l_cur;
  end;

  -- 2. По атрибуту 1
  function get_dataset(by_Attr1 number, p_attr number) return t_cur is
    l_cur t_cur;
  begin
    open l_cur for with t(id, dt_eventDate, num_Attr1, num_Attr2) as (select rownum, date'2018-04-25'+rownum, rownum+1, rownum*7  from dual connect by level < 10)
        select * from t where num_Attr1 = p_attr
    ;
    return l_cur;
  end;

  -- 3. По атрибуту 2
  function get_dataset(by_Attr2 number, p_attr number) return t_cur is
    l_cur t_cur;
  begin
    open l_cur for with t(id, dt_eventDate, num_Attr1, num_Attr2) as (select rownum, date'2018-04-25'+rownum, rownum+1, rownum*7  from dual connect by level < 10)
        select * from t where num_Attr2 = p_attr
    ;
    return l_cur;
  end;

  -- Универсальный обработчик
  procedure process_dataset(p_dataset t_cur) is
    l_row c_rec%rowtype;
  begin
    if not p_dataset%isopen then return; end if;
    loop
      fetch p_dataset into l_row;
      exit when p_dataset%notfound;
      dbms_output.put_line(l_row.id||'. dt_eventDate='||to_char(l_row.dt_eventDate,'yyyy-mm-dd')||', num_Attr1='||l_row.num_Attr1||', num_Attr2='||l_row.num_Attr2);
    end loop;
    close p_dataset;
  end;
begin
  -- Зовем в разных вариациях.
  dbms_output.put_line('FilterSet1');
    process_dataset(get_dataset(by_DtRange=>1, p_dt_from=>l_DateFilterStart, p_dt_to=>l_DateFilterStop));

  dbms_output.put_line('FilterSet2');
    process_dataset(get_dataset(by_Attr1=>1, p_attr=>l_NumFilter1));

  dbms_output.put_line('FilterSet3');
    process_dataset(get_dataset(by_Attr2=>1, p_attr=>l_NumFilter1));
end;
/

FilterSet1
3. dt_eventDate=2018-04-28, num_Attr1=4, num_Attr2=21
4. dt_eventDate=2018-04-29, num_Attr1=5, num_Attr2=28
FilterSet2
6. dt_eventDate=2018-05-01, num_Attr1=7, num_Attr2=42
FilterSet3
1. dt_eventDate=2018-04-26, num_Attr1=2, num_Attr2=7
PL/SQL procedure successfully completed