// Диапазон страниц
#define pgline  3 
 
LIST(ClsName,GlbName,N) ; * Просмотр класса *
 ; ClsName - имя класса
 ; GlbName - имя глобала с данными
 ; N       - количество строк на странице
 n task,prop,page,index,typfnd,fndtyp,set,data,slvtyp,fldtyp
 s set=$$Set^sysNAME
 s:$g(ClsName)="" ClsName=@set@("Class")
 s:$g(GlbName)="" GlbName=$$Temp^sysNAME()
 s N=$g(N, 10 )
 s task=@set@("Task")
 s data=$na(@GlbName@("Data"))
 s page=$$Page
 s index=$g(%request.Data("Index", 1 ))
 s typfnd=$g(%request.Data("TypFindSet", 1 ), 0 )
 s slvtyp=$$SlvTyp
 s fldtyp=$$FldTyp
 s ocls=##class(%Dictionary.ClassDefinition).%OpenId(ClsName)
 d BEGHTML
 d NAMECLS
 &html<<input type='hidden' name='Page' value='#(page)#'>>
 s prop=$na(@GlbName@("Fld"))
 d INDLIST
 if '$g(@GlbName@("Start")) {
	 d SEARCH
 }
 d FINDLIST
 d FINDTYP
 d ocls.%Close()
 d LSTPG
 d BUTTON
 d TABLE
 d LSTPG
 d ENDHTML
 q
FldTyp() ; Это заполнение из справочника
 n val
 s val=$g(%request.Data("fldname",1))
 q:val="" 0
 q 1
SlvTyp() ; Это просмотр справочника
 n val
 s val=$g(%request.Data("clsname",1))
 q:val="" 0
 q 1
BUTTON
 &html<<table>>
 &html<<tr>>
 &html<<td><input type='button' value='Добавить запись' onclick='Add()'>>
 d EXIT
 &html<</table>>
 q
EXIT
 n gl,url
 s gl=$$Exit^sysNAME()
 s url=$g(@gl)
 q:url=""
 &html<<td><input type='button' value='Выход' onclick='Exit("#(url)#")'>>
 q
LSTPG ; Список страниц
 n max,p1,p2,i
 s max=$o(@data@(""),-1)
 s p1=page-$$$pgline
 s:p1<1 p1=1
 s p2=page+$$$pgline
 s:p2>max p2=max
 &html<<table cellpadding="2" cellspacing="0" border="0">>
 &html<<tr>>
 &html<<td><div class='tbl_st0'>Страницы:>
 d:p1>1 BEGPG
 d:page>1 LEFTPG
 for i=p1:1:p2 {
	 d NUMPAGE
 }
 d:page<max RIGHTPG
 d:p2<max ENDPG
 &html<</table>>
 q
RIGHTPG ; Следующая
 &html<<td><div class='tbl_st3'><a href='javascript:GoPg(#(page+ 1 )#)' class='link1' style='text-decoration:none;'><strong>След</strong></a></div>>
 q
LEFTPG ; Предыдущая страница
 &html<<td><div class='tbl_st3'><a href='javascript:GoPg(#(page- 1 )#)' class='link1' style='text-decoration:none;'><strong>Пред</strong></a></div>>
 q
BEGPG ; Первая страница
 &html<<td><div class='tbl_st1'><a href='javascript:GoPg( 1 )' class='link1'>1</a></div>>
 q
ENDPG ; Последняя страница
 &html<<td><div class='tbl_st1'><a href=# class='link1'>#(max)#</a></div>>
 q
NUMPAGE ; Очередной номер
 if i=page {
	 d SETPG
 } else {
	 d NMPG
 }
 q
NMPG ; Очередная страница
 &html<<td><div class='tbl_st1'><a href='javascript:GoPg(#(i)#)' class='link1'>#(i)#</a></div>>
 q
SETPG ; Текущая страница
 &html<<td><div class='tbl_st8'><strong>#(i)#</strong></div>>
 q
