create or replace function grantedSelect (
    p_grantee varchar2
  , p_owner varchar2
  , p_table_name varchar2
) return varchar2 as
  v_row varchar2( 64 );
  cursor cr_sys_privs is 
    select privilege 
    from dba_sys_privs 
    where  1 = 1 
      and grantee = p_grantee 
      and privilege = 'SELECT ANY TABLE';
  cursor cr_tab_privs is 
    select privilege 
    from dba_tab_privs 
    where  1 = 1 
      and grantee = p_grantee 
      and owner = p_owner
      and table_name = p_table_name
      and privilege = 'SELECT';       
begin
  open cr_sys_privs; fetch cr_sys_privs into v_row; close cr_sys_privs;
  if v_row is not null then return 'TRUE'; end if;
  open cr_tab_privs; fetch cr_tab_privs into v_row; close cr_tab_privs;
  if v_row is not null then return 'TRUE'; end if;
  for i in (
    select granted_role from dba_role_privs where grantee = p_grantee
  ) loop                 
    if grantedSelect(i.granted_role, p_owner, p_table_name) = 'TRUE' then
      return 'TRUE';
    end if;  
  end loop;
  return 'FALSE';
end;
/

 -- Проверка
 
select grantedSelect(user, 'SCOTT', 'EMP') from dual;