PUBLIC o
o = CREATEOBJECT('frm')
o.show()

DEFINE CLASS frm as Form 
name = 'frm'
width = 375
PROCEDURE load
CREATE CURSOR test (f1 numeric(10,5), f2 c(30))
SELECT test 
INDEX on f1 TAG f1
FOR i = 1 TO 5
	INSERT INTO test VALUES (i, TRANSFORM(6 - i))
ENDFOR 
GO TOP IN test 
ENDPROC 
PROCEDURE init
WITH this

	.AddObject('grd1','grd')
	.grd1.top = 0
	.grd1.left = 0
	.grd1.Height = .Height 
	.grd1.Width = .Width
	
	.grd1.visible = .t.
	
	.grd1.Column1.AddObject('cmd1','cmd')
	.grd1.Column1.RemoveObject('Text1')
	.grd1.Column1.cmd1.Visible = .t.
	.grd1.Column1.CurrentControl = 'cmd1'
	.grd1.Column1.Sparse = .f.
	
	 
ENDWITH 
ENDPROC 
ENDDEFINE 

DEFINE CLASS cmd as CommandButton 
name = 'cmd'
Caption = 'Тащи меня'
oledragmode = 1
height = 25
width = 110
f1 = 0

PROCEDURE MouseDown
LPARAMETERS nButton, nShift, nXCoord, nYCoord
this.f1 = test.f1
ENDPROC 
ENDDEFINE 

DEFINE CLASS grd as Grid 
name = 'grd'
columncount = 2
oledropmode = 1
HighlightStyle  = 2
Highlight = .t.
AllowCellSelection = .t.
width = 241

PROCEDURE oledragdrop
LPARAMETERS oDataObject, nEffect, nButton, nShift, nXCoord, nYCoord
LOCAL laArr[ 1 ], lnEll, bb 

DO CASE
	CASE oDataObject.GetFormat( "VFP Source Object" )
* пытаемся получить ссылку на обьект
		aa = oDataObject.GetData( "VFP Source Object", @laArr )
		WAIT WINDOW 'Уф - донесли' NOWAIT 
		
		DO CASE 
		CASE (UPPER(aa.BaseClass) == 'COMMANDBUTTON')
			m.bb = test.f1
			replace f1 WITH m.bb - aa.f1 * 0.01 FOR f1 = aa.f1  IN test
			LOCATE FOR f1 = m.bb - aa.f1 * 0.01
		ENDCASE 

		NODEFAULT
		
		this.Refresh() 
		
	ENDCASE 
ENDPROC 

PROCEDURE oledragover
LPARAMETERS oDataObject, nEffect, nButton, nShift, nXCoord, nYCoord, nState

* Проверяем 
IF oDataObject.GetFormat( "VFP Source Object" )
	WAIT WINDOW 'Несём, что надо' nowait
	* пытаемся выделить то что под курсором
	LOCAL nWhere_Out, nRelRow_Out, nRelCol_Out,	nView_Out 
	
	nWhere_Out = 0
	nRelRow_Out = 0
	nRelCol_Out = 0
	nView_Out = 0
	WITH this
	IF .GridHitTest(nXCoord, nYCoord ;
   , @nWhere_Out , @nRelRow_Out , @nRelCol_Out , @nView_Out)
   

		IF nWhere_Out = 3
		   .ActivateCell(nRelRow_Out, nRelCol_Out)
		   .Refresh()
   
		ENDIF 
	ENDIF 
	ENDWITH 

ELSE
	WAIT WINDOW 'Не то' nowait
ENDIF 
ENDPROC 
ENDDEFINE