Function ReportSendMail(ByVal SendOrSave As Boolean, MyTo As String, MySubject As Variant, _
                        MyBody As Variant, ParamArray varItems() As Variant)
' Данная функция отправляет или сохраняет письмо
' Переменные:
'     SendOrSave - отпределяет будет письмо отправлено сразу или сохранено (true - отправлено)
'     MyTo       - адрес электронной почты
'     MySubject  - заголовок электронной почты
'     MyBody     - текст письма электронной почты
'     varItems() - список подключенных к письму приложений или отчетов
    Dim MyApplication As Object
    Dim myItem As Object
    Dim intI As Integer
    ' Установление связи с Microsoft Outlook
    On Error Resume Next
    Set MyApplication = GetObject(,  "Outlook.Application" )
    If Err.Number <>  0  Then
        Err.Clear
        Set MyApplication = CreateObject( "Outlook.Application" )
    End If
    ' Создание нового объекта - письма и присвоение ему всех параметров
    Set myItem = MyApplication.CreateItem(0) '  0  - почта
    With myItem
        .To = MyTo
        .Subject = MySubject
        .Body = MyBody
        For intI = UBound(varItems) To LBound(varItems) Step - 1 
            If Not Nz(varItems(intI),  "") = " " Then
                .Attachments.Add varItems(intI)
            End If
        Next intI
        ' В зависимости от параметра - отправить или сохранить в черновике
        If SendOrSave = True Then
            ' Отправить
            .Send
        Else
            ' сохранить в черновике
            .Save
        End If
        If Err.Number <>  0  Then
            ReportSendMail = Err.Number
            Err.Clear
        Else
            ReportSendMail =  0 
        End If
    End With
End Function