declare
  procedure assert_inn(i_inn varchar2) is
    la_coeff_10 sys.odcinumberlist  := sys.odcinumberlist(2,4,10,3,5,9,4,6,8,0);
    la_coeff_121 sys.odcinumberlist := sys.odcinumberlist(7,2,4,10,3,5,9,4,6,8,0);
    la_coeff_122 sys.odcinumberlist := sys.odcinumberlist(3,7,2,4,10,3,5,9,4,6,8,0);
    procedure assert_cs(i_inn varchar2, io_coeff in out nocopy sys.odcinumberlist) is
      l_calc number := 0;
    begin
      for i in 1..io_coeff.count loop
        l_calc := l_calc + io_coeff(i)*to_number(substr(i_inn,i,1),'0');
      end loop;
      case to_char(mod(mod(l_calc,11),10),'fm0') 
        when substr(i_inn,io_coeff.count,1) then null;
        else raise_application_error(-20000,'ИНН не валиден: "'||i_inn||'"');
      end case;       
    end;
  begin
    case length(i_inn)
      when 10 then
        assert_cs(i_inn,la_coeff_10);
      when 12 then
        assert_cs(i_inn,la_coeff_121);
        assert_cs(i_inn,la_coeff_122);
    else
      raise VALUE_ERROR;
    end case;
  exception
    when VALUE_ERROR then
      raise_application_error(-20000,'ИНН должен состоять из 10 либо 12 цифр, получено "'||i_inn||'"');
  end;
begin
  assert_inn('7830002293');
  assert_inn('500100732259');
end;
/