Public Function GetFormByPath(strFormPath As String) As Form
'returns form variable of last subform in path by form path like "frm_Main>frm_SubFormControl>frm_SubSubFormControl"
Dim astrFrm() As String
Dim i As Long
Dim frm As Form

On Error GoTo ErrorHandler

astrFrm = Split(strFormPath, ">")

If UBound(astrFrm) < 0 Then
GoTo ExitHere
End If
Set frm = Forms(astrFrm(0))

For i = 1 To UBound(astrFrm)
Set frm = frm.Controls(astrFrm(i)).Form
Next

Set GetFormByPath = frm

ExitHere:
Exit Function

ErrorHandler:
Resume ExitHere
End Function

Public Function GetFormPath(frmForm As Form) As String
'returns form form path like "frm_Main>frm_SubFormControl>frm_SubSubFormControl"

Dim strRes
Dim frm As Form

On Error GoTo ErrorHandler

Set frm = frmForm

Do
If IsFormStandalone(frm) Then
strRes = frm.Name & IIf(strRes = "", "", ">" & strRes)
Exit Do
Else
strRes = frm.Parent.ActiveControl.Name & IIf(strRes = "", "", ">" & strRes)
Set frm = frm.Parent
End If
Loop While True

ExitHere:
On Error Resume Next
GetFormPath = strRes
Exit Function

ErrorHandler:
Select Case Err
Case 0
Resume Next
Case Else
LogError Err.Number, Err.Description, Erl, "GetFormPath", "bas_CommonFunctions"
Resume ExitHere
End Select
End Function