DEFINE CLASS clsfile AS custom
	PROTECTED nhandle
	nhandle = - 1 
	Name = "clsfile"

	PROCEDURE create
		lpara tcFile
		this.Close()
		this.nHandle = fcreate(alltrim(tcFile))
		return this.nHandle >=  0 
	ENDPROC

	PROCEDURE close
		if this.nHandle >  0 
			fclose(this.nHandle)
			this.nHandle = - 1 
		endif
	ENDPROC

	PROCEDURE writestring
		lpara tcS
		return fputs(this.nHandle, tcS) !=  0 
	ENDPROC

	PROCEDURE openread
		lpara tcFile
		this.Close()
		this.nHandle = fopen(alltrim(tcFile))
		return this.nHandle >=  0 
	ENDPROC

	PROCEDURE readstring
		return fgets(this.nHandle,  8192 )
	ENDPROC

	PROCEDURE eof
		return this.nHandle <  0  or feof(this.nHandle)
	ENDPROC

	PROCEDURE getsize
		local lnSize
		lnSize =  0 
		if this.nHandle >=  0 
			lnSize = fseek(this.nHandle,  0 ,  2 )
			fseek(this.nHandle,  0 ,  0 )
		endif
		return lnSize
	ENDPROC

	PROCEDURE openwrite
		lpara tcFile
		this.Close()
		if !file(tcFile)
			this.Create(tcFile)
		else
			this.nHandle = fopen(alltrim(tcFile),  1 )
			fseek(this.nHandle,  0 ,  2 )
		endif
		return this.nHandle >=  0 
	ENDPROC

	PROCEDURE isopen
		return this.nHandle >=  0 
	ENDPROC

	PROCEDURE write
		lpara tcS
		return (fwrite(this.nHandle, tcS) !=  0 )
	ENDPROC

	PROCEDURE Destroy
		this.Close()
	ENDPROC

ENDDEFINE

loF = NewObject("clsFile")
if loF.Create("MyFile.txt")
loF.WriteString("123456")
endif