ALTER FUNCTION [dbo].[f_InclineFamily]
(
	@case tinyint, -- Падеж (2 - Родительный (genitive), 3 - Дательный (dative) )
	@Sex tinyint, -- 1 - муж., 2 - жен.
	@f nvarchar(64), @i nvarchar(64)='', @o nvarchar(64)=''
)
RETURNS nvarchar(255)
AS
BEGIN
	DECLARE @index int
	DECLARE @temp nvarchar(64)
	DECLARE @consonants nvarchar(21) = N'бвгджзйклмнпрстфхцчшщ'; -- Согласные
	DECLARE @vowels nvarchar(10) = N'аеёиоуыэюя'; -- Гласные
	DECLARE @hissing nvarchar(4) = N'жшчщ'; -- Шипящие

	/*
	П1. В современном русском литературном языке не склоняются русские фамилии, 
		оканчивающиеся на -ых, -их (типа Черных, Долгих), а также все фамилии, 
		оканчивающиеся на гласные е, и, о, у, ы, э, ю.
	П2. Все женские фамилии, оканчивающиеся на согласный, не склоняются.
	П3. Если фамилия оканчивается на гласный -а, которому предшествует 
		другой гласный (напр.: Галуа, Моруа, Делакруа, Моравиа, Эриа, Эредиа, Гулиа), 
		она не склоняется.
		Примеры: тетрадь Николая Галуа, диплом выдан Ирине Эриа, встреча с Игорем Гулиа.
	П4. Женские заимствованные фамилии, оканчивающиеся на -ОВ, -ИН, не склоняются.
	*/
	DECLARE @vowels_f_rule1 nvarchar(7) = N'еиоуыэю';

	DECLARE @Result nvarchar(255)
	--DECLARE @Sex tinyint

	set @f=lower(rtrim(ltrim(@f)))
	set @i=lower(rtrim(ltrim(@i)))
	set @o=lower(rtrim(ltrim(@o)))

	DECLARE @f_len tinyint = len(@f)

	IF @f_len >= 2 BEGIN
		set @f=upper(left(@f, 1)) + SUBSTRING(@f, 2, @f_len - 1)

		set @index = CHARINDEX(N'-', @f)
		if @index > 0
		begin
			set @f = left(@f, @index -1) + N'-' + upper(substring(@f, @index + 1, 1)) + right(@f, @f_len - @index - 1)
		end;
		set @index = CHARINDEX(N' ', @f)
		if @index > 0
		begin
			set @f = left(@f, @index -1) + N'-' + upper(substring(@f, @index + 1, 1)) + right(@f, @f_len - @index - 1)
		end;

		DECLARE @f_suffix1 nvarchar(1) = right(@f, 1)
		DECLARE @f_suffix2 nvarchar(2) = case when @f_len > 2 then right(@f, 2) else N'' end
		DECLARE @f_suffix3 nvarchar(3) = case when @f_len > 3 then right(@f, 3) else N'' end
		DECLARE @f_suffix4 nvarchar(4) = case when @f_len > 4 then right(@f, 4) else N'' end
		DECLARE @before_last nvarchar(1) = left(@f_suffix2, 1)

		DECLARE @without_last nvarchar(63) = left(@f, @f_len - 1)
		DECLARE @without_2_last nvarchar(63) = left(@f, @f_len - 2)

		DECLARE @ends1 nvarchar(2) = N'ой'
		DECLARE @ends2 nvarchar(1) = case @case when 2 then N'а' when 3 then N'у' end
		DECLARE @ends3 nvarchar(3) = case @case when 2 then N'ого' when 3 then N'ому' end
		DECLARE @ends4 nvarchar(1) = case @case when 2 then N'я' when 3 then N'ю' end
		DECLARE @ends5 nvarchar(1) = case @case when 2 then N'ы' when 3 then N'е' end
		DECLARE @ends6 nvarchar(1) = case @case when 2 then N'и' when 3 then N'е' end

		IF(@Sex NOT IN (1,2))
		BEGIN
			set @Sex=isnull( (select top 1 sex from dbo.slv_names where [name]=@i), 
						 (select sex from dbo.slv_secondnames where [second_name]=@o) );
		END;

		SELECT @Result = case
			when @f_suffix2 in (N'ых', N'их') or CHARINDEX(@f_suffix1, @vowels_f_rule1) > 0 then @f -- П1
			when @Sex=2 and (@f_suffix1=N'ь' or CHARINDEX(@f_suffix1, @consonants) > 0) then @f -- П2
			when @f_suffix1=N'а' and CHARINDEX(@before_last, @vowels) > 0 then @f -- П3
			when @Sex=2 and @f_suffix2 in (N'ов', N'ин') then @f -- П4
			when @f_suffix3 in (N'сть', N'ядь', N'ажь') then @f

			when @Sex=1 and @f_suffix2 in (N'ов', N'ев', N'ёв', N'ин', N'ын') then @f + @ends2
			when @Sex=2 and @f_suffix3 in (N'ова', N'ева', N'ёва', N'ина', N'ына') then @without_last + @ends1
			when @Sex=1 and @f_suffix4 in (N'ский', N'цкий') then @without_2_last + @ends3
			when @Sex=2 and @f_suffix4 in (N'ская', N'цкая') then @without_2_last + @ends1
			when @Sex=1 and @f_suffix2 in (N'ый', N'ой') then @without_2_last + @ends3

			when @Sex=1 and @f_suffix3 in (N'ски', N'цки') then @without_last + @ends3
			when @Sex=2 and @f_suffix3 in (N'ска', N'цка') then @without_last + @ends1

			when @Sex=1 and @f_suffix2=N'ей' then @without_last + @ends4

			--when @Sex=2 and @f_suffix2=N'ая' then @without_2_last + @ends1

			when @Sex=1 and CHARINDEX(@f_suffix1, @consonants) > 0 then @f + @ends2

			when @Sex=1 and @f_suffix1=N'ь' and CHARINDEX(@before_last, @hissing) = 0 then @without_last + @ends4

			when @f_suffix1=N'а' and CHARINDEX(@before_last, @consonants) > 0 then @without_last +
				case
					when CHARINDEX(@before_last, N'д') > 0 then @ends5
					else @ends6
				end
			when @f_suffix1=N'я' then @without_last + @ends6
		end;
	END
	ELSE BEGIN
		SET @Result = @f
	END;

	RETURN UPPER(left(@i, 1) + N'.' + case when len(@o)>0 then left(@o, 1) + N'. ' else N' ' end) + @Result;
END
go
select dbo.f_InclineFamily(2, 1, N'Иванов', N'Иван', N'Иванович'),
	dbo.f_InclineFamily(2, 2, N'Иванов', N'Иван', N'Иванович'),
	dbo.f_InclineFamily(3, 1, N'Иванов', N'Иван', N'Иванович'),
	dbo.f_InclineFamily(3, 2, N'Иванов', N'Иван', N'Иванович')