declare
     v_refcur sys_refcursor;
     cursor v_cur
       is
         select  id,
                 price,
                 quantity
           from  xmltable(
                          '/ROWSET/ROW'
                          passing xmltype(v_refcur)
                          columns
                            id number path 'ID',
                            price number path 'PRICE',
                            quantity number path 'QUANTITY'
                         );
begin
    get_product(sysdate,v_refcur);
    for v_rec in v_cur loop
      dbms_output.put_line('id = ' || v_rec.id);
      dbms_output.put_line('price = ' || v_rec.price);
      dbms_output.put_line('quantity = ' || v_rec.quantity);
    end loop;
end;
/

declare
     v_refcur sys_refcursor;
     v_dbms_sql_cur number;
     v_column_count number;
     l_column_tbl   dbms_sql.desc_tab;
     v_id           number;
     v_price        number;
     v_quantity     number;
     v_id_pos       number;
     v_price_pos    number;
     v_quantity_pos number;
begin
    get_product(sysdate,v_refcur);
    v_dbms_sql_cur := dbms_sql.to_cursor_number(v_refcur);
    dbms_sql.describe_columns(v_dbms_sql_cur,v_column_count,l_column_tbl);
    for v_i in 1..v_column_count loop  
      if l_column_tbl(v_i).col_name = 'ID'
        then
          v_id_pos := v_i;
          dbms_sql.define_column(v_dbms_sql_cur,v_i,v_id);
      elsif l_column_tbl(v_i).col_name = 'PRICE'
        then
          v_price_pos := v_i;
          dbms_sql.define_column(v_dbms_sql_cur,v_i,v_price);
      elsif l_column_tbl(v_i).col_name = 'QUANTITY'
        then
          v_quantity_pos := v_i;
          dbms_sql.define_column(v_dbms_sql_cur,v_i,v_quantity);
      end if;
    end loop;
    while dbms_sql.fetch_rows(v_dbms_sql_cur) > 0 loop
      dbms_sql.column_value(v_dbms_sql_cur,v_id_pos,v_id);
      dbms_sql.column_value(v_dbms_sql_cur,v_price_pos,v_price);
      dbms_sql.column_value(v_dbms_sql_cur,v_quantity_pos,v_quantity);
      dbms_output.put_line('id = ' || v_id);
      dbms_output.put_line('price = ' || v_price);
      dbms_output.put_line('quantity = ' || v_quantity);
    end loop;
end;
/

declare
     v_refcur sys_refcursor;
begin
    get_product(sysdate,v_refcur);
    dbms_sql.return_result(v_refcur);
end;
/