create or replace PROCEDURE RunProcedIndependSesNotWait(
                                                        In_OwnerJOB         IN VARCHAR2, 
                                                        In_NameRunProcedure IN VARCHAR2, 
                                                        In_CntArgumentProc  IN NUMBER,
                                                        In_ArrArgument      IN ARRAY_ARGUMENT_TAB
                                                        ) is

v_OwnerJOB          VARCHAR2(100):='"'||In_OwnerJOB||'"';
v_TmpNameJob        VARCHAR2(100);
BEGIN

        v_TmpNameJob:='"TMP'||TO_CHAR(SYS_CONTEXT ('USERENV', 'SID'))||'"';

        DBMS_SCHEDULER.CREATE_JOB (
                                   job_name             =>  v_OwnerJOB||'.'||v_TmpNameJob, --название джоба
                                   job_type             =>  'STORED_PROCEDURE', --тип джоба
                                   job_action           =>  In_NameRunProcedure,-- вызываемая процедура
                                   number_of_arguments  =>  In_CntArgumentProc, --кол-во входных параметров у процедуры
                                   start_date           =>  sysdate,  --время старта джоба                              
                                   enabled              =>  FALSE,  -- по умолчанию при создание нельзя включать джоб
                                   auto_drop            =>  TRUE,   -- автоудаление джоба по завершению выполнения процедуры
                                   comments             =>  ''      -- комментарий к джобу
                                   );
        FOR i in 1..In_ArrArgument.count LOOP

            DBMS_SCHEDULER.SET_JOB_ARGUMENT_VALUE(      -- присваивание значение входным параметрам согласно номеру по порядку параметра
                         job_name => v_OwnerJOB||'.'||v_TmpNameJob, -- название джоба
                         argument_position => In_ArrArgument(i).NUM_ARGUMENT,                -- номер параметра
                         argument_value => In_ArrArgument(i).VAL_ARGUMENT);    --значение параметра
        END LOOP;

            DBMS_SCHEDULER.SET_ATTRIBUTE( -- отключение логирования
                     name => v_OwnerJOB||'.'||v_TmpNameJob, 
                     attribute => 'logging_level', value => DBMS_SCHEDULER.LOGGING_OFF);

            DBMS_SCHEDULER.enable( -- включение джоба
                     name => v_OwnerJOB||'.'||v_TmpNameJob);
                     
        EXCEPTION 
            WHEN OTHERS 
            THEN 
                
                RAISE;

END RunProcedIndependSesNotWait;