type
  TProtocol = (TCP, SPX, NamedPipe, Local);
...
  TBRStruct = packed record
    BackupDirName: string;
    BackupFileName: string;
    PageSize: Integer;
    Protocol: TProtocol;
    Port: string;
    ServerDirName: string;
    ServerFileName: string;
    ServerName: string;
    Password: string;
  end;
...
procedure TDBBackupForm.PrepareBackupStruct(var aBackupStruct: TBRStruct);
// Подготовка данных для бэкапа
begin
  aBackupStruct.BackupDirName := Trim(edTrgDirName.Text); // Текст из контролов "Edit"
  aBackupStruct.BackupFileName := Trim(edTrgFileName.Text);
  aBackupStruct.Protocol := TCP; // Такие дела.

  aBackupStruct.Port := FBPortConnection;

  aBackupStruct.ServerDirName := Trim(edSrcDirName.Text);
  aBackupStruct.ServerFileName := Trim(edSrcFileName.Text);

  if Trim(edTrgServerName.Text) <> '' then begin
    aBackupStruct.ServerName := Trim(edTrgServerName.Text);
    aBackupStruct.Port := FBPortConnection;
  end;

  aBackupStruct.Password := Trim(edPassword.Text);

end;
...
procedure TDBBackupForm.ValidateBackupStruct(var aBackupStruct: TBRStruct);
// Проверка исходных данных
begin
  if aBackupStruct.BackupDirName = '' then
    raise Exception.Create('Не указано имя директории резервной копии');
  if aBackupStruct.BackupFileName = '' then
    raise Exception.Create('Не указано имя файла резервной копии');
  if (aBackupStruct.Protocol <> Local) and (aBackupStruct.ServerName = '') then
    raise Exception.Create('Не указано имя сервера');

  if aBackupStruct.ServerDirName = '' then
    raise Exception.Create('Не указано имя директории на сервере');
  if aBackupStruct.ServerFileName = '' then
    raise Exception.Create('Не указано имя файла базы на сервере');

  if AnsiUpperCase(aBackupStruct.BackupDirName + aBackupStruct.BackupFileName)
    =
    AnsiUpperCase(aBackupStruct.ServerDirName + aBackupStruct.ServerFileName)
    then
    raise
      Exception.Create('Файл копии и файл базы должны быть различны.');

  if aBackupStruct.Password = '' then
  begin
    SetFocusIfPossible(edPassword);
    raise Exception.Create('Не указан пароль SYSDBA.');
  end;

end;
...

procedure TDBBackupForm.btnOkClick(Sender: TObject);
//  Выполнение бэкапа с логированием в edVerbose : TMemo
var
  fBegin, fEnd: TDateTime;
  fError: string;
  fTmpStr: string;

begin

  PrepareBackupStruct(fBRStruct);
  ValidateBackupStruct(fBRStruct);

  btnCancel.Enabled := False;
  btnOk.Enabled := False;
  pcMain.Enabled := False;

  fBegin := Now; // Время начала
  Screen.Cursor := crHourGlass;

  try
    edVerbose.Text := 'Начало резервного копирования. Время: ' +
      DateTimeToStr(fBegin);
    edVerbose.Lines.Add('');
    edVerbose.Lines.Add('');

    srvBackup.Params.Clear;
    srvBackup.Protocol := fBRStruct.Protocol;
    if fBRStruct.Protocol <> Local then
      srvBackup.ServerName := fBRStruct.ServerName + '/' + FBPortConnection
    else
      srvBackup.ServerName := '';

    srvBackup.LibraryName := ConnectDataModule.GetFBClientLibName;

    srvBackup.Params.Values['user_name'] := 'SYSDBA';
    srvBackup.Params.Values['password'] := edPassword.Text;

    pcMain.ActivePage := tsProtocol;
    btnOk.Enabled := pcMain.ActivePage = tsParams;

    try
      srvBackup.Attach;
      srvBackup.BackupFile.Clear;

      fTmpStr := IncludeTrailingPathDelimiter(fBRStruct.BackupDirName);
      // Добавляем слэш в конец пути

      srvBackup.BackupFile.Add(fTmpStr + fBRStruct.BackupFileName);

      if srvBackup.Active then
      begin

        fTmpStr := IncludeTrailingPathDelimiter(fBRStruct.ServerDirName)
          + fBRStruct.ServerFileName;

        srvBackup.DatabaseName := fTmpStr;

        srvBackup.Verbose := cbVerbose.Checked;
        if cbGarbageCollection.Checked then
          srvBackup.Options := srvBackup.Options - [NoGarbageCollection]
        else
          srvBackup.Options := srvBackup.Options + [NoGarbageCollection];

        srvBackup.ServiceStart;

        if srvBackup.Verbose then
          while not srvBackup.Eof do
          begin
            edVerbose.Lines.Add(srvBackup.GetNextLine);
            Application.ProcessMessages
          end
        else
          while srvBackup.IsServiceRunning do
            Application.ProcessMessages;

        // Считаем, что в этой точке backup успешно выполнен
        BusinessDataModule.SaveBRStruct('LastBackup', fBRStruct);

      end;
      fEnd := Now;

    except
      on e: Exception do
      begin
        fEnd := Now;
        fError := ('Ошибка:' + e.Message);
        ShowMessage(fError);
      end
    end
  finally
    if srvBackup.Active then
      srvBackup.Detach;

    Screen.Cursor := crDefault;

    edVerbose.Lines.Add(fError);
    edVerbose.Lines.Add('Резервное копирование завершено. Время: ' +
      DateTimeToStr(fEnd));
    edVerbose.Lines.Add('Затрачено времени: ' + TimeToStr(fEnd - fBegin));

    btnOk.Enabled := pcMain.ActivePage = tsParams;
    btnCancel.Enabled := True;
    pcMain.Enabled := True;
  end
end;