DEFINE CLASS waitexec AS custom
	Height = 15
	Width = 101
	HIDDEN nhandle
	nhandle = -1
	*-- Время в момент запуска
	HIDDEN nsecond
	nsecond = 0
	PROTECTED clasterror
	clasterror = "No error"
	nexitcode = -1
	Name = "clsexec"

	*-- Скрыть окно вызываемой программы.
	lhide = .F.


	HIDDEN PROCEDURE long2str
		LPARAMETERS tnlongval

		* Passed : 32-bit non-negative numeric value (m.longval)
		* Returns : ASCII character representation of passed
		*           value in low-high format (m.retstr)
		* Example :
		*    m.long = 999999
		*    m.longstr = long2str(m.long)

		local i, lсretstr

		lcretstr = ""
		FOR i = 24 TO 0 STEP -8
			lcretstr = CHR(INT(tnlongval/(2^i))) + lcretstr
			tnlongval = MOD(tnlongval, (2^i))
		NEXT
		RETURN lcretstr
	ENDPROC


	HIDDEN PROCEDURE str2long
		LPARAMETERS tclongstr

		* Passed:  4-byte character string (m.longstr)
		*   in low-high ASCII format
		* returns:  long integer value
		* example:
		*   m.longstr = "1111"
		*   m.longval = str2long(m.longstr)

		PRIVATE i, lnretval

		lnretval = 0
		FOR i = 0 TO 24 STEP 8
			lnretval = lnretval + (ASC(tclongstr) * (2^i))
			tclongstr = RIGHT(tclongstr, LEN(tclongstr) - 1)
		NEXT
		RETURN lnretval
	ENDPROC


	*-- Запуск указанного приложения. Параметр - полный путь к файлу. Возвращает .t. если выполнено
	PROCEDURE execute
		lpara tcExe, tnWaitToKill, tcWorkFolder
		* tcExe - командная строка для запуска
		* tnWaitToKill - время ожидания в секундах, по истечении TerminateProcess()
		* tcWorkFolder - рабочая папка, если не задана, то берется папка где расположен запускаемый EXE

		#DEFINE NORMAL_PRIORITY_CLASS 32
		#DEFINE IDLE_PRIORITY_CLASS 64
		#DEFINE HIGH_PRIORITY_CLASS 128
		#DEFINE REALTIME_PRIORITY_CLASS 1600

		this.nExitCode = -1

		local llRet, lcstart, lcprocess_info, lcPath, i

		this.Free()

		if this.lHide
			lcstart = this.long2str(68) + REPLICATE(CHR(0), 40) + this.long2str(1) + REPLICATE(CHR(0), 20)
		else
			lcstart = this.long2str(68) + REPLICATE(CHR(0), 64)
		endif
		lcprocess_info = REPLICATE(CHR(0), 16)

		if !empty(tcWorkFolder)
			lcPath = tcWorkFolder
		else
			lcPath = alltrim(tcExe)
			if left(lcPath, 1) = '"'
				lcPath = substr(lcPath, 2)
				if at('"', lcPath) != 0
					lcPath = left(lcPath, at('"', lcPath))
				endif
			else
				if at(' ', lcPath) != 0
					lcPath = left(lcPath, at(' ', lcPath))
				endif
			endif
			lcPath = addbs(justpath(lcPath))
			if left(tcExe, 1) = '"' and at('"', tcExe, 2) = len(tcExe)
				* Убирание лишних кавычек
				tcExe = substr(tcExe, 2)
				tcExe = Left(tcExe, len(tcExe) - 1)
			endif
		endif

		if empty(lcPath)
			lcPath = addbs(fullpath(''))
		endif

		if CreateProcess(0, tcExe, 0, 0, 0, NORMAL_PRIORITY_CLASS, 0, lcPath, @lcstart, @lcprocess_info) = 0
			llRet = .f.
			this.nHandle = -1
			this.cLastError = 'Не удалось выполнить ' + tcExe
		else
			this.nHandle = this.str2long(SUBSTR(lcprocess_info, 1, 4))
			this.nSecond = second()
			if empty(tnWaitToKill)
				llRet = .t.
			else
				for i = 1 to tnWaitToKill
					if this.WaitStop(1000)
						exit
					endif
				endfor
				if this.nHandle = -1
					llRet = .t.
				else
					this.Killprocess()
					llRet = .f.
					this.cLastError = 'Истекло время выполнения (' + astr(tnWaitToKill) + ' сек.) ' + tcExe
				endif
			endif
		endif

		return llRet
	ENDPROC


	*-- Ожидание завершения работы приложения. Параметр - время ожидания в мс, если не указан, то ждать до конца. Возвращает .t. если завершено.
	PROCEDURE waitstop
		#DEFINE WAIT_TIMEOUT 0x00000102

		lpara tnTime

		local llRet, llCircle, lnExitCode

		if vartype(tnTime) != 'N'
			tnTime = 200
			llCircle = .t.
		endif

		if this.nHandle != -1
			do while .t.
				IF WaitForSingleObject(this.nHandle, tnTime) != WAIT_TIMEOUT
					llRet = .t.
					lnExitCode = -2
					if GetExitCodeProcess(this.nHandle, @lnExitCode) > 0
						this.nExitCode = lnExitCode
					endif
					this.Free()
					exit
				else
					if !llCircle
						exit
					endif
				ENDIF
			enddo
		else
			llRet = .t.
		endif

		return llRet
	ENDPROC


	*-- Отказ от контроля за запущенным процессом.
	PROCEDURE free
		if this.nHandle != -1
			CloseHandle(this.nHandle)
			this.nHandle = -1
		endif
	ENDPROC


	*-- Время, которое программа работает с момента запуска, в секундах.
	PROCEDURE getworkingtime
		return second() - this.nSecond
	ENDPROC


	PROCEDURE killprocess
		if this.nHandle != -1
			TerminateProcess(this.nHandle, 0)
			this.Free()
		endif
	ENDPROC


	*-- Получение описания последней ошибки
	PROCEDURE getlasterror
		return this.cLastError
	ENDPROC


	PROCEDURE getexitcode
		return this.nExitCode
	ENDPROC


	PROCEDURE Destroy
		this.Free()
	ENDPROC


	PROCEDURE Init
		if type('glDeclareCreateProcess') = 'U'
			public glDeclareCreateProcess
			DECLARE INTEGER CreateProcess IN kernel32.DLL ;
			     INTEGER lpApplicationName, ;
			     STRING lpCommandLine, ;
			     INTEGER lpProcessAttributes, ;
			     INTEGER lpThreadAttributes, ;
			     INTEGER bInheritHandles, ;
			     INTEGER dwCreationFlags, ;
			     INTEGER lpEnvironment, ;
			     STRING @lpCurrentDirectory, ;
			     STRING @lpStartupInfo, ;
			     STRING @lpProcessInformation

			DECLARE INTEGER WaitForSingleObject IN kernel32.DLL ;
			     INTEGER hHandle, INTEGER dwMilliseconds

			DECLARE INTEGER CloseHandle IN kernel32.DLL ;
			     INTEGER hObject

			DECLARE INTEGER GetLastError IN kernel32.DLL

			DECLARE INTEGER TerminateProcess IN kernel32.DLL INTEGER, INTEGER

			DECLARE INTEGER GetExitCodeProcess IN kernel32.DLL INTEGER hProcess, INTEGER @dwExitCode
		endif
	ENDPROC
ENDDEFINE