Page() ; Номер страницы
 n val
 s val=$g(%request.Data("Page",1))
 q:val="" 1
 q:'$d(@data@(val))  1 
 q val
FINDTYP ; Тип поиска
 &html<<table cellpadding="2" cellspacing="0" border="0">>
 &html<<tr>>
 &html<<td style='border:dotted;border-width:1px;border-left:none;border-right:none;border-color:#000;' colspan="3">>
 &html<<table cellpadding="2" cellspacing="0" border="0">>
 &html<<tr>>
 &html<<td>[Равно>
 &html<<td><input type='radio' name='TypFind' value='0'#($$Val( 0 ))#>]>
 if fndtyp= 1  {
	 d STRTYP
 } elseif fndtyp= 2  {
	 d NUMTYP 
 }
 &html<<td align="right"><a href='javascript:Find()' ><img src="/prt/img/search.gif" border="0"></a>>
 &html<<td align="right"><a href='javascript:Stop()' ><img src="/prt/img/stop.gif" border="0"></a>>
 &html<<td align="right"><a href='javascript:LoadPg()' ><img src="/prt/img/refresh.gif" border="0"></a>>
 &html<</table>>
 &html<</table>>
 &html<<input type='hidden' name='TypFindSet' value='#(typfnd)#'>>
 q
NUMTYP ; Поиск строки
 &html<<td>[Больше>
 &html<<td><input type='radio' name='TypFind' value='3'#($$Val( 3 ))#>]>
 &html<<td>[Меньше>
 &html<<td><input type='radio' name='TypFind' value='4'#($$Val( 4 ))#>]>
 q
STRTYP ; Поиск строки
 &html<<td>[Начинается>
 &html<<td><input type='radio' name='TypFind' value='1'#($$Val( 1 ))#>]>
 &html<<td>[Содержит>
 &html<<td><input type='radio' name='TypFind' value='2'#($$Val( 2 ))#>]>
 q
Val(Typ) ; Значение для типа
 q:Typ=typfnd " checked"
 q ""
NAMECLS
 &html<<table cellpadding="2" cellspacing="0" border="0" width="100%">>
 &html<<tr class="data">>
 &html<<td class='headerdata' width="%100"><strong>#(ocls.Description)#</strong>>
 &html<</table>>
 q
ENDHTML ; Окончательный текст html
 &html<<td width="3" background="/prt/img/framebar-right-middle.gif">>
 &html<<tr>>
 &html<<td width="3" height="6" background="/prt/img/framebar-left-bottom.gif">>
 &html<<td height="6" background="/prt/img/framebar-middle-bottom.gif">>
 &html<<td width="3" height="6" background="/prt/img/framebar-right-bottom.gif">>
 &html<</table>>
 q
BEGHTML ; Начальный текст html
 &html<<table width="100%"  border="0" cellspacing="0" cellpadding="0" align="center">>
 &html<<tr>>
 &html<<td width="3" height="6" background="/prt/img/framebar-left-top.gif">>
 &html<<td height="6" background="/prt/img/framebar-middle-top.gif">>
 &html<<td width="3" height="6" background="/prt/img/framebar-right-top.gif">>
 &html<<tr>>
 &html<<td width="3" background="/prt/img/framebar-left-middle.gif">>
 &html<<td valign="top" class="maintablebody">>
 q
SEARCH ; Выполнить поиск
 n sql,exe
 s sql=$$SqlStr
 s exe=$$Execute
 s @GlbName@("sql")=sql
 s @GlbName@("exe")=exe
 j FIND(sql,exe,GlbName,N)
 q
SqlStr()
 n sql,cls
 s cls=$$ClsSql^sysNAME(ClsName)
 s sql="Select * From "_cls
 d WHERE
 d ORDERBY
 q sql
WHERE
 n i,d,first,rlt
 s first= 1 
 s rlt=$$Rlt^sysNAME()
 s d=""
 s i=$o(@rlt@(""))
 while i'="" {
	 d RFLD
	 s i=$o(@rlt@(i))
 }
 s i=$o(@prop@(0,""))
 while i'="" {
	 d WFLD
	 s i=$o(@prop@( 0 ,i))
 }
 q
RFLD ; Очередное свойство в реляции
 n val
 d:first WFIRST
 s val=@rlt@(i)
 s sql=sql_d_i_"="_val
 s d=" and "
 q
WFLD ; Очередное свойство
 n opr,val,fld,cls
 s fld=@prop@( 0 ,i)
 s cls=$g(@prop@( 0 ,i,"Class"))
 s val=$$Value
 q:val=""
 d:first WFIRST
 s opr=$$Opr
 s sql=sql_d_fld_opr_"?"
 s d=" and "
 q
Opr() ; Вычислить операцию
 q:typfnd= 0  "="
 q:typfnd= 1  " like "
 q:typfnd= 2  " like "
 q:typfnd= 3  ">"
 q:typfnd= 3  "<"
 q ""
Value() ; Вычислить значение
 n val
 s val=$g(%request.Data(fld, 1 ))
 q:val="" ""
 q:cls="" val
 s val=$$Code^sysFNC(val,cls)
 q val
WFIRST ; Первое условие
 s sql=sql_" where "
 s first= 0 
 q
ORDERBY ; Сортировка
 n i,d
 s sql=sql_" order by "
 s d=""
 s i=$o(@prop@( 0 ,""))
 while i'="" {
	 d OFLD
	 s i=$o(@prop@(0,i))
 }
 q
OFLD ; Очередное свойство
 n val
 s val=@prop@(0,i)
 s sql=sql_d_val
 s d=","
 q
Execute() ; Execute с параметрами
 n str,d,j
 s str="s ok=o.Execute("
 s i=$o(@prop@(0,""))
 s d=""
 while i'="" {
	 d EFLD
	 s i=$o(@prop@( 0 ,i))
 }
 s str=str_")"
 q str
EFLD ; Очередное свойство
 n val,cls
 s val=@prop@( 0 ,i)
 s val=$g(%request.Data(val, 1 ))
 q:val=""
 s cls=$g(@prop@( 0 ,i,"Class"))
 s:cls'="" val=$$Code^sysFNC(val,cls)
 q:val=""
 s:typfnd=1 val=val_"%"
 s:typfnd=2 val="%"_val_"%"
 s @GlbName@(0,i)=val
 s val="@GlbName@(0,"_i_")"
 s str=str_d_val
 s d=","
 q
FIND(Sql,Execute,GlbName,N) ; Поиск значений
 n data,o,sql,ok,i,prop,brk,value
 s @GlbName@("Start")=1
 s data=$na(@GlbName@("Data"))
 k @data
 s prop=$na(@GlbName@("Fld"))
 s o=##class(%ResultSet).%New("%DynamicQuery:SQL")
 s ok=o.Prepare(Sql)
 x Execute
 s brk=0
 while o.Next()!brk {
	 d FLINE
 }
 d o.Close()
 s @GlbName@("Stop")=1
 q
FLINE ; Очередная сторока
 n pg,lin,val
 s i=$i(@data)
 s pg=(i\N)+1
 s lin=$i(@data@(pg))
 s val=o.Get("ID")
 s @data@(pg,lin,"ID")=val
 d FTYPE()
 d FTYPE(1)
 if $$Break {
	 k:'$g(@GlbName@("Start")) @GlbName
	 s brk= 1 
 }
 q
Break() ; Прервать поиск
 q:'$g(@GlbName@("Start")) 1
 q:$g(@GlbName@("Break")) 1
 q 0
FTYPE(Typ) ; Очередной тип полей
 n j
 s Typ=$g(Typ,0)
 s j=$o(@prop@(Typ,""))
 while j'="" {
	 d LFLD
	 s j=$o(@prop@(Typ,j))
 }
 q
