Darkhan DarkhanВсем спасибо за отзывчивость. Сейчас рассмотрю предложенные варианты.
Но мне нужно использовать это в CSP (не ZEN).
doublefint привёл некоторые методы из класса
%ZEN.Auxiliary.jsonProvider , которые можно вызывать из CSP, например:
Пример на ZENClass SqlRu.test Extends %ZEN.Component.page
{
/// Comma-separated list of additional JS include files for the page.
Parameter JSINCLUDES As STRING = "zenCSLM.js";
XData Style
{
<style type="text/css">
/* establish size of finder */
#finder {
border: 1px solid black;
width: 900px;
height: 400px;
overflow-x: auto;
overflow-y: hidden;
background: rgb(180,190,200);
}
/* fix width/height of each finder column */
.finderColumn {
width: 300px;
height: 400px;
}
</style>
}
XData Contents [ XMLNamespace = "
http://www.intersystems.com/zen" ]
{
<page xmlns="
http://www.intersystems.com/zen" title="" height="100%">
<jsonProvider id="json" OnGetArray="GetFinderArray"/>
<finderPane id="finder" ongetdata="return zen('json').getContentObject();"/>
<button caption="test" onclick="zenPage.test();"/>
</page>
}
ClientMethod test() [ Language = javascript ]
{
zenAlert(ZLM.jsonEncode(zen('json').getContentObject()));
}
/// Provide the source data (as an array) that will drive the finder.
Method GetFinderArray(
ByRef pParameters,
Output pMetaData,
Output pData) As %Status
{
// The MetaData list specifies the names of the properties of the
// JavaScript objects and the order in which they appear within
// nodes of the data array.
Set pMetaData = $LB("name","title","supervisor","phoneNo")
// create a random org chart
Set d = 0
For tDept = "Sales","Marketing","Engineering","HR","Finance" {
// add top-level entry for each department
Set d = d + 1
Set pData(d) = $LB(tDept) // name, but no other properties
// add executive to each dept
Set tVPName = ##class(%PopulateUtils).Name()
Set pData(d,1) = $LB(tVPName,"Vice President, "_ tDept)
// add 2nd level managers
For n = 1:1:($R(10)+2) {
Set tMgrName = ##class(%PopulateUtils).Name()
Set pData(d,1,n) = $LB(tMgrName,"Manager",tVPName)
// add workers
For w = 1:1:($R(25)+2) {
Set tWkrName = ##class(%PopulateUtils).Name()
Set tTitle = ##class(%PopulateUtils).Title()
Set pData(d,1,n,w) = $LB(tWkrName,tTitle,tMgrName)
}
}
}
Quit $$$OK
}
}
Аналог на CSP<CSP:CLASS INCLUDES="%callout">
<html>
<head>
<title></title>
<script type="text/javascript" src="zenutils.js"></script>
<script type="text/javascript" src="zenCSLM.js"></script>
<script language="cache" method="GetFinderArray" arguments="&pMetaData,&pData" returntype="%Status">
new d,tDept,tVPName,n,tMgrName,tWkrName,tTitle
// The MetaData list specifies the names of the properties of the
// JavaScript objects and the order in which they appear within
// nodes of the data array.
Set pMetaData = $LB("name","title","supervisor","phoneNo")
// create a random org chart
Set d = 0
For tDept = "Sales","Marketing","Engineering","HR","Finance" {
// add top-level entry for each department
Set d = d + 1
Set pData(d) = $LB(tDept) // name, but no other properties
// add executive to each dept
Set tVPName = ##class(%PopulateUtils).Name()
Set pData(d,1) = $LB(tVPName,"Vice President, "_ tDept)
// add 2nd level managers
For n = 1:1:($R(10)+2) {
Set tMgrName = ##class(%PopulateUtils).Name()
Set pData(d,1,n) = $LB(tMgrName,"Manager",tVPName)
// add workers
For w = 1:1:($R(25)+2) {
Set tWkrName = ##class(%PopulateUtils).Name()
Set tTitle = ##class(%PopulateUtils).Title()
Set pData(d,1,n,w) = $LB(tWkrName,tTitle,tMgrName)
}
}
}
/*
или
Set pMetaData = $LB("name","rank","serialNo")
Set pData(1) = $LB("Smith","Captain","444-33-2222")
Set pData(1,1) = $LB("Jones","Corporal","333-22-3333")
*/
Quit $$$OK
</script>
<script language="cache" method="SrvTest" returntype="%String">
new format,tIO,tXDEV,export,tChunk
do ..GetFinderArray(.pMetaData,.pData)
// собираем в строку всё, что выводится через write
set tIO=$IO,tXDEV="|XDEV|"_+$JOB,$ZT="Trap"
Do {
/// For $$$IsUnicode use UTF-8
Open tXDEV:($ZF(-6,$$$XSLTLibrary,12):"":"S":/HOSTNAME="XSLT":/IOT=$S(($zcvt($get(format),"L")[",utf8")||$$$IsUnicode:"UTF8",1:"RAW"):/IBU=16384:/OBU=16384)
Use tXDEV
Quit:$$$ISERR(##class(%ZEN.Auxiliary.jsonProvider).%ArrayToJSON(.pMetaData,.pData))
// Flush any remaining output
Write *-3
// Now read back a string (up to the maximum possible length, 32k or ~4MB for long strings)
Set export = ""
While (1) {
#dim tChunk As %String
Read tChunk:0
Quit:'$L(tChunk)
Set export = export _ tChunk
}
} While (0)
:Exit
Close tXDEV
Use tIO
Quit export
:Trap
Set $ZT=""
Goto Exit
</script>
<script type="text/javascript">
function test()
{
var str=#server(..SrvTest())#;
var obj=ZLM.jsonParseObject(str);
zenAlert("str=",str);
zenAlert("obj=",obj);
zenAlert("name=",obj.obj.children[0].name);
/*
можно ещё так
var str2=ZLM.jsonEncode(obj,false);
zenAlert("str2=",str2);
*/
}
</script>
</head>
<body>
<button onclick="test();">test</button>
</body>
</html>
PS: в обратную сторону, думаю, справитесь самостоятельно.
