ReSQL.ru
     
powered by simpleCommunicator - 2.0.51     © 2025 Programmizd 02
Мобильная версия    Контакт    Правила    FAQ    Помощь
Доб. в избранное | Игнор. тему | Прикреп. тему | Пометить прочит. / непрочит. | Фильтр
Форумы / Microsoft Access [игнор отключен] [закрыт для гостей] / Удобный диалог выбора каталога?
25 сообщений из 52, страница 1 из 3
  1  все
Удобный диалог выбора каталога?
    #32947445
Bagin
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Bagin
Участник
Здравствуйте!
Для диалога выбора каталога, я использую такой вариант:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
Private Sub btnDirForFlSelect_Click()
  Dim dr As FileDialog
  Set dr = Application.FileDialog(msoFileDialogFolderPicker)
  dr.Title = "Выбор каталога для новых отчетов"
  dr.ButtonName = "Выбрать"
  dr.AllowMultiSelect = False
  If dr.show = - 1  Then
      Me.DirForFl = dr.SelectedItems( 1 )
  End If
  Set dr = Nothing
End Sub
Для того, чтобы выбрать папку, нужно в нее войти. Хотелось бы, чтобы можно было просто выделить папку. Возможно кто-нибудь подскажет другие диалоговые окна или как модифицировать приведенный код?
...
Рейтинг: 0 / 0
04.03.2005, 22:06
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #32947520
Фотография Alexander G
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexander G
Участник
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
Private Type BROWSEINFO
  hOwner As Long
  pidlRoot As Long
  pszDisplayName As String
  lpszTitle As String
  ulFlags As Long
  lpfn As Long
  lParam As Long
  iImage As Long
End Type

Private Const BIF_RETURNONLYFSDIRS = &H1
Public Const OFN_EXPLORER = &H80000 '  new look commdlg
Public Const OFN_NOCHANGEDIR = &H8

Private Declare Function SHBrowseForFolder Lib "shell32.dll" Alias "SHBrowseForFolderA" (lpBrowseInfo As BROWSEINFO) As Long
Private Declare Function SHGetPathFromIDList Lib "shell32.dll" Alias "SHGetPathFromIDListA" (ByVal pidl As Long, ByVal pszPath As String) As Long

Public Function BrowseFolder(szDialogTitle As String) As String
 Dim x As Long, bi As BROWSEINFO, dwIList As Long
 Dim szPath As String, wPos As Integer

 With bi
  .hOwner = hWndAccessApp
  .lpszTitle = szDialogTitle
  .ulFlags = BIF_RETURNONLYFSDIRS
 End With

 dwIList = SHBrowseForFolder(bi)
 szPath = Space$( 512 )
 x = SHGetPathFromIDList(ByVal dwIList, ByVal szPath)

 If x Then
  wPos = InStr(szPath, Chr( 0 ))
  BrowseFolder = Left$(szPath, wPos -  1 )
 Else
  BrowseFolder = ""
 End If
End Function
...
Рейтинг: 0 / 0
05.03.2005, 00:15
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #32947752
ищ
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
ищ
Гость
"Для того, чтобы выбрать папку, нужно в нее войти"
неправда. у меня выбирает и без входа в нее
просто ставишь курсор.

могу дать еще простой вариант

