Option Compare Database
Option Explicit

Private WithEvents con As ADODB.Connection
Private Steps%

Private Sub Form_Load()
    Set con = CurrentProject.Connection
End Sub

Private Sub Form_Close()
    Set con = Nothing
    wait_avi.fWait.EndWait
End Sub

Private Sub cmdPushMe_Click()
    Steps = 1
    con.BeginTrans
    wait_avi.fWait.StartWait
    DoIt Steps
End Sub

Private Sub DoIt(n%)
    Dim s$
    Select Case n
    Case 1
    s = "select * into t from q"
    Case 2
    s = "update t set n=n + 1000"
    Case 3
    s = "delete from t"
    Case 4
    s = "drop table t"
    Case Else
        con.CommitTrans
        wait_avi.fWait.EndWait
        Exit Sub
    End Select
    Me.Info = "step " & n
    con.Execute s, , adAsyncExecute
End Sub

Private Sub con_WillExecute(Source As String, CursorType As ADODB.CursorTypeEnum, LockType As ADODB.LockTypeEnum, Options As Long, adStatus As ADODB.EventStatusEnum, ByVal pCommand As ADODB.Command, ByVal pRecordset As ADODB.Recordset, ByVal pConnection As ADODB.Connection)
    'Старт AVI
    'wait_avi.fWait.StartWait
    DoEvents
End Sub

Private Sub con_ExecuteComplete(ByVal RecordsAffected As Long, ByVal pError As ADODB.Error, adStatus As ADODB.EventStatusEnum, ByVal pCommand As ADODB.Command, ByVal pRecordset As ADODB.Recordset, ByVal pConnection As ADODB.Connection)
    'Стоп AVI
    'wait_avi.fWait.EndWait
    
    If Not pError Is Nothing Then
          con.RollbackTrans
          MsgBox pError.Description, vbCritical, ""
          Exit Sub
    End If
    
    DoEvents
    Steps = Steps + 1
    DoIt Steps
End Sub