CREATE OR REPLACE PACKAGE addr_search AS
 lexem_delimiter_    CONSTANT VARCHAR2(1) := ' '; --разделитель частей адреса (лексем) в поисковой строке пользователя
 lexem_s3_           CONSTANT PLS_INTEGER := -3; --кандидат для позиционного поиска
 lexem_jast_digit_   CONSTANT PLS_INTEGER := -2; --лексема является просто цифрой/цифрами
 lexem_default_      CONSTANT PLS_INTEGER := -1; --текстовая лексема, не похожа на д.к.с.
 lexem_dks_prefix_   CONSTANT PLS_INTEGER := 0; --лексема похожа на префикс д.к.с., с паразитным пробелом справа
 lexem_dom_          CONSTANT PLS_INTEGER := 1; --лексема похожа на дом
 lexem_korp_         CONSTANT PLS_INTEGER := 2; --лексема похожа на корпус
 lexem_str_          CONSTANT PLS_INTEGER := 3; --лексема похожа на строение
 lexem_s3complex_    CONSTANT PLS_INTEGER := 9; --комплексный тип лексемы в позиционном поиске
....
END addr_search;
/

CREATE OR REPLACE PACKAGE BODY addr_search AS
.....

--Стартовая обработка поисковой строки пользователя перед smart / naive парсингом и определения релевантности
 FUNCTION pre_launch(user_str IN VARCHAR2)
  RETURN VARCHAR2 IS
  user_str_   VARCHAR2(2048 CHAR); --входная строка псле чистки
 BEGIN
  user_str_ :=
   TRANSLATE(TRIM(user_str), 'eyuopagkxcbnmETOPAHKXCBMЁё*?@#№$^=_|[]{}~,;:+<>"''`', 'еуиорадкхсьпмЕТОРАНКХСВМЕе%_'); --удаление транслитерации и мусора,*? -> %_
  user_str_ := REGEXP_REPLACE(user_str_, '!{2,}', '!', 1, 0, 'i'); --превращение повторяющихся ! в один !
  WHILE REGEXP_LIKE(' ' || user_str_ || ' ', '[[:space:]][%_!]*![%_!]*[[:space:]]', 'i') LOOP --удаление мусорных комбинаций из !%_
   user_str_ := REGEXP_REPLACE(' ' || user_str_ || ' ', '[[:space:]][%_!]*![%_!]*[[:space:]]', ' ', 1, 0, 'i');
  END LOOP;
  user_str_ := REGEXP_REPLACE(user_str_, '%{2,}', '%', 1, 0, 'i'); --превращение повторяющихся ! в один !
  user_str_ := REGEXP_REPLACE(user_str_, '[[:space:]]{2,}', ' ', 1, 0, 'i'); --удаление повторяющихся пробелов
  RETURN (TRIM(user_str_));
 END pre_launch;
....

