zerror ;
  /// Пример использования обработчика ошибок
  n $es
  s $et="d ERROR^zerror(""showErr^zerror(1)"")"
  s $ec=""
  d TEST
  q
TEST ; Защищаемая процедура
  n val
  s val="Test"
  w 1/0
  q
  /// Произошла ошибка. Запишем в глобал и выведем сообщение
  /// [Параметр]
  /// %ePrc - Имя пользовательской процедуры
ERROR(%ePrc)
  n %eGlb
  s %ePrc=$g(%ePrc)
  s %eGlb=$$save^zerror("MSP")
  q:%eGlb=""!(%ePrc="")
  d @%ePrc
  q
  /// Пример пользовательской процедуры вывода информации об ошибке
showErr(Type)
  n txt
  i $g(Type)=1 d ERRWRT^zerror q:$q 1 q
  s txt(1)="@Произошла ошибка"
  s txt(3)="Код ошибки: @"_$tr($g(@%eGlb@("$ec")),",")
  s txt(4)="Вызов: @"_$g(@%eGlb@("$place"))
  ;d BoxMess^aBOX(,,.txt)
  ;d SCRERR^aMENUTWO
  q
ERRWRT ; Консольное сообщение об ошибке
  w !!,"Произошла ошибка"
  w !,"Код  : "_$tr($g(@%eGlb@("$ec")),",")
  w !,"Вызов: "_$g(@%eGlb@("$place"))
  w !,"Ошибка зарегистрирована в журнале.",!
  q
  /// Запись в ^UTILITY информации об ошибке
  /// [Параметр]
  /// %eTsk* - Имя задачи
save(%eTsk)
  n %eLev,%eGlb,%eNum,%eCd,%eVar,%eNm,%eSt,%eZe
  u $p
  i $ec["<DSCON>" q:$q "" q
  w /proff
  TROLLBACK
  d DATA^zerror
  d ERRTITLE^zerror
  d VARLIST^zerror
  d STACK^zerror
  s $et="d ERR^zerror("""_$$Trans^zfunc($et)_""")"
  q:$q %eGlb
  q
ERR(Run) ; Внутренний перехват ошибки - выйдем на нужном уровне
  q:$es>2
  s $et=Run
  s $ec=""
  q
DATA ; Определим переменные
  s %eCd=$p($ec,",",2)
  s %eGlb=$na(^UTILITY("%ER",+$h))
  s %eNum=$i(@%eGlb@(0))
  s %eGlb=$na(@%eGlb@(%eNum))
  s %eNm=$na(@%eGlb@("Var"))
  s %eSt=$na(@%eGlb@("Stack"))
  s %eLev=$st(-1)
  s %eZe=$p($ze,">",2)
  q
ERRTITLE ; "Заголовок" ошибки
  d TTL^zerror("$ec",$ec,1)
  d TTL^zerror("$h",$$Date^zfunc_" "_$$Time^zfunc(,3))
  d TTL^zerror("$zv",$zv)
  d TTL^zerror("$p",$p)
  d TTL^zerror("$i",$i)
  d TTL^zerror("$s",$s)
  s @%eGlb@("task")=%eTsk
  d TTL^zerror("$zr",$$glb^zsys)
  d TTL^zerror("$$wp^zsys",$$wp^zsys)
  d TTL^zerror("$place",%eZe,1)
  ;d TTL^zerror("$place",$st(%eLev-3,"PLACE"),1)
  i $g(Info)'="",$d(@Info) m @%eGlb@("Info")=@Info
  s @%eGlb=$ec_" "_$st(%eLev-3,"PLACE")
  q
TTL(Nm,Val,Up) ; Запишем общие данные
  i '$g(Up) s @%eGlb@("Info",Nm)=Val q
  s @%eGlb@(Nm)=Val
  q
VARLIST ; Список локальных переменных
  s %eVar=$$firstVar^zsys
  f  s %eVar=$o(@%eVar) q:%eVar=""  d NEXTVAR^zerror
  q
NEXTVAR ; Следующая локальная переменная
  n ln
  s ln=",%eLev,%eGlb,%eNum,%eCd,%ePrc,"
  s ln=ln_"%eVar,%eNm,%eSt,%eZe,%eTsk,"
  q:ln[(","_%eVar_",")
  m @%eNm@(%eVar)=@%eVar
  q
STACK ; Запишем стек
  n lev,num,code,len
  s num=-1
  s %eLev=%eLev-3
  s len=$l(%eLev)
  s %eZe=$p(%eZe," ")
  f lev=%eLev:-1:0 d NEXTLEV^zerror
  q
NEXTLEV ; Пишем очередной уровень стека
  n val
  s val=$st(lev,"PLACE")
  s code=$$PadL^zfunc($i(num),len)_". "_val
  s @%eSt@(code)=$$line(lev)
  q
line(Lev) ; Строка с ошибкой
  q $$At^zfunc($tr($st(Lev,"MCODE"),$c(9)," "))
  /// Обработка исключения
  /// [Параметры]
  /// Proc* - Процедура подлежащая защите
  /// pUser - Пользовательская обработка исключения
exception(Proc,pUser)
  n syserr,syset
  s pUser=$g(pUser)
  s syset=$et
  s $ec=""
  s syserr=0
  s $et="d EXCEPTION^zerror"
  d @Proc
  q:$q syserr
  q
EXCEPTION ; Действия при возникновении исключения
  s syserr=1
  d:$g(pUser)'="" @pUser
  s $ec=""
  s $et=syset
  q