NNN
Можно я за Игоря напоследок покритикую :)). Сомневаюсь я, что после нового года у меня будет время сюда заглядывать.
Собственно по коду я особых ошибок не вижу (ну разве что стиль написания, но к делу это не относится). Меня смущает сам подход.
Здесь идет не только генерация нового ключа, но и собственно создание новой записи (INSERT INTO) причем в определенном виде. Создается запись с Default-значениями и рассчитанным значением ключевого поля.
Как следствие, это налагает определенный стиль написания процедуры вставки, что не есть хорошо. Например, при таком подходе организовать APPEND FROM невозможно. Придется писать циклы.
Т.е. просто взять команду FoxPro и использовать ее уже не получится. Надо будет учитывать, а как эта команда будет увязана с принятой идеологией создания новых записей.
Использование же служебной таблицы и вызов функции из Default-поля не налагает никаких ограницений на использование всех прочих команд FoxPro.
XAndy1
Если уж таблица для индивидуального пользования, быстрее и проще всего старое доброе go (reccount()), затем id = id + 1
Далеко не факт, что последняя запись таблицы (GO (Reccount())) будет содержать и максимальное значение ключа записи. Это зависит от идеологии программы. Более надежным в этом случай будет все-таки работа с индексом (SET DELETED OFF + SET ORDER ... DESC + GO TOP) или определение MAX()+1
FM32YO aka KID
"Если неприятность может случится, то она обязательно случится" (с)
Если ты разрабатываешь процедуру для многопользовательского приложения (пусть даже для 2 клиентов), то почти наверняка возникнет ситуация, когда они одновременно обратятся к одной записи. Или в твоем случае влезут между SELECT и UPDATE
Простейшая модификация твоего кода - это заменить SELECT на LOCATE и сразу после нее сделать попытку блокировки (RLOCK()). Соответсвенно заменить UPDATE на REPLACE (хотя это уже не обязательно).
Ну, вот мой код для критики :)
Здесь используется служебная таблица TabLists из базы данных Leasing следующей структуры
TableName С(10) - имя таблицы (файла DBF) большими буквами
LastID I - последнее использованное значение ключевого поля этой таблицы
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
74.
75.
76.
77.
78.
79.
*************************************************************
*формирование нового кода записи в указанном или в текущем alias
*************************************************************
*Параметры
*tcAlias - имя таблицы без расширения для которой следует сформировать новый ID
*************************************************************
*Возвращаемое значение
*В случае успешного формирования, возвращается сформированный ID
*В случае неудачи, возвращается значение NULL
*************************************************************
*Замечание
*Рекомендуется установить для ключевых полей таблиц признак NOT NULL, тогда
*в случае неудачного формирования ID возникнет сообщение об ошибке при попытке
*записать это ID в ключевое поле таблицы
*************************************************************
FUNCTION NewID(tcAlias)
LOCAL lcAlias
IF TYPE( "tcAlias" )<> "C" OR EMPTY(m.tcAlias)=.T.
lcAlias = UPPER(ALIAS())
ELSE
lcAlias = UPPER(AllTrim(m.tcAlias))
ENDIF
LOCAL lnNewID
lnNewID=NULL
* Некоторые обязательные предварительные настройки среды
LOCAL lcReprocess, lnArea, lcError, llIsUsedTabLists
lnArea = SELECT()
lcReprocess = SET('REPROCESS')
SET REPROCESS TO 3
lcError=ON( "ERROR" )
ON ERROR * && подавляю выдачу сообщений об ошибках
llIsUsedTabLists=USED( "TabLists" )
* Если служебная таблица не открыта, то открываю ее
IF m.llIsUsedTabLists=.F.
USE Leasing!TabLists IN 0
ENDIF
* Дополняю имя таблицы пробелами справа до длины поля TabLists.TableName
* чтобы исключить поиск по первым символам
IF USED( "TabLists" )=.T. AND LEN(m.tcAlias)<LEN(TabLists.TableName)
m.tcAlias=PADR(m.tcAlias,LEN(TabLists.TableName))
ENDIF
* Вариант, когда указанный алиас не найден в служебной таблице
* рассматривается как ошибка и новый номер ID не присваивается
* Проверка на блокировку и собственно блокировка найденной записи
* предотвращают ряд специфических ошибок связанных с работой
* невизуальных ActiveX компонент
IF USED( "TabLists" )=.T. AND SEEK(m.lcAlias, "TabLists" , "TableName" )=.T. AND ;
ISRLOCKED(RECNO( "TabLists" ), "TabLists" )=.F. AND RLOCK( "TabLists" )=.T.
SELECT TabLists
REPLACE TabLists.LastID WITH TabLists.LastID+ 1
IF CursorGetProp('buffering','TabLists')> 1 AND TableUpdate(.F.,.T.,'TabLists')=.F.
* Если на служебную таблицу была установлена буферизация и сброс буфера
* не удался, то делаю откат буфера, причем результат этого отката уже
* не имеет значения
TableRevert(.F.,'TabLists')
ELSE
lnNewID=TabLists.LastID
ENDIF
UNLOCK RECORD RECNO( "TabLists" ) IN TabLists
ENDIF
* Восстанавливаю исходные настройки среды
IF m.llIsUsedTabLists=.F.
USE IN TabLists
ENDIF
SELECT (m.lnArea)
SET REPROCESS TO m.lcReprocess
ON ERROR &lcError
RETURN m.lnNewID
ENDFUNC
*************************************************************
*Завершение формирования нового кода записи в указанном или в текущем alias
*************************************************************
