-- disable all constraints
EXEC sp_MSforeachtable "ALTER TABLE ? NOCHECK CONSTRAINT all"

-- enable all constraints
exec sp_MSforeachtable @command1="print '?'", @command2="ALTER TABLE ? WITH CHECK CHECK CONSTRAINT all"

CREATE TABLE #fvplist(id int not null identity primary key, name sysname);   -- save list of modifyed functions
GO
CREATE PROCEDURE ViewRemoveSchemaBinding @ViewName sysname
AS
BEGIN
    SET NOCOUNT ON
    DECLARE @PositionShemaBinding INT
    DECLARE @Command NVARCHAR(MAX)
    DECLARE @typeobj varchar(8) = (select type from sys.objects WHERE name=@ViewName)
    DECLARE @nametypeobj  sysname = 
    (
        SELECT CASE WHEN @typeobj = 'P' THEN 'PROCEDURE'
                    WHEN @typeobj = 'V' THEN 'VIEW'
                    WHEN @typeobj IN ('FN', 'IF', 'FT', 'TF') THEN 'FUNCTION' END
    )
    SELECT @Command = OBJECT_DEFINITION(OBJECT_ID(@ViewName));
    SET @PositionShemaBinding = CHARINDEX('WITH SCHEMABINDING', @Command)

    IF NOT @PositionShemaBinding = 0 BEGIN
        -- WITH SCHEMA BINDING IS PRESENT... Let's remove it !
        SET @Command = STUFF(@Command, CHARINDEX('WITH SCHEMABINDING', @Command), LEN('WITH SCHEMABINDING'), '/*$$$*/');
        SET @Command = REPLACE(@Command, 'CREATE ' + @nametypeobj, 'ALTER ' + @nametypeobj);

        EXECUTE sp_executesql @Command
        INSERT INTO #fvplist (name) VALUES (@ViewName);
    END
END
GO

CREATE PROCEDURE ViewAddSchemaBinding @ViewName sysname
AS
BEGIN
    SET NOCOUNT ON
    DECLARE @PositionShemaBinding INT
    DECLARE @Command NVARCHAR(MAX)
    DECLARE @ObjectName VARCHAR(MAX)
    DECLARE @typeobj varchar(8) = (select type from sys.objects WHERE name=@ViewName)
    DECLARE @nametypeobj  sysname = 
    (
        SELECT CASE WHEN @typeobj = 'P' THEN 'PROCEDURE'
                    WHEN @typeobj = 'V' THEN 'VIEW'
                    WHEN @typeobj IN ('FN', 'IF', 'FT') THEN 'FUNCTION' END
    )

    SELECT  @Command = OBJECT_DEFINITION(OBJECT_ID(@ViewName)),
            @ObjectName = OBJECT_NAME(OBJECT_ID(@ViewName));

    SET @PositionShemaBinding = PATINDEX('%WITH SCHEMABINDING%', @Command)

    IF @PositionShemaBinding = 0 BEGIN
        -- WITH SCHEMA BINDING IS NOT PRESENT... Let's add it !
        SET @Command = STUFF(@Command, CHARINDEX('/*$$$*/', @Command), LEN('/*$$$*/'), ' WITH SCHEMABINDING ');
        SET @Command = REPLACE(@Command, 'CREATE ' + @nametypeobj, 'ALTER ' + @nametypeobj);

        EXECUTE sp_executesql @Command
        DELETE FROM #fvplist WHERE name = @ViewName;
    END
END
GO
PRINT '1. remove schema binding'
EXEC ViewRemoveSchemaBinding 'fn_group_device_reports_int'
EXEC ViewRemoveSchemaBinding 'fn_doc_usage_sum_byuserdate'
EXEC ViewRemoveSchemaBinding 'fn_all_usage_bydate'
EXEC ViewRemoveSchemaBinding 'doc_detail_col_all'

GO
PRINT '2. drop relations'
ALTER TABLE printjob_details DROP CONSTRAINT pk_printjob_details
GO
ALTER TABLE printjob_details DROP CONSTRAINT fk_printjob_details
GO
ALTER TABLE printjob_details ALTER COLUMN job_id bigint NOT NULL
GO
.....
PRINT '3. restore relations'
---------------------------------------------------------------------------------------------
ALTER TABLE job ADD CONSTRAINT pk_job PRIMARY KEY ( job_id )
GO
.....
PRINT '4. restore schema binding'
SET NOCOUNT ON
DECLARE @fvpName sysname
DECLARE fvpName CURSOR LOCAL FOR SELECT name FROM #fvplist ORDER BY id DESC
OPEN fvpName
FETCH NEXT FROM fvpName INTO @fvpName
WHILE @@FETCH_STATUS = 0
BEGIN
    EXEC ViewAddSchemaBinding @fvpName
    FETCH NEXT FROM fvpName INTO @fvpName
END
Close fvpName
DeAllocate fvpName
GO
DROP PROCEDURE ViewAddSchemaBinding;
GO
DROP PROCEDURE ViewRemoveSchemaBinding;
GO