* Сначала определяем константы

#DEFINE BLOCK_END "###"

#DEFINE LINE_YEAR "ГодПериодОтч:"
#DEFINE LINE_DOC "ДокПредст:"
#DEFINE LINE_OKEI "ОКЕИ:"
#DEFINE LINE_QTY "КолПокФОтч:"
#DEFINE LINE_OKATO "ОКАТО:"

#DEFINE LINE_KBK "КБК:"
#DEFINE LINE_SUM_1 "СумПл1:"
#DEFINE LINE_SUM_2 "СумПл2:"
#DEFINE LINE_SUM_3 "СумПл3:"

* Таблица заголовка
IF FILE('fns.dbf')
	DELETE FILE fns.dbf
endif 

* Поле fns_id - это идентификатор записи
CREATE TABLE fns (fns_id n( 10 ), ;
		g_p_ot c( 4 ), ;
		doc_p c( 4 ), ;
		okey c( 4 ), ;
		p_f_ot c( 3 ), ;
		okato c( 13 ), ;
		kbk_s c( 20 ), ;
		kbk_n c( 20 ) )

* Таблица платежей
IF FILE('platezh.dbf')
	DELETE FILE platezh.dbf
endif 

CREATE TABLE platezh (fns_id n( 10 ), ;
		kbk c( 20 ), ;
		platezh1 n( 13 , 2 ), ;
		platezh2 n( 13 , 2 ), ;
		platezh3 n( 13 , 2 ) )

* Временная таблица с содержимым текстового файла
create cursor temp (line c( 130 ))

* Наполняем временную таблицу
LOCAL laFiels( 1 ), lnNextFile, lcFileName
rt=adir(laFiels,"*.023") 
for lnNextFile= 1  to m.rt
	lcFileName = laFiels[m.lnNextFile, 1 ]
	append from (m.lcFileName) TYPE SDF as  866 
ENDFOR

* Переменная, которая содержит признак того, 
* что текущая строка - это первая строка нового блока
LOCAL llFirstLine
llFirstLine = .T.

* Сравнение строк осуществляем до истечения символов в более короткой строке
SET EXACT OFF

* Сканируем таблицу 
select temp
SCAN

* Проверяем, что текущая строка - это конец блока
IF temp.line = BLOCK_END
	* Следующая строка, будет первой строкой нового блока
	llFirstLine = .T.
	* Больше с данной строкой делать нечего. Берем следующую
	LOOP
ENDIF

* Если данная строка - это начало нового блока, то, 
* возможно, надо создать новую строку
IF m.llFirstLine = .T.
	DO CASE
	* Новая строка заголовка
	CASE InList(temp.line, LINE_YEAR, LINE_DOC, LINE_OKEI, LINE_QTY) 
		select fns 
		append blank
		* Здесь надо сформировать код записи новой строки
		* Пока просто присваиваю физический номер записи
		* хотя это не очень хорошо
		replace fns_id with Recno()
	* Это НЕ новая строка, а продолжение старой
	CASE temp.line = LINE_OKATO
		* Ничего не делаем
	* Новая строка платежей
	CASE InList(temp.line, LINE_KBK, LINE_SUM_1, LINE_SUM_2, LINE_SUM_3)
		select platezh
		append blank
		replace fns_id with fns.fns_id
	ENDCASE
	* Сбрасываю признак новой строки
	m.llFirstLine = .F.
ENDIF

* Теперь собственно запись информации в соответсвующие поля
DO CASE
CASE temp.line = LINE_YEAR
	select fns
	replace g_p_ot with strTran(temp.line,LINE_YEAR,"")
CASE temp.line = LINE_DOC
	select fns
	replace doc_p with strTran(temp.line,LINE_DOC,"")
CASE temp.line = LINE_OKEI
	select fns
	replace okey with strTran(temp.line,LINE_OKEI,"")
CASE temp.line = LINE_QTY
	select fns
	replace p_f_ot with strTran(temp.line,LINE_QTY,"")
CASE temp.line = LINE_OKATO
	select fns
	replace okato with strTran(temp.line,LINE_OKATO,"")
CASE temp.line = LINE_KBK
	select platezh
	replace kbk with strTran(temp.line,LINE_KBK,"")
CASE temp.line = LINE_SUM_1
	select platezh
	replace platezh1 with val(strTran(temp.line,LINE_SUM_1,""))
CASE temp.line = LINE_SUM_2
	select platezh
	replace platezh2 with val(strTran(temp.line,LINE_SUM_2,""))
CASE temp.line = LINE_SUM_3
	select platezh
	replace platezh3 with val(strTran(temp.line,LINE_SUM_3,""))
ENDCASE


ENDSCAN