create or replace function EVALUATE( s in varchar ) return date as
  res date;
begin
  execute immediate 'begin :x := '||s||'; end;' using out res;
  return res;
end;
/

Function created

create table dropme_t(id, val, dDate)
partition by range(dDate)
interval (interval '11' day)
(partition p1 values less than (date'2000-01-01') segment creation deferred)
as select rownum, 'val'||rownum, date'2016-12-01'+rownum from dual connect by level < 200
;

Table created

select count(*) "ВСЕГО"
     , count(case when ddate <  date'2017-01-01' then 1 end) "Удалить"
     , count(case when ddate >= date'2017-01-01' then 1 end) "Сохранить"
from dropme_t;

     ВСЕГО    Удалить  Сохранить
---------- ---------- ----------
       199         30        169

-- Пограничный раздел
select * from dropme_t partition for (date'2017-01-01');

        ID VAL                                         DDATE
---------- ------------------------------------------- -----------
        25 val25                                       26.12.2016
        26 val26                                       27.12.2016
        27 val27                                       28.12.2016
        28 val28                                       29.12.2016
        29 val29                                       30.12.2016
        30 val30                                       31.12.2016
        31 val31                                       01.01.2017
        32 val32                                       02.01.2017
        33 val33                                       03.01.2017
        34 val34                                       04.01.2017
        35 val35                                       05.01.2017
11 rows selected

-- Поехали...
declare
  l_owner varchar2(100) := USER;
  l_name varchar2(100) := 'DROPME_T';
  l_keep_after date := date'2017-01-01';
  l_partkeyexpression varchar2(2000) := to_char(l_keep_after,q'{"TO_DATE('"yyyy-mm-dd hh24:mi:ss"','yyyy-mm-dd hh24:mi:ss')"}');
  l_meta xmltype;
begin
  l_meta := xmltype(dbms_metadata.get_xml('TABLE',l_name,l_owner));
  for i in (
    select interval_str
    from xmltable('/ROWSET/ROW/TABLE_T/PART_OBJ/PARTOBJ'
           passing l_meta
           columns interval_str path 'INTERVAL_STR'
         )
  )loop
    if i.interval_str is not null then
      execute immediate 'alter table '||l_owner||'.'||l_name||' set interval()';
      execute immediate 'alter table '||l_owner||'.'||l_name||' set interval('||i.interval_str||')';
    end if;
  end loop;
  for i in (
    select 'alter table DROPME_T drop partition '||part_name||' update indexes' stmnt
      from xmltable('/ROWSET/ROW/TABLE_T/PART_OBJ/PART_LIST/PART_LIST_ITEM'
      passing l_meta
      columns part_name path 'SCHEMA_OBJ/SUBNAME'
            , HIBOUNDVAL path 'HIBOUNDVAL'
      ) x
      where evaluate(hiboundval) <= l_keep_after
    ) loop
      execute immediate ''||i.stmnt;
    end loop;
    execute immediate 'alter table '||l_owner||'.'||l_name||' split partition for('||l_partkeyexpression||') at ('||l_partkeyexpression||') update indexes';
    execute immediate 'alter table '||l_owner||'.'||l_name||q'{ drop partition for(date'1900-01-01') update indexes}';
end;
/

PL/SQL procedure successfully completed

-- Итог: 
select count(*) "ВСЕГО"
     , count(case when ddate <  date'2017-01-01' then 1 end) "Удалить"
     , count(case when ddate >= date'2017-01-01' then 1 end) "Сохранить"
from dropme_t;

     ВСЕГО    Удалить  Сохранить
---------- ---------- ----------
       169          0        169

select * from dropme_t partition for (date'2017-01-01');
        ID VAL                                         DDATE
---------- ------------------------------------------- -----------
        31 val31                                       01.01.2017
        32 val32                                       02.01.2017
        33 val33                                       03.01.2017
        34 val34                                       04.01.2017
        35 val35                                       05.01.2017

SQL>