-- Description:	Преобразование строки 
-- "Са..." в nvarchar (utf16)
/*
declare @str nvarchar(max) = 'Самая полезная рассылка Море Трэвел'
select * from [mailchimp].[decodeJsonStr]( @str ) as t
*/
ALTER FUNCTION [MailChimp].[decodeJsonStr]( @str nvarchar(max) )
RETURNS TABLE 
AS
RETURN 
(
with t0 as ( select * from dbo.f_nStrToTableEx_v2(@str, N'\') as x )
   , t  as ( select n = Number
                  , s = case when left(Value, 2) = N'u0' then
                                nchar(cast(convert(binary(2), substring(Value, 2, 4), 2) as int))
                                + substring(Value, 6, 100000)
                            else Value
                        end
               from t0
            )
       select str = ( select s + '' from t order by n asc for xml path(''), type ).value('.', 'nvarchar(max)')
)

-- Description:	Преобразование строки 
--  nvarchar  в "Са..."
/*
declare @str nvarchar(max) = 'Самая полезная рассылка Море Трэвел'
declare @str0 nvarchar(max) = N'{} /\ []Самая полезная рассылка Море Трэвел'
declare @estr nvarchar(max) = (select str from [mailchimp].[encodeJsonStr]( @str0) as t);
select @str0;
select @estr;
select str from [mailchimp].[decodeJsonStr]( @estr) as t
*/
ALTER FUNCTION [MailChimp].[encodeJsonStr]( @str nvarchar(max) )
RETURNS TABLE 
AS
RETURN 
(
with t0 as ( select n, c = substring(@str, n, 1) from dbo.N where n between 1 and len(@str) )
   , t1 as ( select n, c, u = unicode(c) from t0 )
   , x as ( select x = N'{}[]""\' )
   , t  as ( select n, c = case when u > 127 or charindex(c, x) > 0 
                                  then '\u' + lower( convert( nvarchar(4), cast( u as binary(2)), 2 ))
                                else c
                           end
               from t1 cross join x
            )
       select str = ( select c + '' from t order by n asc for xml path(''), type ).value('.', 'nvarchar(max)')
)