PUBLIC oForm

oForm = CREATEOBJECT('comboingrid')
oForm.Show

*
DEFINE CLASS comboingrid AS form


	DoCreate = .T.
	Caption = "Form1"
	Name = "form1"


	ADD OBJECT grid1 AS grid WITH ;
		Height =  217 , ;
		Left =  12 , ;
		Top =  12 , ;
		Width =  349 , ;
		Name = "Grid1"


	PROCEDURE Load
		CREATE CURSOR test (id i, id_Child i)

		INSERT INTO test (id) VALUES ( 1 )
		INSERT INTO test (id) VALUES ( 2 )

		CREATE CURSOR test_Child (id i, comment c ( 10 ))

		INSERT INTO test_Child (id, comment) VALUES ( 1 , 'One')
		INSERT INTO test_Child (id, comment) VALUES ( 3 , 'Three')
	ENDPROC


	PROCEDURE Init
		WITH this.grid1
			.columncount =  3 
			.recordsource = "Test"
			.Column1.controlsource = "Test.id"
			.Column2.controlsource = "Test.id_Child"
			.Column2.Sparse = .f.
			.Column2.Bound = .t.

			WITH .Column2
				.removeobject('Text1')
				.Addobject('ComboBox1','ComboBox')
				.ComboBox1.AddProperty('Arr(2,2)')
				.ComboBox1.Visible = .t.
				.ComboBox1.rowsourcetype =  5 
				.ComboBox1.rowsource = "This.Arr"
				SELECT PADR(Comment, 10 ), id FROM test_child INTO ARRAY .ComboBox1.arr
				.ComboBox1.BorderStyle =  0 
				.ComboBox1.ColumnCount =  2 
				.ComboBox1.BoundColumn =  2 
				.ComboBox1.ColumnLines = .f.
				.ComboBox1.ColumnWidths = "100,10"
				.ComboBox1.style =  2 
			ENDWITH 

			.Column3.controlsource = "Transform(Test.id_Child)"

		ENDWITH 
	ENDPROC


ENDDEFINE