create or replace package reset_running_distance_ptf is
function describe(
  tab  in out dbms_tf.table_t,
  col  in     dbms_tf.columns_t,
  dist number default 1.0
) return dbms_tf.describe_t;
procedure fetch_rows(dist number default 1.0);
end reset_running_distance_ptf;
/

create or replace package body reset_running_distance_ptf is 
function describe(
  tab  in out dbms_tf.table_t,
  col  in     dbms_tf.columns_t,
  dist number default 1.0
) return dbms_tf.describe_t is
  ok boolean;
begin
  if col.count <> 1 then
    raise_application_error(-20001, 'Должна быть указана одна колонка скольжения');
  end if;
  ok := false;
  for i in 1..tab.column.count loop
    if tab.column(i).description.name = col(1) and tab.column(i).description.type = dbms_tf.type_number then
      ok := true;
      tab.column(i).for_read := true;
      exit;
    end if;
  end loop;
  if not ok then
    raise_application_error(-20002, 'Колонка скольжения должна иметь тип НУМБЕР');
  end if;
  --
  return dbms_tf.describe_t(
    new_columns => dbms_tf.columns_new_t(1=>dbms_tf.column_metadata_t(name=>'DISTANCE_GROUP', type=>dbms_tf.type_number)));
end describe; 
procedure fetch_rows(dist number default 1.0) is
  dg_num  number;
  dg_end  number;
  ru_col  dbms_tf.tab_number_t;
  dg_col  dbms_tf.tab_number_t;
begin
  dbms_tf.get_col(1, ru_col);
  dg_num := 0;             dbms_tf.xstore_get('dg_num', dg_num);
  dg_end := ru_col(1) - 1; dbms_tf.xstore_get('dg_end', dg_end);
  for i in 1..ru_col.count loop
      if ru_col(i) > dg_end then
        dg_num := dg_num + 1;       dbms_tf.xstore_set('dg_num', dg_num);
        dg_end := ru_col(i) + dist; dbms_tf.xstore_set('dg_end', dg_end);
      end if;        
      dg_col(i) := dg_num;
  end loop;
  dbms_tf.put_col(1, dg_col);
end fetch_rows;
end reset_running_distance_ptf; 
/

create or replace function reset_running_distance(
  tab table,
  col columns,
  dist number default 1.0
) return table pipelined table polymorphic using reset_running_distance_ptf; 
/