drop table job_next_run purge;
create table job_next_run(job_name varchar2(50 char) not null, next_run_date date not null);

begin
    for i in (select * from user_scheduler_jobs where job_name = 'JOB_RUNER')
    loop
        sys.dbms_scheduler.drop_job(i.job_name);
    end loop i;
end;
/
begin
    sys.dbms_scheduler.create_job
    (
        job_name            => 'JOB_RUNER',
        job_type            => 'PLSQL_BLOCK',
        job_action          => '
declare
    procedure run_job(p_job_name varchar2)
    is
        pragma autonomous_transaction;
        type t_rowid_list is table of rowid;
        v_rowid_list t_rowid_list;
        v_cur sys_refcursor;
    begin
        -- Лочим со skip и удаляем записи, дающие основания для запуска жоба сейчас.
        open v_cur for select rowid from job_next_run where next_run_date <= sysdate and job_name = p_job_name for update skip locked;
        loop
            fetch v_cur bulk collect into v_rowid_list limit 1000;
            exit when v_rowid_list.count() = 0;
            forall v_idx in indices of v_rowid_list
                delete from job_next_run where rowid = v_rowid_list(v_idx);
            exit when v_cur%notfound;
        end loop;
        close v_cur;

        -- Инициируем запуск жоба.
        sys.dbms_scheduler.run_job(p_job_name, use_current_session => false);

        -- В случае успеха - коммитим удаление основания для запуска жоба.
        commit;
    exception
        when others then
            -- В случае - ошибки откатываемся.
            rollback;
            
            -- Если ошибка вне списка ожидаемых, логгируем её.
            if sqlcode not in (-27478 /*job is running*/  ) then
                event_api.log_event
                (
                    p_event_text => sqlerrm,
                    p_event_type => ''E'',
                    p_autonomous =>  true
                );
            end if;
    end;
begin
    for i in (select distinct job_name from  job_next_run where next_run_date <= sysdate)
    loop
        run_job(i.job_name);
    end loop;
end;
',
        number_of_arguments => 0,
        start_date          => to_date(null),
        repeat_interval     => 'Freq=Secondly;Interval=1',
        end_date            => to_date(null),
        job_class           => 'DEFAULT_JOB_CLASS',
        enabled             => true,
        auto_drop           => false,
        comments            => 'Жоба для внепланого запуска других жоб'
    );
end;
/