Dim WSHShell, folder
On Error Resume Next
Set WSHShell = CreateObject("Shell.application")
Set folder = WSHShell.browseforfolder(0, "Выбор папки", 0, "D:\Access\Рабочая\")
If Not Err.Number = 91 Then MsgBox folder.Title
Set WSHShell = Nothing
...
Рейтинг: 0 / 0
05.03.2005, 10:07
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #32947861
Bagin
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Bagin
Участник
Alexander GСпасибо, получилось. Только так и не понял, как можно инициализировать каталог, на котором он сразу бы открывался.
...
Рейтинг: 0 / 0
05.03.2005, 11:04
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #32947913
Bagin
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Bagin
Участник
ищ"Для того, чтобы выбрать папку, нужно в нее войти"
неправда. у меня выбирает и без входа в нее
просто ставишь курсор.

могу дать еще простой вариант

Dim WSHShell, folder
On Error Resume Next
Set WSHShell = CreateObject("Shell.application")
Set folder = WSHShell.browseforfolder(0, "Выбор папки", 0, "D:\Access\Рабочая\")
If Not Err.Number = 91 Then MsgBox folder.Title
Set WSHShell = NothingЯ специально после Вашего сообщения проверил, необходимо в нее войти. У меня аксес2003, вин2000.
А за вариант спасибо, с помощью folder.Dir можно вернуть выбранный каталог,
но та же проблема, не могу задать начальный каталог, если его задать, например: WSHShell.browseforfolder(0, "Выбор папки", 0, "Начальный каталог"), то нельзя увидеть то, что находится выше. Доступ ко всему можно получить только в том случае, если "Начальный каталог" не существует.
...
Рейтинг: 0 / 0
05.03.2005, 11:21
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #32947938
Bagin
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Bagin
Участник
Bagin ищ"Для того, чтобы выбрать папку, нужно в нее войти"
неправда. у меня выбирает и без входа в нее
просто ставишь курсор.
..........Я специально после Вашего сообщения проверил, необходимо в нее войти. У меня аксес2003, вин2000.
Прошу прощения, оказывается действительно как Вы и говорили, я спутал с открытием в указанном каталоге. Спасибо!
...
Рейтинг: 0 / 0
05.03.2005, 11:32
| Ответить | Цитировать | Написать  
Период между сообщениями больше года.
Удобный диалог выбора каталога?
    #33844666
Agilyera
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Agilyera
Гость
Попробовал оба варианта поставить в код кнопки для выбора каталога, постоянно выходят ошибки. Прошу помощи
...
Рейтинг: 0 / 0
11.07.2006, 12:41
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #33845192
Фотография Alexander G
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexander G
Участник
...
Рейтинг: 0 / 0
11.07.2006, 14:48
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #33845639
Анатолий ( Киев )
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Анатолий ( Киев )
Гость
В Access (начиная с 2000) работает и такой метод:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
Public Function SelectFolderDialogOffice(Optional strInitialDir As String, _
    Optional strTitle As String = "Выбор папки", _
    Optional ByVal strButtonName As String, _
    Optional ByVal hWnd As Long) As String
Dim ret As Long, strFile As String
    
    WizHook.Key =  51488399 
 
 If hWnd =  0  Then hWnd = Application.hWndAccessApp
    strFile = String( 255 , Chr( 0 ))
    
    ret = WizHook.GetFileName(hWnd, "", strTitle, strButtonName, _
        strFile, strInitialDir, "*.*",  0 ,  0 ,  32 , True)
        
' Проверим, не произошел ли возврат в результате нажатия клавиши Esc (-302)
 If ret <> - 302  Then
    SelectFolderDialogOffice = strFile
 End If
End Function
Здесь вам и панель покрасивше, и стартовая папка, и надпись на кнопке вместо "OK". С другой комбинацией аргументов это может быть диалог открытия или сохранения файла (например 0 вместо 32).
Подробнее можно найти на этом сайте. Ищите "WizHook".
...
Рейтинг: 0 / 0
11.07.2006, 16:35
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #33845974
Agilyera
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Agilyera
Гость
...
Рейтинг: 0 / 0
11.07.2006, 17:58
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #33850087
Agilyera
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Agilyera
Гость
Ребята, у меня с Аксесом не лады. Жить осталось 2 дня ))). VB не знаю совсем ....

agilmeister собака gmail.com

помогите пожалуйста
...
Рейтинг: 0 / 0
13.07.2006, 10:51
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #33850855
Фотография Alexander G
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexander G
Участник
И пример выложил... Чего еще надо... Тогда вам в форум Работа - за некоторое количество денежных знаков вам могут сделать все.
...
Рейтинг: 0 / 0
13.07.2006, 13:36
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #33851794
Agilyera
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Agilyera
Гость
Прикол в том что я попытался сделать такой же файл с теми же модулями и кнопками и ничего не получилось.

Но за помощь спасибо
...
Рейтинг: 0 / 0
13.07.2006, 16:52
| Ответить | Цитировать | Написать  
Период между сообщениями больше года.
Удобный диалог выбора каталога?
    #35286308
frolson
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
frolson
Гость
Ребят, нужна помощь!
Есть форма, в которой отображается содержание нескольких таблиц, например:
препод | методичка | вид занятия

При этом на машине есть папки где хранятся методички отсортированые по видам занятия, например:
C:\лабораторные
C:\контрольные
C:\практические

Создал таблицу где хранятся эти пути к папкам, и эта таблица связана с таблицей "вид занятия" по коду. Необходимо сделать так, чтоб при нажатии на кнопку в форме открывалась папка соответствующая виду занятия, который указан в той строчке где находится курсор, например если курсор находится на строчке:
Иванов | анализ систем | лабораторные
то при нажатии на кнопку должна открыться папка - C:\лабораторные

