DEFINE CLASS adoEHandler AS Form
IMPLEMENTS RecordsetEvents IN "adodb.recordset"
***************************************
* тут описание тела класса....
***************************************

*********************************************************
DEFINE CLASS adoEHandler AS Form
*********************************************************
IMPLEMENTS RecordsetEvents IN "adodb.recordset"
*********************************************************
*
*	Пример использования класса
*
*		
*			rsAdo = CreateObject( "ADODB.Recordset" )
*		
*			&& .....
*		
*			rsAdo.CursorLocation= adUseClient
*			rsAdo.Properties("Initial Fetch Size") =  10 		&& или другое значение >  0 
*											    &&   такое вы сможете в фоксе?
*
*			oEvents = NEWOBJECT("adoEHandler")		   && привязка обработчика
*			rsAdo.Open(,,,, adAsyncFetch)
*			EVENTHANDLER(rsAdo, oEvents)
*
*			DO WHILE .T.
*				IF	adStateOpen = rsAdo.State	;
*				OR	oEvents.isCanceled
*					EXIT
*				ENDIF
*				wPause( 0 . 3 )	&& пауза  0 . 3  сек
*				DOEVENTS
*			ENDDO
*
*			&& Дальше работаем с rsAdo
*
*********************************************************

	ADD OBJECT LabelStatus	 AS Label WITH Left= 10 , Top= 10 , AutoSize=.T., Caption="" &&, WordWrap=.T.
	ADD OBJECT ShapeProgress AS Shape WITH Left= 10 , Top= 40 , Height =  10 , Width= 0 , BackColor=RGB( 0 ,  0 ,  128 )
	ADD OBJECT LabelRCount	 AS Label WITH Left= 10 , Top= 60 , AutoSize=.T., Caption=""
	ADD OBJECT ButtonStop	 AS CommandButton WITH Left= 300 , Top= 60 , Caption="Stop", Visible=.T.
	ADD	OBJECT TimerShow	 AS Timer WITH Interval= 2000 
	
	RecordsCount 	=  0 
	isCanceled	  = .F.

	PROCEDURE Init
		This.Caption 		= "Получение данных, состояние..."
		This.WindowType		=  1  
		This.AutoCenter		= .T.
		This.AlwaysOnTop	= .T.
		This.HalfHeightCaption= .T. 
		This.ControlBox		= .F.
		This.BorderStyle	=  2  
		This.Height			=  80 
		This.Width			=  400 
		
		BINDEVENT(This.TimerShow, "Timer", ;
							This, "SetVisible" )
		BINDEVENT(This.ButtonStop, "Click", ;
							This, "StopProcess" )
							
		_Screen.MousePointer=  11 
		DOEVENTS
	*
	***


	PROCEDURE Destroy
		sbMessageStartLoad( ;
			"Загружено записей: " + ;
						TRANSFORM(This.RecordsCount) )
	*
	***

	
	PROCEDURE SetVisible
		This.Visible	= .T.
		
		This.TimerShow.Enabled = .F.
		BINDEVENT(This.TimerShow, "Timer", ;
						This, "IncrementProgressBar")
		This.TimerShow.Enabled = .T.
		
		_Screen.MousePointer=  0 
	*
	***


	PROCEDURE StopProcess
		This.isCanceled	= .T.
		This.ButtonStop.Enabled = .F.
		DOEVENTS
	*
	***


	PROCEDURE IncrementProgressBar
		This.ShapeProgress.Width = This.ShapeProgress.Width +  2 
		This.LabelRCount.Caption = "Получено записей: " + ;
									TRANSFORM(This.RecordsCount)
				
		IF	This.ShapeProgress.Width > (This.Width -  20 )
			This.ShapeProgress.Width =  0 
		ENDIF
		DOEVENTS
	*
	***
		

	PROCEDURE Recordsetevents_WillChangeField(	;
					cFields		AS Number @, 	;
					Fields		AS VARIANT @, 	;
					adStatus	AS VARIANT @, 	;
					pRecordset	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', начало обновления'
	*	wPause ( 1 )
	***	
	
	PROCEDURE Recordsetevents_FieldChangeComplete(	;
					cFields 	AS Number @, 	;
					Fields 		AS VARIANT @, 	;
					pError 		AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @)		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', завершение обновления'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_WillChangeRecord(	;
					adReason 	AS VARIANT @, 	;
					cRecords 	AS Number @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', обновление записи'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_RecordChangeComplete(	;
					adReason 	AS VARIANT @, 	;
					cRecords 	AS Number @, 	;
					pError 		AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', обновление записи завершено'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_WillChangeRecordset(	;
					adReason 	AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', изменение данных'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_RecordsetChangeComplete(	;
					adReason 	AS VARIANT @, 	;
					pError 		AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', изменение данных выполнено'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_WillMove(			;
					adReason 	AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', получение записи'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_MoveComplete(		;
					adReason 	AS VARIANT @, 	;
					pError 		AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', запись получена'
		This.RecordsCount = This.RecordsCount +  1 
		This.IncrementProgressBar()
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_EndOfRecordset(	;
					fMoreData 	AS LOGICAL @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', все данные загружены'
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_FetchProgress(	;
					Progress 	AS Number @, 	;
					MaxProgress AS Number @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', загрузка данных'
		DOEVENTS	
	*	wPause ( 1 )
	***
	
	PROCEDURE Recordsetevents_FetchComplete(	;
					pError 		AS VARIANT @, 	;
					adStatus 	AS VARIANT @, 	;
					pRecordset 	AS VARIANT @) 		AS VARIANT

		This.LabelStatus.Caption = TRANSFORM(DATETIME())+', данные загружены'
		DOEVENTS
	*	wPause ( 1 )
	***
ENDDEFINE
***

DEFINE CLASS MY1 AS Custom	OLEPUBLIC
	Name		= "MY1"
	lusTaskCode   = NULL
	ldtCreateDate = NULL
	
	ADD OBJECT oFoo1	AS Custom
	ADD OBJECT oFoo2	AS Collection
ENDDEFINE