я делаю так
в файле Paths.ini
пишу
[System]
Base=C:\\Data\
Program=C:\MyPrg

а в основной программе

DataBasePath = ProfileString( "PATHS.INI", "System", "Base", 0)
ProgramPath = ProfileString( "PATHS.INI", "System", "Program", 0)
SET PATH TO &DataBasePath
SET DEFAULT TO &ProgramPath

*** Где ProfileString - ф-я чтения из ИНИ файла ****
****************
**
** Functions for reading and writing .INI files.
**
** PUBLIC FUNCTIONS:
**
** =ProfileString( cINIFile, cSection, cKey, cDefault )
** =ProfileNum( cINIFile, cSection, cKey, nDefault )
** =ProfileDate( cINIFile, cSection, cKey, dDefault )
** =SetProfile( cINIFile, cSection, cKey, xValue )
**
** ProfileString is used to read a string from the specified .INI file.
**
** Eg. cSystemPath = ProfileString( "TEST.INI", "System", "Path", "." )
**
**
** ProfileNum is used to read a numeric value from the specified .INI file,
** including logical values (stored as 0 or 1).
**
** Eg. nMaxUsers = ProfileNum( "TEST.INI", "System", "MaxUsers", 20 )
**
** ProfileDate is used to read a date value from the specified .INI file.
** ( SetProfile stores dates in the format YYYYMMDD. )
**
** Eg. dDownload = ProfileDate( "TEST.INI", "System", "LastDnld", DATE() )
**
**
** SetProfile is used to store a value of any data type except objects,
** code blocks & arrays in the .INI file.
**
** lSuccess = SetProfile( "TEST.INI", "System", "MaxUsers", 20 )
**
**

** FSEEK() modes for FoxPro

#define FS_SET 0 && Seek from beginning of file
#define FS_RELATIVE 1 && Seek from current file position
#define FS_END 2 && Seek from end of file


** FOPEN() access modes for FoxPro

#define FO_READ 0 && Open for reading buffered (default)
#define FO_WRITE 1 && Open for writing buffered
#define FO_READWRITE 2 && Open for reading or writing buffered
#define FO_UREAD 10 && Open for reading unbuffered
#define FO_UWRITE 11 && Open for writing unbuffered
#define FO_UREADWRITE 12 && Open for reading or writing unbuffered

** FCREATE() file attribute modes for FoxPro

#define FC_NORMAL 0 && Create normal read/write file (default)
#define FC_READONLY 1 && Create read-only file
#define FC_HIDDEN 2 && Create hidden file
#define FC_RO_HIDDEN 3 && Read Only/Hidden
#define FC_SYSTEM 4 && Create system file
#define FC_SYS_RO 5 && Read Only/System
#define FC_SYS_HID 6 && System/Hidden
#define FC_SYS_ROH 7 && Read Only/Hidden/System


** define Carriage Return/Linefeed _CRLF

#define _CRLF CHR(13) + CHR(10)



******************************
** FUNCTION ProfileString **
*****************************************************************************
**
** This function reads a string from the specified .INI file.
**
** Parameters: cFile - The .INI file name to be used
** cSection - The section from which to read
** cKey - The key value for which to search
** cDefault - The default value if not found (optional)
**
** Returns: cString - The string read from the file.
**

FUNCTION ProfileString
PARAMETERS cFile, cSection, cKey, cDefault

** cString := The string read from the file
** nHandle := File handle for the read
** cBuffer := Buffer for the read
** nFileLen := Length of the file in bytes
** nSecPos := Position in the file of the specified section
** cSecBuf := Section subtring
** nKeyPos := Position in the file of the specified key value
** cChar := Single character read from buffer

PRIVATE cString,nHandle,cBuffer,nFileLen,nSecPos,cSecBuf,nKeyPos,cChar

IF LEFT( cSection, 1 ) <> "["
cSection = "[" + cSection
ENDIF

IF RIGHT( cSection, 1 ) <> "]"
cSection = cSection + "]"
ENDIF

IF EMPTY(cDefault) && was = NIL
cDefault = ""
ENDIF

cString = cDefault

**
** If no extension is provided for the file, assume .INI.
**
IF RAT( ".", cFile ) = 0
cFile = UPPER( ALLTRIM( cFile )) + ".INI"
ENDIF

nHandle = FOPEN( cFile, FO_READWRITE )

IF nHandle > 0
nFileLen = FSEEK( nHandle, 0, FS_END )

=FSEEK( nHandle, 0 , FS_SET )

cBuffer = SPACE( nFileLen )

**
** Read in the entire file (.INI files should be less than 64K!).
**
cBuffer = FREAD( nHandle, 64000 )
IF LEN(cBuffer) = nFileLen
**
** Determine the position in the buffer
** of the requested section.
**
nSecPos = ATC( cSection, cBuffer )