LFLD ; Очередное свойство
 n fld,val,cls
 s fld=@prop@(Typ,j)
 s cls=$g(@prop@(Typ,j,"Class"))
 s val=o.Get(fld)
 s:cls'="" val=$$String^sysFNC(val,cls)
 s @data@(pg,lin,fld)=val
 q
TABLE ; Собствено таблица
 &html<<table cellspacing="0" cellpadding="0" border="0" class="tabledata">>
 d TITLE
 d DATA
 &html<</table>>
 q
DATA ; Вывод даных
 n i
 &html<<tbody>>
 s i=$o(@data@(page,""))
 while i'="" {
	 d LINE
	 s i=$o(@data@(page,i))
 }
 q
LINE ; Очередная строка
 n typ,id
 s typ="chet_row"
 s:i# 2  typ="nechet_row"
 &html<<tr class="#(typ)#">>
 d DATTYPE()
 d DATTYPE( 1 )
 s id=@data@(page,i,"ID")
 if fldtyp {
	 d SETFLD
 } else {
	 d BTN
 }
 q
SETFLD ; Для заполнения поля
 n val
 s val=@data@(page,i,"Name")
 &html<<td class='tbl_st6'><a href='javascript:SetFld("#(val)#")' title="Удалить запись"><img src="/prt/img/check.gif" border="0"></img></a>>
 q