как это можно осуществить?
...
Рейтинг: 0 / 0
29.04.2008, 15:54
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #35286550
Анатолий ( Киев )
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Анатолий ( Киев )
Гость
Есть такая API функция ShellExequte. Кроме всех прочих полезностей может открыть указанную папку.
...
Рейтинг: 0 / 0
29.04.2008, 16:43
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #35286707
Анатолий ( Киев )
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Анатолий ( Киев )
Гость
Или так (проще):
Код: plaintext
1.
2.
3.
Dim WSHShell As Object  
    Set WSHShell = CreateObject("WScript.Shell")
    WSHShell.Run """C:\My Documents""",  3    'Путь с пробелами должен быть в кавычках.
    Set WSHShell = Nothing
...
Рейтинг: 0 / 0
29.04.2008, 17:15
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #35767925
Alexey2006
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey2006
Гость
Анатолий ( Киев )В Access (начиная с 2000) работает и такой метод:
Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
Public Function SelectFolderDialogOffice(Optional strInitialDir As String, _
    Optional strTitle As String = "Выбор папки", _
    Optional ByVal strButtonName As String, _
    Optional ByVal hWnd As Long) As String
Dim ret As Long, strFile As String
    
    WizHook.Key =  51488399 
 
 If hWnd =  0  Then hWnd = Application.hWndAccessApp
    strFile = String( 255 , Chr( 0 ))
    
    ret = WizHook.GetFileName(hWnd, "", strTitle, strButtonName, _
        strFile, strInitialDir, "*.*",  0 ,  0 ,  32 , True)
        
' Проверим, не произошел ли возврат в результате нажатия клавиши Esc (-302)
 If ret <> - 302  Then
    SelectFolderDialogOffice = strFile
 End If
End Function
Здесь вам и панель покрасивше, и стартовая папка, и надпись на кнопке вместо "OK". С другой комбинацией аргументов это может быть диалог открытия или сохранения файла (например 0 вместо 32).
Подробнее можно найти на этом сайте. Ищите "WizHook".
Анатолий, спасибо за пример, а как сделать чтобы файлы были видны и их названия можно было бы редактировать.
...
Рейтинг: 0 / 0
20.01.2009, 18:34
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #35767987
Анатолий ( Киев )
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Анатолий ( Киев )
Гость
Alexey2006, я же написал, что если в предпоследнем аргументе заменить 32 на 0, то получим диалог открытия файла, т.е. вместо ..., 32, True) указать ..., 0, True)
Добавлю, что ..., 0, False) - диалог сохранения файла.
Еще у меня получался мультивыбор и предосмотр картинок.
...
Рейтинг: 0 / 0
20.01.2009, 19:15
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #35768484
Alexey2006
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Alexey2006
Гость
спасибо все получилось!
...
Рейтинг: 0 / 0
21.01.2009, 08:48
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #35769025
vladK
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
vladK
Участник
Что бы топик можно было считать почти ФАК'ом по вызову диалога открытия папки, дополню.