IF nSecPos > 0
**
** Extract the section from the buffer.
**
cSecBuf = RIGHT( cBuffer, nFileLen - ( nSecPos + LEN( cSection )))

IF !EMPTY( cSecBuf )
**
** Get the position of the end of the section...
**
nSecPos = ATC( "[", cSecBuf )

**
** ...and extract the section!
**
IF nSecPos > 0
cSecBuf = LEFT( cSecBuf, nSecPos - 1 )
ENDIF

**
** Now find the key within the section.
**
nKeyPos = ATC( cKey, cSecBuf )

IF nKeyPos > 0
**
** Load the return string with the value
** until a carriage return is found.
**
nKeyPos = nKeyPos + LEN( cKey ) + 1

cString = ""
cChar = ""

DO WHILE cChar <> CHR(13)
cChar = SUBSTR( cSecBuf, nKeyPos, 1 )

IF cChar <> CHR(13)
cString = cString + cChar

nKeyPos = nKeyPos + 1
ENDIF
ENDDO
ENDIF
ENDIF
ENDIF
ENDIF

=FCLOSE( nHandle )
ENDIF

RETURN cString
**
** EOP: ProfileString
**


***************************
** FUNCTION ProfileNum **
*****************************************************************************
**
** This function reads a number from the specified .INI file.
**
** Parameters: cFile - The .INI file name to be used
** cSection - The section from which to read
** cKey - The key value for which to search
** nDefault - The default value if not found (optional)
**
** Returns: nValue - The numeric value read from the file.
**

FUNCTION ProfileNum
PARAMETERS cFile, cSection, cKey, nDefault

** cValue := Profile string read from file
** cDefault := Default value converted to string
** nValue := Profile string converted to numeric

PRIVATE cValue,cDefault,nValue

IF EMPTY(nDefault) && was = NIL
nDefault = 0
ENDIF

nValue = nDefault
cDefault = ALLTRIM( STR( nDefault ))

cValue = ProfileString( cFile, cSection, cKey, cDefault )

IF !EMPTY( cValue )
nValue = VAL( cValue )
ENDIF

RETURN nValue
**
** EOP: ProfileNum
**


****************************
** FUNCTION ProfileDate **
*****************************************************************************
**
** This function reads a date from the specified .INI file.
**
** Parameters: cFile - The .INI file name to be used
** cSection - The section from which to read
** cKey - The key value for which to search
** dDefault - The default date if not found (optional)
**
** Returns: dDate - The date value read from the file.
**

FUNCTION ProfileDate
PARAMETERS cFile, cSection, cKey, dDefault

** cDateFmt := Date format on entry
** cValue := Profile string read from file
** cDefault := Default value converted to string
** dDate := Profile string converted to numeric

PRIVATE cDateFmt,cValue,cDefault,dDate

IF TYPE( dDefault ) <> "D"
dDefault = CTOD( "" )
ENDIF

dDate = dDefault
cDefault = ALLTRIM( DTOS( dDefault ))

cValue = ProfileString( cFile, cSection, cKey, cDefault )

IF !EMPTY( cValue )
**
** Try just converting the date as is.
**
dDate = CTOD( cValue )

IF EMPTY( dDate )
**
** If that doesn't work, convert
** using a standard date format.
**
cDateFmt = SET( "DATE" )
SET DATE AMERICAN
dDate = CTOD( SUBSTR( cValue, 5, 2 ) + "/" + RIGHT( cValue, 2 ) + ;
"/" + LEFT( cValue, 4 ))

SET DATE ( cDateFmt )
ENDIF
ENDIF

RETURN dDate
**
** EOP: ProfileDate
**


***************************
** FUNCTION SetProfile **
*****************************************************************************
**
** This function writes a value to the .INI file specified.
**
** Parameters: cFile - The .INI file name to be used
** cSection - The section for which to search
** cKey - The key value for which to search
** xValue - The new value to be written
**
** Returns: .T. if successful, .F. otherwise.
**

FUNCTION SetProfile
PARAMETERS cFile, cSection, cKey, xValue

** lRetCode := Function's return code
** cType := Data type of the value
** cOldValue := Current value
** cNewValue := New value to be written
** nHandle := File handle for the read
** cBuffer := Buffer for the read
** nFileLen := Length of the file in bytes
** nSecStart := Start position in the file of the section
** nSecEnd := Ending position in the file of the section
** nSecLen := Initial length of the section
** cSecBuf := Section subtring
** nKeyStart := Start position in the file of the key
** nKeyEnd := Ending position in the file of the key
** nKeyLen := Initial length of the key
** lProceed := .T. if proceeding with the change
** cChar := Single character read from file