BTN ; Стандартные кнопки управления
 &html<<td class='tbl_st6'><a href='javascript:Browse(#(id)#)' title="Удалить запись"><img src="/prt/img/check.gif" border="0"></img></a>>
 &html<<td class='tbl_st6'><a href='javascript:Edit(#(id)#)' title="Редактировать запись"><img src="/prt/img/edit_button.png" border="0"></img></a>>
 &html<<td class='tbl_st6'><a href='javascript:Del(#(id)#)' title="Удалить запись"><img src="/prt/img/delete_button.png" border="0"></img></a>>
 q
DATTYPE(Typ) ; Очередной тип полей
 n j
 s Typ=$g(Typ, 0 )
 s j=$o(@prop@(Typ,""))
 while j'="" {
	 d DFLD
	 s j=$o(@prop@(Typ,j))
 }
 q
DFLD ; Очередное поле
 n val,fld
 s fld=@prop@(Typ,j)
 s val=@data@(page,i,fld)
 s:val="" val="<br>"
 &html<<td class='tbl_st6'>#(val)#>
 q
TITLE ; Шапка таблицы
 n val
 &html<<thead>>
 &html<<tr>>
 d TITTYPE()
 d TITTYPE(1)
 s val="colspan='3'"
 s:fldtyp val=""
 &html<<th class='tbl_st6' #(val)#><strong>Служебная</strong>>
 q
TITTYPE(Typ) ; Очередной тип полей
 n i
 s Typ=$g(Typ,0)
 s i=$o(@prop@(Typ,""))
 while i'="" {
	 d TFLD
	 s i=$o(@prop@(Typ,i))
 }
 q
TFLD ; Очередной столбец
 n val
 s val=@prop@(Typ,i,"Tit")
 &html<<th class='tbl_st4'><strong>#(val)#</strong>>
 q
FINDLIST ; Список полей участвующих в поиске
 n i,val
 q:'$d(@prop)
 &html<<table>>
 &html<<tr>>
 s i=$o(@prop@(0,""))
 while i'="" {
	 d FNDFLD
	 s i=$o(@prop@( 0 ,i))
 }
 &html<</table>>
 q
FNDFLD ; Очередное поисковое поле
 n fld,val,cls
 s fld=@prop@( 0 ,i)
 &html<<td>#(@prop@( 0 ,i,"Tit"))#>
 s val=$g(%request.Data(fld, 1 ))
 s cls=$g(@prop@( 0 ,i,"Class"))
 if cls'="" {
	 d FLDCLS
	 q
 }
 &html<<td><input type='text' name='#(fld)#' value='#(val)#'>>
 q
