LPARAMETERS tcFileName
LOCAL lcFileName, lcFileExt, lqClsidEncoder, lqEncoderParameter, luPtr
IF VARTYPE(tcFileName) = 'C'
	IF this.nativeImage =  0 		&& Если нет  загруженного изображения
		this.Status = - 1         && Наш код ошибки
		RETURN .f.
	ENDIF
	lqEncoderParameter = NULL
	lcFileExt = UPPER(JUSTEXT(tcFileName))
	DO CASE 
		CASE lcFileExt == "BMP"
			lqClsidEncoder = this.ClsidBmp 
		CASE lcFileExt == "GIF"
			lqClsidEncoder = this.ClsidGif 
		CASE lcFileExt == "JPG"
			lqClsidEncoder = this.ClsidJpeg 
			luPtr = this.GetJpegParameter(@lqEncoderParameter)
		CASE lcFileExt == "PNG"
			lqClsidEncoder = this.ClsidPng 
		CASE lcFileExt == "TIF"
			lqClsidEncoder = this.ClsidTiff
		OTHERWISE 
			this.Status =  13 	&& Gdiplus: UnknownImageFormat 
			RETURN .f.
	ENDCASE 
	lcFileName = STRCONV(tcFileName + CHR( 0 ),  5 )	&& Имя файла - в Unicode
	DECLARE Long GdipSaveImageToFile IN Gdiplus.dll Long, String, String, String
	DECLARE Long GlobalFree IN kernel32.dll Long
	this.Status = GdipSaveImageToFile(this.nativeImage, lcFileName, lqClsidEncoder, lqEncoderParameter)
	IF !ISNULL(lqEncoderParameter)	&& Если резервиловалась глобальная память Windows под структуру параметров,
		= GlobalFree(luPtr)			&& то освобождаем эту память
	ENDIF 	
ELSE 
	this.Status =  2 				&& Gdiplus: InvalidParameter
ENDIF 	
RETURN this.Status =  0 

DECLARE Long GlobalAlloc IN kernel32.dll Long, Long
DECLARE Long GlobalFree IN kernel32.dll Long
DECLARE Long lstrlenW IN kernel32.dll Long
DECLARE Long GdipGetImageEncodersSize IN gdiplus.dll Long @numEncoders, Long @ nsize
DECLARE Long GdipGetImageEncoders IN gdiplus.dll Long numEncoders, Long nsize, Long nBufferPtr

luBMP = STRCONV("image/bmp",  5 )
luGIF = STRCONV("image/gif",  5 )
luJPEG = STRCONV("image/jpeg",  5 )
luPNG = STRCONV("image/png",  5 )
luTIFF = STRCONV("image/tiff",  5 )
lnNumEncoders =  0 
lnBufferSize =  0 
this.Status = GdipGetImageEncodersSize(@lnNumEncoders, @lnBufferSize)
IF this.Status =  0 
	lnBufferPtr = GlobalAlloc(0x0040, lnBufferSize)
	this.Status = GdipGetImageEncoders(lnNumEncoders, lnBufferSize, lnBufferPtr)
	IF this.Status =  0 
		FOR lnNum =  0  to lnNumEncoders -  1 
			lnStringPtr = CTOBIN(SYS( 2600 , lnBufferPtr + lnNum *  76  +  48 ,  4 ),'RS')
			lcEncoderType = SYS( 2600 , lnStringPtr, lstrlenW(lnStringPtr) *  2 )
			lcEncoderClsid = SYS( 2600 , lnBufferPtr + lnNum *  76 ,  16 )
			DO CASE
				CASE lcEncoderType == luBMP		      && Кодер формата BMP
					this.ClsidBmp = lcEncoderClsid
				CASE lcEncoderType == luGIF		      && Кодер формата GIF
					this.ClsidGIF = lcEncoderClsid
				CASE lcEncoderType == luJPEG		  && Кодер формата JPEG
					this.ClsidJpeg = lcEncoderClsid
				CASE lcEncoderType == luPNG		      && Кодер формата PNG
					this.ClsidPNG = lcEncoderClsid
				CASE lcEncoderType == luTIFF	      && Кодер формата TIFF
					this.ClsidTiff = lcEncoderClsid
			ENDCASE 
		ENDFOR 
	ENDIF 
	= GlobalFree(lnBufferPtr)
ENDIF