declare 
  jobhandle    NUMBER;
  job_state    VARCHAR2(30);
  status       ku$_Status;

  job_not_exist EXCEPTION;
  PRAGMA EXCEPTION_INIT (job_not_exist, -31626);
  sobject_list varchar2(3000);

  ind          NUMBER;         -- Loop index number
  percent_done NUMBER;         -- Percentage of job complete
  le           ku$_LogEntry;       -- work-in-progress and error messages
  js           ku$_JobStatus;     -- Job status from get_status
  jd           ku$_JobDesc;       -- Job description from get_status
  sts          ku$_Status;         -- Status object returned by get_status
    
begin

  sobject_list := '''PROC1'', ''PROC2''';

  jobhandle := dbms_datapump.open( operation    => 'IMPORT',
                                   job_mode     => 'SCHEMA',
                                   remote_link  => 'DBLINK1' );

  dbms_datapump.metadata_filter( handle => jobhandle,
                                 name   => 'INCLUDE_PATH_EXPR',
                                 value  => 'IN (''FUNCTION'',''PROCEDURE'')');

  dbms_datapump.metadata_filter( handle      => jobhandle
                               , name        => 'SCHEMA_LIST'
                               , value       => '''SCHEMA1''' );

  dbms_datapump.metadata_filter( handle      => jobhandle
                               , name        => 'NAME_LIST'
                               , value       => sobject_list
                               , object_type => 'SCHEMA_EXPORT/PROCEDURE' );

  dbms_datapump.metadata_filter( handle      => jobhandle
                               , name        => 'NAME_LIST'
                               , value       => '''FUNC1'''
                               , object_type => 'SCHEMA_EXPORT/FUNCTION' );

  dbms_datapump.start_job(jobhandle);

  percent_done := 0;
  job_state := 'UNDEFINED';
  
  while (job_state != 'COMPLETED') and (job_state != 'STOPPED') loop
    
    DBMS_DATAPUMP.get_status(jobhandle,
                             DBMS_DATAPUMP.ku$_status_job_error +
                             DBMS_DATAPUMP.ku$_status_job_status +
                             DBMS_DATAPUMP.ku$_status_wip,
                             -1,
                             job_state,
                             sts);
    js := sts.job_status;

      -- As the percentage-complete changes in this loop, the new value displays.
      if 
        js.percent_done != percent_done
    then
        DBMS_OUTPUT.PUT_LINE('*** Job percent done = ' || to_char(js.percent_done));
        percent_done := js.percent_done;
     end if;
     
  if (bitand(sts.mask,dbms_datapump.ku$_status_wip) != 0)
  then
      le := sts.wip;
  else
      if (bitand(sts.mask,dbms_datapump.ku$_status_job_error) != 0)
      then
       le := sts.error;
      else
       le := null;
      end if;
  end if;
  
   if 
     le is not null
 then
     ind := le.FIRST;
      while ind is not null loop
       DBMS_OUTPUT.PUT_LINE(le(ind).LogText);
       ind := le.NEXT(ind);
      end loop;
 end if;
end loop;     
     
-- When the job finishes, display status before detaching from job.
 DBMS_OUTPUT.PUT_LINE('Job has completed');
 DBMS_OUTPUT.PUT_LINE('Final job state = ' || job_state);
-- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

  dbms_datapump.detach(jobhandle);

EXCEPTION
  WHEN OTHERS 
  THEN raise_application_error(-20001,dbms_utility.format_error_stack||' '||
                                      dbms_utility.format_error_backtrace);
end;

ORA-31684: Object type PROCEDURE:"SCHEMA1"."PROC1" already exists

dbms_datapump.set_parameter( handle => jobhandle
                           , name => 'TABLE_EXISTS_ACTION'
                           , value => 'REPLACE' );