function TIBBlob.Read(ABuff: PByte; ABuffLen: LongWord): LongWord;

{$IFDEF FireDAC_MONITOR}
  procedure Trace1;
  begin
    Env.Trace(sisc_get_segment, ['blob_handle', FBLHandle]);
  end;
{$ENDIF}

var
  iStatus: ISC_STATUS;
  iSeg, iRead: Word;
  pOrigBuff: Pointer;
begin
  ASSERT(IsOpen);
  Result := 0;
  pOrigBuff := ABuff;

  if National and (ABuffLen > 0) then
    ABuff := FDatabase.Buffer.Check(ABuffLen * SizeOf(WideChar));

  while ABuffLen > 0 do begin
    if ABuffLen > High(Word) then
      iSeg := High(Word)
    else
      iSeg := Word(ABuffLen);
{$IFDEF FireDAC_MONITOR}
    if Env.Tracing then Trace1;
{$ENDIF}
    iStatus := Lib.Fisc_get_segment(@Error.FStatusVector, @FBLHandle, iRead,
      iSeg, PISC_SCHAR(ABuff));
    if (iStatus <> 0) and (Error.FStatusVector[1] <> isc_segment) and
       (Error.FStatusVector[1] <> isc_segstr_eof) then
      Check(iStatus);
    ABuffLen := ABuffLen - iRead;
    ABuff := ABuff + iRead;
    Result := Result + iRead;
    if Error.FStatusVector[1] = isc_segstr_eof then
      Break;
  end;

  if National and (Result > 0) then
    Result := FDatabase.Encoder.Decode(FDatabase.Buffer.Ptr, Result,
      pOrigBuff, ecUTF16);
end;

procedure TForm1.btBLOBToFileClick(Sender: TObject);
var
  s: TStream;
  fs: TFileStream;
begin
  FDConnection1.Connected := True;
  FDTransaction1.StartTransaction;

  FDQuery1.FetchOptions.AutoFetchAll := afDisable;
  FDQuery1.FetchOptions.Cache := [fiDetails, fiMeta];
  FDQuery1.FetchOptions.Items := [fiDetails, fiMeta];

  FDQuery1.SQL.Text := 'select ID, FILE_ from TEST_BLOB where ID = :ID';
  FDQuery1.MasterFields := 'ID';
  FDQuery1.ParamByName('ID').AsInteger := 1;
  FDQuery1.Open;
  if not FDQuery1.Eof then begin
    fs := TFileStream.Create('C:\Work\disk2.iso', fmCreate);
    try
      s := FDQuery1.CreateBlobStream(FDQuery1.FieldByName('FILE_'), bmRead);
      fs.CopyFrom(s, -1);
    finally
      fs.Free;
    end;
  end;
  FDQuery1.CloseStreams;
  FDQuery1.Close;

  FDTransaction1.Commit;
  FDConnection1.Connected := False;
end;