Всем привет!
Если кому интересно могу отписать как отправить вложение больше чем 32К!
Прикол заключается в том что необходимо закодировать в base64 blob

Используйте следующие процедуры для кодирования и декодирования в base64

{src}

PROCEDURE Encode_Base64(p_Src IN OUT NOCOPY BLOB
,p_Dst IN OUT NOCOPY BLOB) IS
c_Max_Length_Base64 CONSTANT PLS_INTEGER := 22848;
/*
c_Max_Length_Base64 НЕ МЕНЯТЬ
Она подобранна специальным образом
Исходя из следующих соображений
32767 - максимальный размер буфера что оракл может сконвертить (на выходе)
поэтому на входе необходимо подать 32767*0.7 = 22936 байт
(особенности base64 (три байта конвертятся в четыре))
Другой особенностью является то что сконвертированный текст режится на строки по 64 символа
Так как алгоритм построен просто на склейке выходных данных (после кодирования)
то необходимо основные данные резать так чтоб длинна была кратна 3 чтоб в конце не было
символов "="
Но и этого не достаточно когда обрабатываются куски входного потока то
размер обрабобтанного куска должен быть кратен 64
поэтому получаем следующее 64*3*n < 22936
путем не сложных вычислений получаем что n = 119
64*3*119 = 22848
вот так получена эта цифра
можно былобы по другому (вырезать переводы корретки а потом резать по 64 и добавлять
переводу коретки по моему это лишнее)
*/
i_Pos INTEGER := 1;
n_Amount BINARY_INTEGER := c_Max_Length_Base64;
i_Pos_w INTEGER := 1;
n_Amount_w BINARY_INTEGER;
a_Raw RAW(32767);
n_Length_Src INTEGER;
BEGIN
IF p_Src IS NOT NULL
AND Dbms_Lob.Getlength(p_Src) != 0 THEN
Dbms_lob.Createtemporary(p_Dst,FALSE);
n_Length_Src := Dbms_Lob.Getlength(p_Src);
LOOP
IF i_Pos + c_Max_Length_Base64 - 1 <= n_Length_Src THEN
n_Amount := c_Max_Length_Base64;
ELSE
n_Amount := n_Length_Src - i_Pos + 1;
END IF;
a_Raw := Utl_Encode.Base64_Encode(Dbms_Lob.Substr(p_Src, n_Amount, i_Pos));
n_Amount_w := Utl_Raw.Length(a_Raw);
Dbms_lob.Write(p_Dst, n_Amount_w, i_Pos_w, a_Raw);
i_Pos_w := n_Amount_w + i_Pos_w;
i_Pos := n_Amount + i_Pos;
EXIT WHEN i_Pos >= n_Length_Src;
END LOOP;
END IF;
END;

PROCEDURE Decode_Base64(p_Src IN OUT NOCOPY BLOB
,p_Dst IN OUT NOCOPY BLOB) IS
c_Max CONSTANT PLS_INTEGER := 32736;
/*
c_Max НЕ МЕНЯТЬ
Она подобранна специальным образом
Исходя из следующих соображений
32767 - максимальный размер буфера что оракл может сконвертить (на входе)
на выходе получится примерно 32767*0.7 = 22936 байт
(особенности base64 (три байта конвертятся в четыре))
Другой особенностью является то что сконвертированный текст режится на строки по 64 символа
Так как алгоритм построен просто на склейке выходных данных (после декодирования)
то необходимо основные данные резать так чтоб длинна была кратна 4
Но и этого не достаточно когда обрабатываются куски входного потока
они порезаны по строчкам длинной 66 символов (64 основных и 2 символа перевода корректки 13+10)
поэтому получаем следующее 66*4*n < 32767
путем не сложных вычислений получаем что n = 119
66*4*124 = 32736
вот так получена эта цифра
*/

a_Part RAW(32764);
i_Pos INTEGER := 1;
n_Amount BINARY_INTEGER := c_Max;
i_Pos_w INTEGER := 1;
n_Amount_w BINARY_INTEGER;
n_Length_Src INTEGER;
BEGIN
IF p_Src IS NOT NULL
AND Dbms_Lob.Getlength(p_Src) != 0 THEN
Dbms_lob.Createtemporary(p_Dst,FALSE);
n_Length_Src := Dbms_Lob.Getlength(p_Src);
LOOP
IF i_Pos + c_Max - 1 <= n_Length_Src THEN
n_Amount := c_Max;
ELSE
n_Amount := n_Length_Src - i_Pos + 1;
END IF;
a_Part := Utl_Encode.Base64_Decode(Dbms_Lob.Substr(p_Src, n_Amount, i_Pos));
n_Amount_w := Utl_raw.Length(a_Part);
Dbms_lob.Write(p_Dst, n_Amount_w, i_Pos_w, a_Part);
i_Pos_w := n_Amount_w + i_Pos_w;
i_Pos := n_Amount + i_Pos;
EXIT WHEN i_Pos >= n_Length_Src;
END LOOP;
END IF;
END;


PROCEDURE Parse_Blob(p_Blob IN BLOB
,t_Raw_Tab IN OUT NOCOPY Raw_Table) IS
c_Cr CONSTANT RAW(2) := Utl_Raw.Cast_To_Raw(Chr(13)||chr(10));
i_Blob_Length INTEGER;
Part_Blob RAW(100);
i PLS_INTEGER := 1;
Pos_CR PLS_INTEGER := 1;
BEGIN
t_Raw_Tab.DELETE();
IF p_Blob IS NOT NULL THEN
i_Blob_Length := dbms_lob.GetLength(p_Blob);
LOOP
Pos_CR := dbms_lob.instr(p_Blob, c_Cr, i);
IF Pos_CR != 0 THEN
Part_Blob := dbms_lob.substr(p_Blob,Pos_CR-i,i);
i := Pos_CR + 2;
ELSE
Part_Blob := dbms_lob.substr(p_Blob,i_Blob_Length-i,i);
i := i_Blob_Length;
END IF;
t_Raw_Tab(t_Raw_Tab.Count()+1) := Part_Blob;
EXIT WHEN i >= i_Blob_Length;
END LOOP;
END IF;
END;
{/src}

chameleon82stalker_copВсем привет!
Если кому интересно могу отписать как отправить вложение больше чем 32К!
Прикол заключается в том что необходимо закодировать в base64 blob
Спасибо за код. А Вы могли бы привести пример работы с Вашим кодом? Я так понял изначальный блоб должен храниться в бд? Как вариант в таком случае можно блоб сохранить во временный файл, тогда пакет его скушает без особых проблем.

Всем привет
Я просто предоставил три процедурки которые кодируют и раскодируют блоб в/из base64. В последнем варианте отправки писем отредактировать вызов utl_smtp.write_raw_data(v_Mail_Conn, UTL_ENCODE.base64_encode(vRAW)); На то что я представил (но не в лоб там начитка из файла для начала файл в blob а потом нарезать на кусочки и отправить)

А зачем тебе вообще BLOB записывать на файловую систему?
В данном случаи тебе нужно BLOB просто перекодировать в base64
в данном топике есть все необходимое чтоб переделать "готовое решение" под себя.