DECLARE
  c_cnt_job CONSTANT NUMBER := 4;
  v_cnt_run_job NUMBER;
  lnJob         NUMBER;
  v_done        BOOLEAN := FALSE;
BEGIN
  MERGE INTO some_work_table c
  USING (SELECT c.rowid rd,
                ntile(c_cnt_job) over(PARTITION BY NULL ORDER BY NULL) nt
           FROM appdeploy.some_work_table c
          WHERE CHANGEDFROMLASTCHECK = 'Y') t$src
  ON (c.rowid = t$src.rd)
  WHEN MATCHED THEN
    UPDATE
       SET c.job_no         = t$src.nt,
           c.job_updated    = NULL,
           c.job_row_status = 'N';
  --
  --
  dbms_application_info.set_module('MAIN', 'STARTED');
  --
  FOR i IN 1 .. c_cnt_job LOOP
    lnJob := i;
    dbms_job.submit(job       => lnJob,
                    what      => 'begin schema.some_pkg.FS_JOB(' || i || '); end;',
                    next_date => SYSDATE + 1 / (24 * 60 * 60));
  END LOOP;
  COMMIT;
  -- sleep for a job settled
  DBMS_LOCK.sleep(5);
  --sync and wait
  WHILE NOT v_done LOOP
    SELECT COUNT(1) INTO v_cnt_run_job FROM dba_jobs WHERE what LIKE '%some_pkg.FS_JOB%';
    IF v_cnt_run_job > 0 THEN
      DBMS_LOCK.sleep(60);
    ELSE
      v_done := TRUE;
    END IF;
  END LOOP;
END;