CREATE PROCEDURE [dbo].[DatabaseFileShrink]
	@File				nvarchar(100),
	@TargetFreeMB		int = 100000,
	@ShrinkIncrementMB	int = 1000
AS

declare @msg		nvarchar(max)
declare @sql		nvarchar(max)
declare @SizeMB		int  
declare @UsedMB		int    

select	[FileSizeMB]    = convert(numeric(10,2),round(a.size/128.,2)),
		[UsedSpaceMB]   = convert(numeric(10,2),round(fileproperty( a.name,'SpaceUsed')/128.,2)) ,
		[UnusedSpaceMB] = convert(numeric(10,2),round((a.size-fileproperty( a.name,'SpaceUsed'))/128.,2)) ,
		[DBFileName]    = a.name  
from          sysfiles a    
where name = @File

-- Get current file size in MB
select @SizeMB = size/128.
from sys.sysfiles
where name = @File

-- Get current space used in MB  
select @UsedMB = fileproperty( @File,'SpaceUsed')/128.
select [StartFileSize] = @SizeMB, [StartUsedSpace] = @UsedMB, [DBFileName] = @File

-- Loop until file at desired size
while @SizeMB > @UsedMB + @TargetFreeMB + @ShrinkIncrementMB
begin
	set @sql =  'dbcc shrinkfile ( ' + @File + ', '+
				convert(varchar(20) , @SizeMB - @ShrinkIncrementMB) + ' )'
	
	print 'Start ' + @sql
	print 'at ' + convert(varchar(30), getdate(), 121)
	exec ( @sql )
	if @@error <> 0
		return
	print 'Done at ' + convert(varchar(30), getdate(), 121)

	-- Get current file size in MB
	select @SizeMB = size/128.
	from sysfiles
	where name = @File

	-- Get current space used in MB
	select @UsedMB = fileproperty( @File,'SpaceUsed')/128.
--	select [FileSize] = @SizeMB, [UsedSpace] = @UsedMB, [DBFileName] = @File
end
select [EndFileSize] = @SizeMB, [EndUsedSpace] = @UsedMB, [DBFileName] = @File