{
  * The contents of this file are subject to the Mozilla Public License Version
  * 1.1 (the "License"); you may not use this file except in compliance with
  * the License. You may obtain a copy of the License at
  * http://www.mozilla.org/MPL/
  *
  * Software distributed under the License is distributed on an "AS IS" basis,
  * WITHOUT WARRANTY OF ANY KIND, either express or implied. See the License
  * for the specific language governing rights and limitations under the
  * License.
  *
  * The Initial Developer of the Original Code is Adriano dos Santos Fernandes.
  * Portions created by the Initial Developer are Copyright (C) 2015 the Initial Developer.
  * All Rights Reserved.
  *
  * Contributor(s):
}

unit UdrGenRows;

interface

uses FbApi;

{
  create procedure gen_rows (
    start_n integer not null,
    end_n integer not null
  ) returns (
    result integer not null
  )
  external name 'udr!gen_rows'
  engine udr;
}

type
  GenRowsInMessage = record
    start: Integer;
    startNull: WordBool;
    end_: Integer;
    endNull: WordBool;
  end;

  GenRowsInMessagePtr = ^GenRowsInMessage;

  GenRowsOutMessage = record
    result: Integer;
    resultNull: WordBool;
  end;

  GenRowsOutMessagePtr = ^GenRowsOutMessage;

  GenRowsResultSet = class(ExternalResultSetImpl)
    procedure dispose(); override;
    function fetch(status: status): Boolean; override;

  public
    inMessage: GenRowsInMessagePtr;
    outMessage: GenRowsOutMessagePtr;
  end;

  GenRowsProcedure = class(ExternalProcedureImpl)
    procedure dispose(); override;

    procedure getCharSet(status: status; context: ExternalContext;
      name: PAnsiChar; nameSize: Cardinal); override;

    function open(status: status; context: ExternalContext; inMsg: Pointer;
      outMsg: Pointer): ExternalResultSet; override;
  end;

  GenRowsFactory = class(UdrProcedureFactoryImpl)
    procedure dispose(); override;

    procedure setup(status: status; context: ExternalContext;
      metadata: RoutineMetadata; inBuilder: MetadataBuilder;
      outBuilder: MetadataBuilder); override;

    function newItem(status: status; context: ExternalContext;
      metadata: RoutineMetadata): ExternalProcedure; override;
  end;

implementation

uses System.SysUtils;

procedure GenRowsResultSet.dispose();
begin
  destroy;
end;

function GenRowsResultSet.fetch(status: status): Boolean;
begin
  try
    if (outMessage.result >= inMessage.end_) then
      result := false
    else
    begin
      outMessage.result := outMessage.result + 1;
      result := true;
    end;
  except
    on E: Exception do
      FbException.catchException(status, E);
  end;
end;

procedure GenRowsProcedure.dispose();
begin
  destroy;
end;

procedure GenRowsProcedure.getCharSet(status: status; context: ExternalContext;
  name: PAnsiChar; nameSize: Cardinal);
begin
end;

function GenRowsProcedure.open(status: status; context: ExternalContext;
  inMsg: Pointer; outMsg: Pointer): ExternalResultSet;
var
  Ret: GenRowsResultSet;
begin
  Ret := GenRowsResultSet.create();
  try
    Ret.inMessage := inMsg;
    Ret.outMessage := outMsg;

    // Это будет передано на клиента и обработано
    if Ret.inMessage.start > Ret.inMessage.end_ then
      raise Exception.create('start_n > end_n');

    Ret.outMessage.resultNull := false;
    Ret.outMessage.result := Ret.inMessage.start - 1;
  except
    on E: Exception do
      FbException.catchException(status, E);
  end;
  result := Ret;
end;

procedure GenRowsFactory.dispose();
begin
  destroy;
end;

procedure GenRowsFactory.setup(status: status; context: ExternalContext;
  metadata: RoutineMetadata; inBuilder: MetadataBuilder;
  outBuilder: MetadataBuilder);
begin
end;

function GenRowsFactory.newItem(status: status; context: ExternalContext;
  metadata: RoutineMetadata): ExternalProcedure;
begin
  result := GenRowsProcedure.create;
end;

end.