--Распознавание номеров домов, корпусов, строений
 PROCEDURE dks_parser(lexem IN OUT VARCHAR2, lexem_typ OUT NUMBER, cleaned_lexem OUT VARCHAR2, not_lexem OUT BOOLEAN, empty_lexem OUT BOOLEAN) IS
 BEGIN
  lexem_typ := NULL;
  empty_lexem := FALSE;
  not_lexem := REGEXP_LIKE(lexem, '.!|!.', 'i'); --проверка на принудительное мсключение лексемы(NOT)
  lexem := REPLACE(lexem, '!', NULL); --чистка !
  cleaned_lexem := lexem;

  IF lexem IS NOT NULL THEN
   lexem_typ := lexem_default_; --содержит буквы без цифр
   IF REGEXP_LIKE(lexem,
      '^(д(ом)*[-/\%_]в(л([ао]д(ен([ие]е)*)*)*)*[%_]*|д(ом[оа])*[%_]*в(л([ао]д(ен([ие]е)*)*)*)*[%_]*|в(л([ао]д(ен([ие]е)*)*)*)*[%_]*|д(ом)*[%_]*)(([,:.]*[%_[:digit:]]+[[:print:]]*)|([,:.]+[%_[:alpha:]-]+))',
      'i') THEN
    --Идентификация Дома, владения, домовладения. Замена префикса на HHH
    cleaned_lexem :=
     REGEXP_REPLACE(lexem,
     '^(д[ом]*[-/\]в[лаодени]*|д[-омвладени/\]*|в[-лаодени/\]*)([~`!@#$^=|{}:"?+<>;'',.]*)([%_[:print:]]*)', '\3', 1, 0, 'i');
    lexem := 'HHH' || cleaned_lexem; --префикс HHH
    lexem_typ := lexem_dom_;

   ELSIF REGEXP_LIKE(lexem, '^(к([-/\о]*(([рп](ус)*)*|с))*)(([,:.]*[%_[:digit:]]+[[:print:]]*)|([,:.]+[%_[:alpha:]-]+))', 'i') THEN
    --Идентификация Корпуса. Замена префикса на KKK
    cleaned_lexem := REGEXP_REPLACE(lexem, '^(к[-орпус/\]*)([~`!@#$^=|{}:"?+<>;'',.]*)([%_[:print:]]*)', '\3', 1, 0, 'i');
    lexem := 'KKK' || cleaned_lexem; --префикс KKK
    lexem_typ := lexem_korp_;

   ELSIF REGEXP_LIKE(lexem, '^(с(([-/\]*т(р([оа]ен([ие])*)*)*)*|т[-/\]е)[%_]*)(([,:.]*[%_[:digit:]]+[[:print:]]*)|([,:.]+[%_[:alpha:]-]+))',
         'i') THEN
    --Идентификация Строения. Замена префикса на SSS
    cleaned_lexem := REGEXP_REPLACE(lexem, '^(с[-троаени/\]*)([~`!@#$^=|{}:"?+<>;'',.]*)([%_[:print:]]*)', '\3', 1, 0, 'i');
    lexem := 'SSS' || cleaned_lexem; --префикс SSS
    lexem_typ := lexem_str_;

   ELSIF REGEXP_LIKE(lexem,
         '^(д(ом)*[-/\%_]в(л([ао]д(ен([ие]е)*)*)*)*[%_]*|д(ом[оа])*[%_]*в(л([ао]д(ен([ие]е)*)*)*)*[%_]*|в(л([ао]д(ен([ие]е)*)*)*)*[%_]*|д(ом)*[%_]*)[[:punct:]]*$',
         'i') THEN
    --Идентификация одиночного префикса Дома, владения, домовладения
    IF not_lexem THEN
     lexem := 'HHH'; --префикс HHH
     lexem_typ := lexem_dom_;
     empty_lexem := TRUE;
    ELSE
     lexem_typ := lexem_dks_prefix_;
    END IF;

   ELSIF REGEXP_LIKE(lexem, '^(к([-/\о]*(([рп](ус)*)*|с))*[%_]*)[[:punct:]]*$', 'i') THEN
    --Идентификация одиночного префикса Корпуса
    IF not_lexem THEN
     lexem := 'KKK'; --префикс KKK
     lexem_typ := lexem_korp_;
     empty_lexem := TRUE;
    ELSE
     lexem_typ := lexem_dks_prefix_;
    END IF;

   ELSIF REGEXP_LIKE(lexem, '^(с(([-/\]*тр([оа]ен([ие])*)*)*|т[-/\]е)[%_]*)[[:punct:]]*$', 'i') THEN
    --Идентификация одиночного префикса Строения
    lexem_typ := lexem_dks_prefix_;
    IF not_lexem THEN
     lexem := 'SSS'; --префикс SSS
     lexem_typ := lexem_str_;
     empty_lexem := TRUE;
    ELSE
     lexem_typ := lexem_dks_prefix_;
    END IF;

   ELSIF REGEXP_LIKE(lexem, '^[%_]*[[:digit:]]+[%_]*$', 'i') THEN
    --Идентификация только цифр без чего-либо другого
    lexem_typ := lexem_jast_digit_;

   ELSIF REGEXP_LIKE(lexem, '([[:digit:]]+[-/\%_]+)|([[:digit:]]+[-/\%_]*[[:alpha:]]+)|([[:alpha:]]+[-/\%_]*[[:digit:]]+)|(^[%_]*-[%_]*$)', 'i') THEN
    --Идентификация кандидата для номера дома/корпуса/строения для позиционного распознавания
    lexem_typ := lexem_s3_;
   END IF;
  END IF;
 END dks_parser;
....
END addr_search;
/