PROCEDURE send_message(subject in varchar2,mess in clob,to_address in varchar2,to_cc in varchar default null)
   IS
      header VARCHAR2 (1000);
      cc varchar2(128 Char);
      mail_conn UTL_SMTP.connection;
      len     INTEGER;
      ind   INTEGER;
      mess_len integer:=32767;
      m_mailhost varchar2(128 byte);
      m_sender varchar2(128 byte);
      m_from_mail_disp_name varchar2(128 byte);
   BEGIN
      m_mailhost:=get_sys_parameter('mailhost');
      m_sender:=get_sys_parameter('mail_sender');
      m_from_mail_disp_name:=get_sys_parameter('mail_disp_name');
      mail_conn := UTL_SMTP.open_connection (m_mailhost, 25);
      mail_conn.tx_timeout := 600;

      if to_cc is not null then
        cc:='Cc: '|| ' <'|| to_cc|| '>'|| CHR(13)||CHR(10);
      else
        cc:='';
      end if;
      UTL_SMTP.helo (mail_conn, m_mailhost);

      UTL_SMTP.mail (mail_conn, m_sender);
      UTL_SMTP.rcpt (mail_conn, to_address);
       header := 'From: '|| m_from_mail_disp_name ||' <'|| m_sender || '>' || CHR(13)||CHR(10)
         || 'To: '|| ' <'|| to_address|| '>'|| CHR(13)||CHR(10)||cc
         || 'Subject: '|| subject|| CHR(13)||CHR(10);
      UTL_SMTP.open_data (mail_conn);
      UTL_SMTP.write_data (mail_conn,'MIME-Version: ' || '1.0' || UTL_TCP.crlf);
      UTL_SMTP.write_data (mail_conn,'Content-Type: '||'text/html; charset=utf-8'||UTL_TCP.crlf);
      UTL_SMTP.write_data (mail_conn,'Content-Transfer-Encoding: '||'8bit'||UTL_TCP.crlf);
      UTL_SMTP.write_data (mail_conn, header);


        UTL_SMTP.write_data (mail_conn, UTL_TCP.crlf);
        len := DBMS_LOB.getlength(mess);
        ind := 1;

        WHILE ind <= len
        LOOP
            UTL_SMTP.write_data(mail_conn, DBMS_LOB.SUBSTR(mess, mess_len, ind));
            ind := ind + mess_len;
        END LOOP;


      UTL_SMTP.close_data (mail_conn);
      UTL_SMTP.quit (mail_conn);
   EXCEPTION
      when others then
          UTL_SMTP.quit(mail_conn);
          --log_error();
      raise;
   END;