*  
 * Procedure Mail  
 * Пример  
 *  
 *!*	Dimension aa[ 2 ]  
 *!*	aa[ 1 ]='c:\work\exec.ini'  
 *!*	aa[ 2 ]='c:\work\exec.mpr'  
 *!*	=mail("aaa@bbb.ccc","","hello~iam@server.ru",@aa)  
 *!*	или   
 *!*	=mail("aaa@bbb.ccc;bbb@ccc.ddd","","hello~iam@server.ru","c:\work\exec.ini)  
    
    
  Lparameters m.Address, m.Subject, m.Text, Att  
  If Empty(m.Address)  
  	Messagebox("Не указан адрес получателя",64,_SCREEN.Caption)  
  	Return .F.  
  Endif  
  m.Subject=Iif(Empty(m.Subject),"",m.Subject)  
  m.Text=Iif(Empty(m.Text),"",m.Text)  
 * Преобразуем спецсимвол в разделитель строки  
  m.Text=Strtran(m.Text,"~",Chr(13)+Chr(10))  
    
  Local 	MSession As MSMAPI.MAPISession  
  Local	MMessage As MSMAPI.MAPIMessages  
    
  m.curdir=Fullpath(".")		&& Outlook Express не восстанавливает путь  
  MSession=Createobject("MSMAPI.MAPISession")  
  MMessage=Createobject("MSMAPI.MAPIMessages")  
  With MSession  
  	.DownLoadMail= .F.  
  	.NewSession= .T.  
  	.LogonUI= .T.  
  	.SignOn  
    
  	If .SessionID > 0  
    
  		MMessage.SessionID=.SessionID  
    
  		With MMessage  
  			.MsgIndex=-1  
    
  			If ';' $ m.Address  
  				For i=1 To GetWordCount(m.Address,';')  
  					.RecipIndex=i-1  
  					.RecipAddress=Alltrim(GetWordNum(m.Address,i,';'))  
  					.RecipType=1  
  					.ResolveName  
  				Next  
  			Else  
  				.RecipAddress=m.Address  
  				.ResolveName  
  			Endif  
    
  			.MsgSubject=m.Subject  
  			.MsgNoteText=m.Text  
    
  			If Type('att[1]')="U"  
 				* аттачмент не массив  
  				If ';' $ Att  
  					For i= 1  To GetWordCount(Att,';')  
  						.AttachmentIndex=i- 1   
  						.AttachmentPathName=Alltrim(GetWordNum(Att,i,';'))  
  					Next  
  				Else  
  					If not Empty(Att)  
  						.AttachmentPathName=Att  
  					EndIf  
  				Endif  
  			Else  
  				For i= 1  To Alen(Att)  
  					.AttachmentIndex=i- 1   
  					.AttachmentPathName=Att  
  				Next  
  			Endif  
    
  			.MsgReceiptRequested=.T.  
  			.Send()  
    
  		Endwith  
  	Endif  
  	.SignOff  
  Endwith  
    
  Cd (m.curdir)