FLDCLS
 &html<<td><input type='text' onchange='String(this,"#(cls)#")' name='#(fld)#' value='#(val)#'>>
 &html<<td><input type='button' onclick='Slv("#(fld)#","#(cls)#")' value='...' title='Выбрать значение из справочника'>>
 q
INDLIST ; Список индексов
 n i,n,insl,first
 s n=ocls.Indices.Count()
 q:n=0
 s first=1
 for i=1:1:n {
	 d IND
 }
 &html<</select>>
 &html<<td><a href='javascript:NewInd()' title="Выбрать индекс"><img src="/prt/img/browse.gif" border="0"></img></a>>
 &html<<td>>
 d INFO
 &html<</table>>
 &html<<input type='hidden' name='Index' value='#(index)#'>>
 q
INFO ; Информация о поиске
 n rec,pg,inf
 &html<<table cellspacing="0" cellpadding="0">>
 &html<<tr>>
 s rec=1
 s pg=1
 s inf=$$Inf
 s:inf'="" inf="<i> "_inf_"</i>"
 &html<<td><div class='results'>Записей: <strong>#(rec)#</strong>, страниц: <strong>#(pg)#</strong>.#(inf)#</div>>
 &html<</table>>
 q
Inf()
 q:$g(@GlbName@("Break")) "Поиск прпрерван..."
 q:'$g(@GlbName@("Stop")) "Поиск продолжается..."
 q ""
IND ; Очередной индекс
 n nam,val,typ
 s nam=ocls.Indices.GetAt(i).Name
 q:$l(nam,"Index")=2
 d:first FIRSTIN
 s val=ocls.Indices.GetAt(i).Description 
 s:val="" val="Нет названия ("_nam_")"
 s typ=""
 d:nam=index INDSLCT
 &html<<option value='#(nam)#'#(typ)#>#(val)#>
 q
INDSLCT ; Информация по выбраному индексу
 n fld,j
 s typ=" selected"
 s fld=ocls.Indices.GetAt(i).Properties 
 for j=1:1:$l(fld,",") {
	 d IFLD($p(fld,",",j),j)
 }
 d ADDFLD
 q
ADDFLD ; Добавочные поля
 n o,i
 s o=##class(%ResultSet).%New("sys.AddFld:ListFld")
 d o.Execute(task,ClsName,nam)
 while o.Next() {
	 d IFLD(o.Get("Name"),$i(i),1)
 }
 d o.Close()
 q
IFLD(Fld,Pos,Typ) ; Очередное свойство
 n o,id,val,i
 s Typ=$g(Typ,0)
 s @prop@(Typ,Pos)=Fld
 s id=ClsName_"||"_Fld
 s o=##class(%Dictionary.CompiledProperty).%OpenId(id)
 s val=o.Description
 s:val="" val=Fld
 s @prop@(Typ,Pos,"Tit")=val
 s val=o.Type
 s @prop@(Typ,Pos,"Typ")=val
 s val=##class(sys.FldCls).GetCls(task,ClsName,nam)
 s:val'="" @prop@(Typ,Pos,"Class")=val
 d o.%Close()
 q:Typ'=0 0
 q:Pos'= 1   0 
 d:slvtyp SLVTYP
 s fndtyp=$$FndTyp
 q
SLVTYP ; Для справочника
 n fld
 s fld="Name"
 s:Fld="Name" fld="Code"
 d IFLD(fld, 1 , 1 )
 q
FndTyp() ; Тип поиска
 n typ
 q:$d(@prop@(Typ,Pos,"Class"))  0 
 s typ=@prop@(Typ,Pos,"Typ")
 q:typ="%Library.Integer"  2 
 q:typ="%Library.Date"  2 
 q  1 
FIRSTIN ; Первый индекс
 &html<<table cellpadding="2" cellspacing="0" border="0" >>
 &html<<tr>>
 &html<<td>Индексы>
 &html<<td>>
 &html<<select name='AllInd'>>
 s first= 0 
 q:index'=""
 s index=nam
 q