1. Более полное описание (от Script Guys) варианта с Shell.Application

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
Const WINDOW_HANDLE =  0 
Const OPTIONS =  0 

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.BrowseForFolder _
    (WINDOW_HANDLE, "Select a folder:", OPTIONS, "C:\") 

If objFolder Is Nothing Then
    Wscript.Quit
End If

Set objFolderItem = objFolder.Self
objPath = objFolderItem.Path

Wscript.Echo objPath

We begin by defining a pair of constants: WINDOW_HANDLE and OPTIONS. The WINDOW_HANDLE constant represents a numeric ID that needs to be assigned to the dialog box we’re going to display; for scripts this value should always be  0 . Setting OPTIONS to  0  means we’re going to display a very simple dialog box, one that limits users to selecting from a list of folders. Alternatively, we could have set OPTIONS to &H10&. In that case our dialog box would include a text area where users could type a folder path.

At other times, however, you’d like to give users the opportunity to select any folder located anywhere on the file system. Is that possible?
Const MY_COMPUTER = &H11&
Const WINDOW_HANDLE =  0 
Const OPTIONS =  0 

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace(MY_COMPUTER)
Set objFolderItem = objFolder.Self
strPath = objFolderItem.Path

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.BrowseForFolder _
    (WINDOW_HANDLE, "Select a folder:", OPTIONS, strPath) 
      
If objFolder Is Nothing Then
    Wscript.Quit
End If

Set objFolderItem = objFolder.Self
objPath = objFolderItem.Path

Wscript.Echo objPath

2. Вариант применимый только начиная с XP (более полный и красивый "диалог")

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
Set objDialog = CreateObject("UserAccounts.CommonDialog")

objDialog.Filter = "All Files|*.*"
objDialog.InitialDir = "C:\"
intResult = objDialog.ShowOpen
 
If intResult =  0  Then
    Wscript.Quit
Else
    Wscript.Echo objDialog.FileName
End If

3. Очень простой вариант; требует уверенности что у пользователя стоит Excel

Код: plaintext
1.
2.
3.
4.
5.
6.
7.
Public Sub g()
Dim aas As Object, path_db As String
Set aas = CreateObject("excel.application")
path_db = aas.GetOpenFilename("База данных (*.mdb), *.mdb")
Set aas = Nothing
MsgBox path_db
End Sub
...
Рейтинг: 0 / 0
21.01.2009, 12:11
| Ответить | Цитировать | Написать  
Период между сообщениями больше года.
Удобный диалог выбора каталога?
    #37706083
Фотография natalitvinenko
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
natalitvinenko
Участник
vladK2. Вариант применимый только начиная с XP (более полный и красивый "диалог")
3. Очень простой вариант; требует уверенности что у пользователя стоит Excel


Оба варианта, к сожалению, выбирают файл, а не каталог.
...
Рейтинг: 0 / 0
15.03.2012, 10:39
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #37706096
Фотография natalitvinenko
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
natalitvinenko
Участник
ищ
могу дать еще простой вариант


Для полноты картины замечу, что данный способ работает и в ...Jscript (например, рисуем кнопочку и в разделе <script> пишем таковую функцию, которую потом и вешаем на кнопочку):
Код: javascript
1.
2.
3.
4.
5.
6.
7.
8.
9.
 function kliik()
 {
  var WSHShell = new ActiveXObject("Shell.application");
  var folder = WSHShell.browseforfolder(0, "Выбор папки", 0, "D:/Access/Рабочая/"); 
  if(folder!== 91)
  {
  alert(folder.Title);
  };
 }
...
Рейтинг: 0 / 0
15.03.2012, 10:50
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #37706474
Фотография natalitvinenko
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
natalitvinenko
Участник
vladKЧто бы топик можно было считать почти ФАК'ом по вызову диалога открытия папки, дополню.

1. Более полное описание (от Script Guys) варианта с Shell.Application


Вариант для Jscript
Код: javascript
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
function kliik()
 {
var MY_COMPUTER = 0;//"&H11&";
var WINDOW_HANDLE = 0;
var OPTIONS = 0;

var objShell = new ActiveXObject("Shell.application");
var objFolder = objShell.Namespace(MY_COMPUTER);
var objFolderItem = objFolder.Self;
strPath = objFolderItem.Path;

var objShell = new ActiveXObject("Shell.application");
var objFolder = objShell.BrowseForFolder(WINDOW_HANDLE, "Select a folder:", OPTIONS, strPath); 
      
if(objFolder!==null)
{
var objFolderItem = objFolder.Self;
objPath = objFolderItem.Path;
alert(objPath);
dirdir.value = objPath;
 } ;
}
...
Рейтинг: 0 / 0
15.03.2012, 13:20
| Ответить | Цитировать | Написать  
Период между сообщениями больше года.
Удобный диалог выбора каталога?
    #39802779
Фотография natalitvinenko
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
natalitvinenko
Участник
Подниму- ка эту тему, дабы не плодить другие. Win7, jscript. Открываю окошко вышеназваным методом, как часть другой программы (hta).
Код: javascript
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
var fso=new ActiveXObject("Scripting.FileSystemObject");
var objShell = new ActiveXObject("shell.application");
        var ssfWINDOWS = 36;
        var objFolder;
        
        objFolder = objShell.BrowseForFolder(0, "Example", 16384);
        if (objFolder != null)
        {
            pppath=objFolder.Self.path;
        Ex_ex = fso.GetExtensionName(pppath);
	pppath_GetFileName=fso.GetBaseName(pppath);
        }
	else
	{
		alert("Никакой файл не выбран! Я закрываюсь, пробуйте еще раз:-)");
        self.close();
	};


И все у меня хорошо и замечательно. Но программа пошла в народ. В народе она успешно работает на Win10, но не хочет работать на winXP. Спрос у Гугли приводит к списку советов вида "обновите все"- браузет, пакеты и т.п. В связи с чем есть вопросы:
1) Что минимального надо сделать, чтобы заработало на XP& Или там только долгие и упорные танцы?
2) Есть ли более древние чтоли методы, которые бы были пригодны для ХР?
Спасибо
...
Рейтинг: 0 / 0
17.04.2019, 13:49
| Ответить | Цитировать | Написать  
Удобный диалог выбора каталога?
    #39802917
