create or replace function fed_rsbu.Get_Externaldata_Strings_Pipe(
   p_Data in blob,
   p_Start_Row in number default 1,
   p_ReturnRowQty in number default null,
   p_end_row_symbol in varchar2 default chr(10))
  return sys.ORA_MINING_VARCHAR2_NT
  pipelined is
  v_RowNum number := 1;
  v_StartString number := 1;
  v_EndString number;
  v_blk varchar2(32767);
  v_blk_len number;
  v_StartBlk number := 1;
  v_EndBlk number;
  v_String varchar2(32767);
  v_tot_len number := dbms_lob.getlength(p_Data);
  v_end_row raw(10) := UTL_raw.cast_to_raw(p_end_row_symbol);
begin

  if v_tot_len = 0 then
    pipe row(null);
  end if;

  while v_StartString <= v_tot_len loop
    v_EndString := dbms_lob.instr(p_Data, v_end_row, v_StartString + 32000);
    if v_EndString is null or v_EndString = 0 or v_EndString <= v_StartString then
      v_EndString := v_tot_len + 1;
    end if;
    -- v_blk := trim(UTL_raw.cast_to_varchar2(dbms_lob.substr(p_Data, v_EndString - v_StartString, v_StartString)));
    v_blk := UTL_raw.cast_to_varchar2(dbms_lob.substr(p_Data, v_EndString - v_StartString, v_StartString));
    v_blk_len := length(v_blk);
    v_StartBlk := 1;
    while v_StartBlk <= v_blk_len loop
      v_EndBlk := instr(v_blk, p_end_row_symbol, v_StartBlk);
      if v_EndBlk is null or v_EndBlk = 0 or v_EndBlk <= v_StartBlk then
        v_EndBlk := v_blk_len + 1;
      end if;
      -- v_String := trim(substr(v_blk, v_StartBlk, v_EndBlk - v_StartBlk));
      v_String := substr(v_blk, v_StartBlk, v_EndBlk - v_StartBlk);
      v_StartBlk := v_EndBlk + nvl(length(p_end_row_symbol), 1);
      v_RowNum := v_RowNum + 1;
      if v_RowNum >= p_Start_Row then
        pipe row(substr(v_String,1,4000));
      end if;
      if v_RowNum > p_ReturnRowQty then
        return;
      end if;
    end loop;
    v_StartString := v_EndString + nvl(length(p_end_row_symbol), 1);
  end loop;
  return;
end Get_Externaldata_Strings_Pipe;