-- (пример упрощен и стилизован)

procedure Outer is
begin
  -- якорная строчка. Если Inner() потом вылетает, она должна остаться
  -- конечно, вызывающий может всю транзакцию отменить, и эту строчку тоже.
  insert into TBL10 ...;

  --------- начало вложенной транзакции для Inner()
  savepoint BeforeInner;

  begin
    Inner;
  exception 
    when others
      rollback to BeforeInner;
      LogError('exception в Inner(), частичный откат');
      -- без raise, вызывающий не заинтересован в ошибках Inner()
  end;
  --------- завершение вложенной транзакции для Inner()

  -- далее могут быть аналогичные вызовы Inner2(), Inner3()..
end;

procedure Inner
begin
  update TBL21..;
  update TBL22..; -- вылетает по exception, например строка слишком длинная
  update TBL23..;
end Inner;

  procedure AtomicInner(eatex in boolean := false) is
  begin
    savepoint BeforeCall;
    Inner;
  exception
    when others then 
      rollback to BeforeCall;
      if not eatex then raise; end if;
  end;

procedure Outer is
begin
  insert into TBL10 ...;

  begin
    Inner;
  exception 
    when others
      LogError('exception в Inner(), игнорируем..');
      -- без raise, вызывающий не заинтересован в ошибках Inner()
  end;

SQL> create table TEST20 ( num  NUMBER not null,
  2    text VARCHAR2(10) not null -- короткое поле нам даст проблемы
  3  );
Table created

SQL> create or replace procedure Inner(i in integer, s in varchar2) is
  2  begin
  3    insert into test20(num,text) values( i, '1:' || s);
  4    insert into test20(num,text) values( i, '2:' || s || 'extra'); -- тут рванет, если много текста
  5    insert into test20(num,text) values( i, '3:' || s);
  6  end Inner;
  7  /
Procedure created

SQL> exec Inner(1,'one');

PL/SQL procedure successfully completed.

SQL> select * from test20;

       NUM TEXT
---------- ----------
         1 1:one
         1 2:oneextra
         1 3:one

 Ожидаемо, процедура отработала без ошибок

SQL> exec inner(null,null);
BEGIN inner(null,null); END;

*
ERROR at line 1:
ORA-01400: cannot insert NULL into ("EEK"."TEST20"."NUM")
ORA-06512: at "EEK.INNER", line 3
ORA-06512: at line 1
 null запрещен, сломалось сразу

SQL> exec Inner(0,'zero');
BEGIN Inner(0,'zero'); END;

*
ERROR at line 1:
ORA-12899: value too large for column "EEK"."TEST20"."TEXT" (actual: 11,
maximum: 10)
ORA-06512: at "EEK.INNER", line 4
ORA-06512: at line 1
 сломалось на второй строчке, слишком длинная

SQL> select * from test20;

       NUM TEXT
---------- ----------
         1 1:one
         1 2:oneextra
         1 3:one

 а вот тут интересно. Exceptions откатывали не всю транзакцию, а только
 ту часть, которую исполнял exec. Вот такое поведение мне и надо, в PL/SQL.

SQL> rollback; -- действительно ли не было авто-коммита?

Rollback complete.

SQL> select * from test20;

no rows selected  -- действительно не было.

SQL>

SQL> truncate table test20;

Table truncated.

SQL> begin
  2    Inner(1,'one');
  3    Inner(0,'zero');
  4  end;
  5  /
begin
*
ERROR at line 1:
ORA-12899: value too large for column "EEK"."TEST20"."TEXT" (actual: 11,
maximum: 10)
ORA-06512: at "EEK.INNER", line 4
ORA-06512: at line 3


SQL> select * from test20;

no rows selected

SQL> begin
  2    Inner(1,'one');
  3    Inner(0,'zero');
  4  end;
  5  /

SQL> begin
  2  inner(1,'one');
  3  end;
  4  /

SQL> begin
  2  inner(0,'zero');
  3  end;
  4  /

SQL> create table TEST ( key  INTEGER, text VARCHAR2(100) );

Table created.

SQL> create or replace procedure Outer(n in integer) is
  2    -- обертка для Inner(). Если Inner() сбойнет, откатывает только ее.
  3    procedure AtomicInner(i in integer, s in varchar2) is
  4    begin
  5      savepoint PrepForUndo;
  6      Inner(i,s);
  7    exception
  8      when others then
  9        rollback to PrepForUndo;
 10    end AtomicInner;
 11
 12  begin
 13    insert into TEST(key,text)  values( n, 'anchor key');
 14    AtomicInner( n, rpad('A',n) ); -- сломается в середине апдейтов
 15  end Outer;
 16  /

Procedure created.

SQL> exec outer(5); -- параметры >3 вызывают сбой

PL/SQL procedure successfully completed.

SQL> select * from test;

KEY  TEXT
----   -----
 5  anchor key

SQL> select * from test20;

no rows selected

SQL> truncate table test;
Table truncated

SQL> begin
  2  Outer(5);
  3  Outer(1);
  4  Outer(8);
  5  end;
  6  /

PL/SQL procedure successfully completed.

SQL> select * from test left join test20 on key=num order by key, test20.text;
KEY TEXT             NUM TEXT
---- --------------- ----- ----------
   1 anchor key          1 1:A
   1 anchor key          1 2:Aextra
   1 anchor key          1 3:A
   5 anchor key                                                                                  
   8 anchor key                                                                                  

create or replace procedure Inner(i in integer, s in varchar2) is
begin
  if i in (1,11) then rollback; end if; -- строка подвоха!
  insert into test20(num,text) values( i, '1:' || s);
  insert into test20(num,text) values( i, '2:' || s || 'extra');
  insert into test20(num,text) values( i, '3:' || s);
end Inner;

SQL> truncate table test;

Table truncated.

SQL> truncate table test20;

Table truncated.

SQL> begin
  2  Outer(0); -- ожидаем успех
  3  Outer(1); -- ожидаем подвох, результаты предыдущей строки наверное пропали
  4  Outer(5); -- ожидаем фэйл, но якорь будет?
  5  Outer(11); -- еще подвох, плюс фэйл!
  6  end;
  7  /
begin
*
ERROR at line 1:
ORA-01086: savepoint 'PREPFORUNDO' never established in this session or is
invalid
ORA-06512: at "EEK.OUTER", line 9
ORA-12899: value too large for column "EEK"."TEST20"."TEXT" (actual: 13,
maximum: 10)
ORA-06512: at "EEK.OUTER", line 14
ORA-06512: at line 5