Фотография Joss
Скрыть профиль Поместить в игнор-лист Сообщения автора в теме
Joss
Участник
А попытаться приспособить вот это
Код: vbnet
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
'---------------------------------------------------------------------------------------
' Procedure : fnGetFolder
' DateTime  : 17.08.2006 16:12
' Author    : Joss
' Purpose   : выбор папки
'---------------------------------------------------------------------------------------
'
Public Function fnGetFolder() As String

    Dim WSHShell As Object, objFolder As Object
    Dim P1, P2
' Я не знаю всех значений параметров Р1 и Р2
' Опытным путем установлено следующее
' P1=0 - отображаются Рабочий стол, Мой компьютер, Сеть и "Корзина"
' P1=1 - "Корзина" не отображается
' P1=2 - "Корзина" отображается, в "Моем компьютере" выводится "Панель Управления"
' P2 определяет верхний уровень отображения. Его можно задать как строку символов
' Пример - "C:\". Или числом. Проверено для ХР
' Р2=0 - Рабочий стол                        P2=10 - Корзина
' P2=1 - Интернет Explorer (недопустимо)     P2=11 - Главное меню
' P2=2 - Программы                           Р2=12 - Рабочий стол
' P2=3 - Панель управления (недопустимо)     Р2=13 - Моя музыка
' P2=4 - Принтеры и факсы (недопустимо)      Р2=14 - Мои видеозаписи
' P2=5 - Мои Документы                       Р2=15 - Рабочий стол
' P2=6 - Избранное                           Р2=16 - Рабочий стол
' P2=7 - Автозагрузка                        Р2=17 - Мой Компьютер
' P2=8 - недавние Документы                  Р2=18 - Сетевой окружение
' P2=9 - SendTo                              Р2=19 - NetHood
' Р2=20 - Fonts                              Р2=21 - Templates
' остальные можете вычислить сами. Или найти в документации

   On Error GoTo fnGetFolder_Error
    
    P1 = 1
    P2 = 0

    Set WSHShell = CreateObject("Shell.application")
    Set objFolder = WSHShell.BrowseForFolder(0, "Выбор папки", P1, P2)
    fnGetFolder = objFolder.self.Path
    Set WSHShell = Nothing
    Set objFolder = Nothing
    
   On Error GoTo 0
Exit_fnGetFolder:
   Exit Function

fnGetFolder_Error:
   
   Set WSHShell = Nothing
   Set objFolder = Nothing
   Select Case Err.Number
       Case 91
           fnGetFolder = ""
           Resume Exit_fnGetFolder
       Case Else
           MsgBox "Ошибка " & Err.Number & " (" & Err.Description & ") в процедуре fnGetFolder"
           Resume Exit_fnGetFolder
   End Select

End Function

Под Win XP она отлично работала.
...
Рейтинг: 0 / 0
17.04.2019, 16:04
| Ответить | Цитировать | Написать  
25 сообщений из 52, страница 1 из 3
  1  все
Форумы / Microsoft Access [игнор отключен] [закрыт для гостей] / Удобный диалог выбора каталога?
Целевая тема:
Создать новую тему:
Автор:
Закрыть
Цитировать
Найденые пользователи ...
Разблокировать пользователей ...
Читали тему (0):
Читали форум (0):
Пользователи онлайн (0):
Польз. соглашение
NoSQL.ru       Новости, Чат       Фотоальбом: Участники, Встречи
Закрыть
start [/forum/topic.php?fid=45&msg=32947752&tid=1610749]:
 0ms
get settings:
 9ms
get forum list:
 13ms
check forum access:
 4ms
check topic access:
 4ms
track hit:
 1431ms
get topic data:
 10ms
get forum data:
 3ms
get page messages:
 53ms
get tp. blocked users:
 1ms
others: 12ms
total:  1540ms
созд. / загр.: 1540ms
x
x
Закрыть


Просмотр
0 / 0
Close
Debug Console [Select Text]