PRIVATE lRetCode,cType,cOldValue,cNewValue,nHandle,cBuffer,nFileLen,;
nSecStart,nSecEnd,nSecLen,cSecBuf,nKeyStart,nKeyEnd,nKeyLen,;
lProceed,cChar

IF LEFT( cSection, 1 ) <> "["
cSection = "[" + cSection
ENDIF

IF RIGHT( cSection, 1 ) <> "]"
cSection = cSection + "]"
ENDIF

**
** If no extension is provided for the file, assume .INI.
**
IF RAT( ".", cFile ) = 0
cFile = UPPER( ALLTRIM( cFile )) + ".INI"
ENDIF

lRetcode = .F.
lProceed = .F.
nSecLen = 0
cType = TYPE( "xValue" )

DO CASE
CASE cType = "C"
cNewValue = xValue

CASE cType = "N"
**** changeded by PdF - must check for decimals or fails in FoxPro
IF MOD(xValue,1) > 0
** there are decimals - allow for 5 - extras will disapper in the trim
cNewValue = ALLTRIM( STR( xValue,10,5 ))
ELSE
cNewValue = ALLTRIM( STR( xValue ))
ENDIF

CASE cType = "L"
cNewValue = IIF( xValue, "1", "0" )

CASE cType = "D"
cNewValue = DTOS( xValue )

OTHERWISE
cNewValue = ""

ENDCASE

nHandle = FOPEN( cFile, FO_READ ) && FoxPro does not support Exclusive Open

IF FERROR() = 2
nHandle = FCREATE( cFile, 0 )
ENDIF

IF nHandle > 0
nFileLen = FSEEK( nHandle, 0, FS_END )

=FSEEK( nHandle, 0 , FS_SET )

cBuffer = SPACE( nFileLen )

**
** Read in the entire file (.INI files should be less than 64K!).
**
cBuffer = FREAD( nHandle, 64000 )
IF LEN(cBuffer) = nFileLen
**
** Determine the position in the buffer
** of the requested section.
**
nSecStart = ATC( cSection, cBuffer )

IF nSecStart > 0
nSecStart = nSecStart + LEN( cSection ) + 2 && Length of cSection + CR/LF

**
** Extract the section from the buffer.
**
cSecBuf = RIGHT( cBuffer, nFileLen - nSecStart + 1 )

IF !EMPTY( cSecBuf )
**
** Get the position of the end of the section...
**
nSecEnd = ATC( "[", cSecBuf )

**
** ...and extract the section!
**
IF nSecEnd > 0
cSecBuf = LEFT( cSecBuf, nSecEnd - 1 )
ENDIF

nSecLen = LEN( cSecBuf )

**
** Now find the key within the section.
**
nKeyStart = ATC( cKey, cSecBuf )

IF nKeyStart > 0
**
** Load the return string with the value
** until a carriage return is found.
**
nKeyStart = nKeyStart + LEN( cKey ) + 1
nKeyEnd = nKeyStart

cOldValue = ""
cChar = ""

DO WHILE cChar <> CHR(13)
cChar = SUBSTR( cSecBuf, nKeyEnd, 1 )

IF cChar <> CHR(13)
cOldValue = cOldValue + cChar

nKeyEnd = nKeyEnd + 1
ENDIF
ENDDO

**
** Change the old value to the new one.
**
nKeyLen = LEN( cOldValue )
cSecBuf = STUFF( cSecBuf, nKeyStart, nKeyLen, cNewValue )

lProceed = .T.
ELSE
**
** The key was not found - add it now!
**
**cSecBuf = _CRLF + cKey + "=" + cNewValue + _CRLF

cSecBuf = cKey + "=" + cNewValue + _CRLF + cSecBuf

lProceed = .T.
ENDIF
ENDIF
ELSE
**
** The section was not found - add it now!
**
**cSecBuf = _CRLF + cSection + _CRLF + cKey + "=" + ;
** cNewValue + _CRLF

cSecBuf = cSection + _CRLF + cKey + "=" + cNewValue + ;
_CRLF + _CRLF

lProceed = .T.
ENDIF
ENDIF

IF lProceed
**
** Update the buffer with the new section.
**
IF nSecStart = 0
nSecStart = LEN( cBuffer )
ENDIF

cBuffer = STUFF( cBuffer, nSecStart, nSecLen, cSecBuf )

**
** Replace the existing .INI file.
**
=FCLOSE( nHandle )

nHandle = FCREATE( cFile, 0 )

IF FWRITE( nHandle, cBuffer ) = LEN( cBuffer )
lRetCode = .T.
ENDIF
ENDIF

=FCLOSE( nHandle )
ENDIF

RETURN lRetCode