Public Sub FindCurRec(frm As Form, key As Control, Optional keyFind As Long = - 1 , Optional CtlFocus As Control = Nothing)
'функция делает Обновление (Requery) в форме frm и возвращается на запись, на которой она стояла перед вызовом Обновления (поиск по полю, которое содержит ключ)
'frm - обновляемая форма
'key - контрол который содержит ключевое поле. Это значение будет искаться после обновления, если не указан keyFind
'keyFind - если это значение <>-1, то после обновления в поле key будем искать это значение.
'CtlFocus - контрол, который должен будет получить фокус после выполнения поиска
  '(в случаях, когда поле key невидимое и находится не в области даных,
  'то после поиска не удается этому контролу вернуть невидимость, если не задан явно контрол,
  'который должен получить фокус после обновления)


'Не обработан вариант, когда контрол key имеет значение Enabled = false. (обработать так же как и невидимость)

On Error Resume Next
'On Error GoTo mEr
  Dim n As Variant 'значение, хранящееся в контроле key
  Dim nVis As Boolean 'признак, видимое ли поле key
  Dim curCtl As Control 'контрол, в котором сейчас фокус
  
  frm.Painting = False
  If CtlFocus Is Nothing Then 'если не задан явно контрол, который должен получить фокус после обновления, то
    Set curCtl = Screen.ActiveControl ' берем активный контрол
  Else
    Set curCtl = CtlFocus
  End If
  'если не задано явно значение, которое надо найти в контроле key, то сохраняем текущее значение контрола
  If keyFind = - 1  Then n = Nz(key.Value) Else n = keyFind
  frm.Requery 'то, ради чего мы здесь
  If key.Visible = False Then 'если контрол невидимый, то сделаем его видимым и изменим признак
    nVis = True
    key.Visible = True
  End If
  key.Parent.SetFocus 'фокус - форме, владеющей контролом (если вдруг мы обновляем подчиненную форму)
  key.SetFocus  'фокус контролу
  DoCmd.FindRecord n, acEntire, , , , acCurrent 'ищем нужное значение контрола
  curCtl.Parent.SetFocus 'передаем фокус на нужный контрол
  curCtl.SetFocus
  If nVis = True Then key.Visible = False 'возвращаем состояние невидимости для key, если оно было невидимым
  frm.Painting = True
  
'  Exit Sub
'mEr:  MsgBox Err.Description
End Sub

Public Sub BackToCurRec(frm As Form)
'возврат на текущую позицию в форме. Если была удалена последняя запись, то вернется на первую
  On Error Resume Next
  Dim n As Long
  DoCmd.Echo  0 
  With frm
    .Painting = False
    n = frm.SelTop
   .Requery
    frm.SelTop = n
    .Painting = True
  End With
  DoCmd.Echo - 1 
End Sub