CREATE OR REPLACE procedure Refresh_Seq (p_owner varchar2, p_name varchar2, p_need_val number)
as
  -- процедура изменяет последовательность таким образом, чтобы при следующем вызове
  -- последовательность возвратит p_need_val
  -- процедура применима только к возрастающим последовательностям (у которых задано MINVALUE)
  -- ВНИМАНИЕ: если p_need_val меньше текущего значения, то MINVALUE изменится
  sql_str        varchar2(500);
  l_cache        varchar2(30);
  l_increment    number;
  l_last_num     number;
  l_curr_val     number;
begin
  -- получить значения cache_size, increment_by, last_number
  select case cache_size when 0 then ' nocache ' else ' cache ' || to_char(cache_size) end,
         increment_by,
         last_number
  into l_cache, l_increment, l_last_num
  from dba_sequences
  where sequence_owner = p_owner and sequence_name = p_name;
  if p_need_val = l_last_num then
    -- последовательность или ни разу не вызывалась,
    -- или смысла что-то трогать нет
    null;
  else
    if p_need_val > l_last_num then
      -- отключить кеширование, minvalue не трогать
      sql_str := 'alter sequence ' || p_owner || '.' || p_name
              || ' nocache';
    else
      -- отключить кеширование, сдвинуть minvalue
      sql_str := 'alter sequence ' || p_owner || '.' || p_name
              || ' nocache'
              || ' minvalue ' || to_char(p_need_val - l_increment);
    end if;
    execute immediate sql_str;
    -- получить текущее значение последовательности
    sql_str := 'select ' || p_owner || '.' || p_name || '.nextval from dual';
    execute immediate sql_str into l_curr_val;
    -- если после этого следующий вызов последовательности выдаст нужный результат,
    -- то все, иначе 
    if (p_need_val - l_increment - l_curr_val) <> 0 then
      -- increment_by на нужное значение
      sql_str := 'alter sequence ' || p_owner || '.' || p_name
              || ' increment by ' || to_char(p_need_val - l_increment - l_curr_val);
      execute immediate sql_str;
      -- установить последовательность в нужное значение
      sql_str := 'select ' || p_owner || '.' || p_name || '.nextval from dual';
      -- после чего l_curr_val будет равен p_need_val - l_increment, т.е. MINVALUE
      execute immediate sql_str into l_curr_val;
    end if;
    -- возвращаем cache_size и increment_by
    sql_str := 'alter sequence ' || p_owner || '.' || p_name
            || ' increment by ' || to_char(l_increment)
            --|| ' minvalue ' || to_char(l_curr_val)
            || l_cache;
    execute immediate sql_str;
  end if;
  -- следующий вызов последовательности даст p_need_val
end;
/