PROCEDURE Check_Exist_File(p_Dirname IN VARCHAR2, p_Filename IN VARCHAR2, p_Res OUT NUMBER) AS
    v_Lob_Loc              BFILE;
    v_Num_Num_Not_Null_Log NUMBER := 100;
    --Сколько секунд проверять, что файл не пустой
    v_Handle Utl_File.File_Type;
    Vnewline VARCHAR2(32000);
  BEGIN
    v_Lob_Loc := Bfilename(p_Dirname, p_Filename);
    --Проверим, что файл создан
    IF (Dbms_Lob.Fileexists(v_Lob_Loc) != 0) THEN
      p_Res := 1;
    ELSE
      p_Res := 0;
      RETURN;
    END IF;
    --Если файл создан, то проверим, что он не пустой
    FOR i IN 1 .. v_Num_Num_Not_Null_Log
    LOOP
      v_Handle := Utl_File.Fopen(p_Dirname, p_Filename, 'r');

      BEGIN
        Utl_File.Get_Line(v_Handle, Vnewline);
        --Если смогли прочитать строку
        Utl_File.Fclose(v_Handle);
        RETURN;
      EXCEPTION
        WHEN No_Data_Found THEN
          IF i < v_Num_Num_Not_Null_Log THEN
            Dbms_Lock.Sleep(1);
            Utl_File.Fclose(v_Handle);
          ELSE
            p_Res := 0;
            IF Utl_File.Is_Open(v_Handle) THEN
              Utl_File.Fclose(v_Handle);
            END IF;
            Errors_Pack.Te_User_Error_With_Raise(p_Descr         => 'При проверке лога произошла ошибка. Превышено время ожидания ненулевого содержимого в файле',
                                                 p_Sql_Text      => NULL,
                                                 p_Pars          => 'p_Dirname=' || p_Dirname ||
                                                                    '; p_Filename=' || p_Filename,
                                                 p_Programm_Name => 'Check_Exist_File');
          END IF;
      END;

    END LOOP;

  EXCEPTION
    WHEN OTHERS THEN
      Errors_Pack.Te_Oracle_Error_With_Raise(p_Sql_Text      => NULL,
                                             p_Pars          => 'p_Dirname=' || p_Dirname ||
                                                                '; p_Filename=' || p_Filename,
                                             p_Programm_Name => 'Check_Exist_File');
  END Check_Exist_File;