' From Access 97 Developer's Handbook
' by Litwin, Getz and Gilbert. (Sybex)
' Copyright 1997. All Rights Reserved.
'
Option Compare Database   'Use database order for string comparisons
Option Explicit

Const adhcErrWriteConflict =  7787 
Const adhcErrDataChanged =  7878 

Private Sub cmdClose_Click()
    DoCmd.Close acForm, Me.Name
End Sub

Private Sub Form_Error(DataErr As Integer, Response As Integer)

    ' Handle form-level errors

    On Error GoTo Form_ErrorErr
     
    Dim strMsg As String
    Dim intResp As Integer
    Dim rst As DAO.Recordset
    Dim fld As DAO.Field
    Dim db As DAO.Database
    
    ' Branch based on value of error
    Select Case DataErr
    
    Case adhcErrWriteConflict
        ' Write conflict error
        strMsg = "Another user has updated this record " & _
         "since you began editing it. " & vbCrLf & vbCrLf & _
         "The record will be refreshed with the other " & _
         "user's changes before continuing."
        MsgBox strMsg, vbOKOnly + vbInformation, _
         "Record Refresh"
        
        ' This will cause record refresh
        Response = acDataErrContinue
        
    Case adhcErrDataChanged
        ' This error occurs if Access detects that
        ' another user has changed this record when we
        ' attempt to dirty the record. Fairly harmless since
        ' we haven't actually made any changes.
        strMsg = "Another user has updated this record " & _
         "since you began viewing it. " & vbCrLf & vbCrLf & _
         "The record will be refreshed with the other " & _
         "user's changes before continuing."
        MsgBox strMsg, vbOKOnly + vbInformation, _
         "Record Refresh"
         
        ' This will cause record refresh
        Response = acDataErrContinue
    Case Else
        ' Otherwise, let Access display standard error message
        Response = acDataErrDisplay
    End Select
    
    DoCmd.Hourglass False
    
Form_ErrorEnd:
    Exit Sub

Form_ErrorErr:
    ' It's possible to hit or own error while handling a
    ' data error. For example, someone could pessimstically
    ' lock the record while we are trying to update it.
    ' Report the error to the user and exit.
    MsgBox "Error " & Err.Number & ": " & Err.Description, _
     vbOKOnly + vbCritical, "Error Handler Error"

End Sub