Dim outlItem As Outlook.MailItem, outlObj As Outlook.Application
        Set outlObj = CreateObject("Outlook.Application")
        Set outlItem = outlObj.CreateItem(olMailItem)
        outlItem.Subject = "Тест"
        outlItem.Attachments.Add "Тест.xls"
        outlItem.Importance = olImportanceHigh
        outlItem.To = "Список адресатов"
        outlItem.Body = "Тест"
        outlItem.Display
        Set outlObj = Nothing

Public Function sendEmail(emailTo As String, emailSubject As String, htmlBody As String) As Boolean
On Error GoTo Err_sendEmail
    Dim oMSG As Object
    Dim oConfig As Object
    Dim CFields As Object
    Dim strBody As String
    Dim arr() As Byte
    
    DoCmd.Hourglass True
    
    Set oMSG = CreateObject("CDO.Message")
    Set oConfig = CreateObject("CDO.Configuration")
    
    Set CFields = oConfig.Fields
    Set oMSG.Configuration = oConfig
    
    CFields("http://schemas.microsoft.com/cdo/configuration/sendusing") =  2 
    CFields("http://schemas.microsoft.com/cdo/configuration/smtpserver") = smtpserver
    CFields("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") =  1 
    
    CFields("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = tcpport   '465
    
    CFields("http://schemas.microsoft.com/cdo/configuration/sendusername") = sendusername
    CFields("http://schemas.microsoft.com/cdo/configuration/sendpassword") = sendpassword
    
    CFields("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = usessl
    
    CFields.Update
    
    oMSG.To = emailTo
    oMSG.FROM = sendusername

    oMSG.Subject = emailSubject
    oMSG.BodyPart.Charset = "UTF-8"
    
    oMSG.htmlBody = htmlBody
    oMSG.Send
    
    sendEmail = True

Exit_sendEmail:
    Set CFields = Nothing
    Set oConfig = Nothing
    Set oMSG = Nothing
    DoCmd.Hourglass False
    Exit Function

Err_sendEmail:
    DoCmd.Hourglass False
    MsgBox "An attempt to send a E-Mail message is failed. Err = " & Err.Number & vbCrLf & Err.Description & vbCrLf & _
        "Please configure the E_Mail config!" & vbCrLf & _
            "Open the system parameters form, choose warnings tab and click the E-Mail config button", vbExclamation, ApplName
    
    WriteLog "An attempt to send a E-Mail message is failed. Err = " & Err.Number & vbCrLf & Err.Description
    Resume Exit_sendEmail
    
End Function