CREATE OR REPLACE procedure CHECK_TABLESPACE(a_Trashold in number default 96
                                            ,a_FileSize in number default 1024
                                            ,a_IncSize  in number default 10) AUTHID CURRENT_USER as

l_free_space_query varchar2(4000):=
     q'(select USED_PERCENT
          from DBA_TABLESPACE_USAGE_METRICS m
         where m.TABLESPACE_NAME = '<ИМЯ ТАБЛИЧНОГО ПРОСТРАНСТВА>')';
  l_free_space number;

  l_last_datafile_query varchar2(4000):=
     q'(select regexp_substr(full_path,'[^/\\]*$') filename
              ,substr(full_path,1,regexp_instr(full_path,'[^/\\]*$')-1) dir
          from (select  max(d.name) KEEP (DENSE_RANK LAST ORDER BY d.CREATION_TIME) full_path
                  from v$datafile d, V$TABLESPACE ts
                 where ts.TS#=d.ts#
                   and ts.NAME = 'ИМЯ ТАБЛИЧНОГО ПРОСТРАНСТВА') )';
  lc_last_datafile SYS_REFCURSOR;

  l_old_filename varchar2(1000);
  l_directory    varchar2(1000);
  l_new_filename varchar2(1000);
  l_cmd          varchar2(4000);
BEGIN
  execute immediate l_free_space_query INTO l_free_space;
  if (l_free_space > a_Trashold) and (p_session.getdbedition <> 'EXPRESS') then
    open lc_last_datafile for l_last_datafile_query;
    fetch lc_last_datafile into l_old_filename,l_directory;
    if lc_last_datafile%FOUND then
      select coalesce(regexp_substr(l_old_filename,'([^[:digit:]]*)([[:digit:]]*)(\.[^[:digit:]]*)',1,1,'i',1)
                     ,regexp_substr(l_old_filename,'([^[:digit:]]*)([[:digit:]]*)([^[:digit:]]*)',1,1,'i',1))
            ||lpad(coalesce(c_number(regexp_substr(l_old_filename,'([^[:digit:]]*)([[:digit:]]*)([^[:digit:]]*)',1,1,'i',2))+1,1),3,'0')
            ||coalesce(regexp_substr(l_old_filename,'([^[:digit:]]*)([[:digit:]]*)(\.[^[:digit:]]*)',1,1,'i',3),'.dbf')
        into l_new_filename from dual;
      l_cmd:=q'(alter tablespace <ИМЯ ТАБЛИЧНОГО ПРОСТРАНСТВА> add datafile ')' || l_directory || l_new_filename || q'(' size )' || to_char(a_FileSize) ||'M autoextend on NEXT '||to_char(a_IncSize) || 'M';
      --dbms_output.put_line(l_cmd);
      execute immediate l_cmd;
    end if;
    close lc_last_datafile;
  end if;
EXCEPTION
  when OTHERS then
    p_debug_log.WRITE_ERROR(aPROC => 'P_UPDATE.CHECK_TABLESPACE'
                          , aMsg => 'Ошибка при проверке доступного пространства в табличном пространстве'
                          , aLevel => p_debug_log.LOG_LEVEL_BASIC );
    raise;
END;
/